Copyright 2014-6 by Andrew Plotkin.
This source code is provided for personal, educational use only. The story and text of Hadean Lands belong to me; you may not use them or create derivative works which contain them. However, you have permission to use the programming techniques of this game in your own works, and you may use the source code excluding game text.
Version 1 of HL Game Locs by Andrew Plotkin begins here.
Use authorial modesty.
[### Game-wide things to check:
- Smell (aroma-description)
- Verbs: clean/rub, squeeze, climb, repair, ??
- Inspect through (lens, oculus)
- make sure no "[list of...]" constructs have snuck in without *in.
]
The description of a room is usually "(BUG) [The item described] is undescribed."
To decide whether open-property (T1 - thing) matches (T2 - thing):
if T1 is open:
if T2 is open:
decide yes;
else:
if T2 is closed:
decide yes;
decide no.
The vacuum-entry-cycler is a stopping-cycler.
To say vacuum-entry-reaction:
say "The vacuum plucks at your clothing for a moment";
if the current vacuum-entry-cycler is 1:
say ", but the only other sensation is a nagging dryness in your sinuses[first time]. Very strange[only]".
Chapter - Start Labs
Section - 2nd-Lab
The 2nd-Lab is a recallable room. The printed name is "Secondary Alchemy Lab".
The zone is the 2nd-lab-zone.
Understand "secondary", "second", "alchemy", "lab", "laboratory" as 2nd-Lab.
The description of 2nd-Lab is "[2nd-Lab-desc]".
To say 2nd-Lab-desc:
close tut-initial;
tutor tut-look;
let shocked be whether or not reset-counter is 1;
if Pneuma is not fixed:
say "The lab is unsettlingly dim, but";
else:
say "The lab is";
if bool shocked:
say " familiar -- in fact, exactly as it was before: rough";
else:
say " familiar enough: rough";
say " wooden walls, the broad stone surface of the workbench";
say ". The lab door is to the north";
if the fake-lab-door is in 2nd-Lab:
if the fake-lab-door is closed:
say "; it's closed";
else:
say "; it opens on a frightening Hadean landscape";
else:
say "; it's open, and the lab hall is reassuringly visible outside";
if the 2nd-lab-fracture is undiscovered:
say ".[para]To the east is the lab's supply closet. Except... the entire east side of the room is filled with clear crystal. That's not so familiar. That's downright strange";
else:
say ".[para]Some kind of fracture[if bool shocked] [em]still[/em][end if] blocks the east side of the room from you";
if the fake-lab-door is open and peek at lab-door-cycler is not 1:
say ", and another blocks the hallway to the north";
say period.
The can't-go of 2nd-Lab is "The only ways out are north, east, and the hatch in the floor. (But [if the fake-lab-door is undiscovered or fake-lab-door is not in 2nd-lab]east seems to be a problem[else]north and east seem to be problems[end if].)"
The aroma-description of 2nd-Lab is "You smell the usual mixture of alchemical reagents[if desc-aroma is no-odor] -- mostly rosemary and copal -- over a reek of spilled alcohol[first time]. The undertone of blood has faded[only][end if]".
Check going outside in the 2nd-Lab:
if the fake-lab-door is in 2nd-lab and the 2nd-hatch is open:
instead try going down;
instead try going north.
Check going north in the 2nd-Lab when the fake-lab-door is in 2nd-lab:
instead try entering the fake-lab-door.
Check going east in the 2nd-Lab:
instead try entering the 2nd-lab-fracture.
Report going when the door gone through is the 2nd-hatch:
if the location is the 2nd-Lab:
say "You pull yourself up through the hatch.";
else:
say "You drop through the hatch into the crawlspace below."
Check look-outward-ing in the 2nd-Lab when the fake-lab-door is in the 2nd-lab:
instead try searching the fake-lab-door.
The fake-lab-door is a syn-gap-door in the 2nd-Lab. The printed name is "lab door".
The examine-target is the 2nd-lab-landscape.
The refer-name is "Secondary Alchemy Lab door".
Understand "door", "lab", "laboratory" as the fake-lab-door.
Understand "corridor", "hall", "hallway" as the fake-lab-door when the fake-lab-door is open.
Check examining the fake-lab-door:
if the fake-lab-door is closed:
tutor tut-examine-closed-door with the fake-lab-door;
instead say "The door is closed[if the fake-lab-door is discovered]. It looks perfectly innocuous now[end if].";
instead try examining the 2nd-lab-landscape.
Check opening the fake-lab-door when the fake-lab-door is closed:
now the fake-lab-door is open;
if the fake-lab-door is undiscovered:
now the fake-lab-door is discovered;
instead say "You pull the door open. Then you nearly fall down, so sharp is your disorientation. Only your grip on the door convinces you that you are still standing upright.[para]A Hadean land lies outside the lab door.[para][em]I'm sure this wasn't in the regs.[/em] The east-side corridor is missing. Or most of it is missing. A foot or so of ordinary tile floor is at your feet; but beyond that, the corridor is cut away as if by a knife. Beyond is a barren grey wasteland -- a Hadean land, deadly to any breathing life. Unweathered grey rocks and dead dust rest under bright, unwinking stars.";
else:
say "[one of]Very hesitantly, you open the door[or]You open the door[stopping]. The dead landscape is still there[one of][or][or], despite your efforts[stopping]";
instead say "."
Check closing the fake-lab-door when the fake-lab-door is open:
now the fake-lab-door is closed;
instead say "You shut the door, and resist the temptation to lean against it in relief."
The lab-door-cycler is a stopping-cycler.
Check entering the fake-lab-door:
tutor tut-fail-exiting with fake-lab-door;
if the fake-lab-door is closed:
instead try opening the fake-lab-door;
if the current lab-door-cycler is 1:
say "You might be sucked through the door into vacuum. But wouldn't the lab's atmosphere be sucked out anyway...?[para]You could ponder that for hours, but your hand has more curiosity or less sense than your head. You reach out -- and your fingers brush";
if the 2nd-lab-fracture is undiscovered:
say " a crystal-hard, slick surface. The Hadean land is blocked away, just like the supply closet";
else:
say " another crystal-hard, slick surface. The Hadean land is blocked by a fracture, just like the supply closet";
instead say ".";
else:
if the 2nd-lab-fracture is undiscovered:
say "The corridor ends";
else:
say "The fracture, or whatever it is, is";
instead say " a foot or so beyond the door. There's no room to step outside[first time]. And you wouldn't want to take a stroll out there, anyway[only]."
Check inserting something into the fake-lab-door when the fake-lab-door is open:
if peek at lab-door-cycler is 1:
instead say "You're not even sure the landscape out there is real.";
instead say "The landscape is sealed away by that odd fracture.";
The 2nd-lab-landscape is a far-sight in the fake-lab-door. The printed name is "Hadean land".
Understand "hadean", "land", "landscape", "barren", "grey", "gray", "rock", "rocks", "dead", "dust", "frightening", "desolate", "desolation" as the 2nd-lab-landscape.
The reach-reason is "[reach-2nd-lab-landscape]."
To say reach-2nd-lab-landscape:
if the 2nd-lab-fracture is discovered and peek at lab-door-cycler is not 1:
say "The landscape is sealed away from you by that odd fracture";
else if peek at lab-door-cycler is not 1:
say "The landscape is sealed away from you... somehow";
else:
say "You're not even sure it's [em]there[/em]".
Check examining the 2nd-lab-landscape:
say "Most Hadean lands look alike -- dead rocks, night sky -- and you can tell nothing about this one, except that it very definitely shouldn't be where the [Retort's] east-side corridor usually is";
if the 2nd-lab-fracture is discovered and peek at lab-door-cycler is not 1:
say ". The crystalline glint of a fracture plane is all that protects you";
instead say "."
Check searching the 2nd-lab-landscape:
instead try examining the noun.
Check inspecting the 2nd-lab-landscape with the planetary-lens:
instead say "The lens displays the landscape's Hadean nature."
The 2nd-land-sky is a far-sight in the fake-lab-door. The printed name is "night sky".
The description is "It's the sky of every airless land: unwavering stars, very far away. You recognize no constellations, but then you've never studied astrographerie[if the Observatory is not visited]. Perhaps you can learn more in the observatory[end if]."
The reach-reason is "The stars are infinitely distant."
Understand "space", "sky", "star", "stars", "sky", "bright", "unwinking", "unwavering", "black", "constellation" as the 2nd-land-sky.
Check searching the 2nd-land-sky:
instead try examining the 2nd-land-sky.
Check entering the 2nd-land-sky:
instead say "In a sense, you're among the stars already. But it's the [Retort] and its dragons that carry you there, and you're not likely to fly through them by flapping your arms."
The 2nd-lab-table is a prominent-scenery supporter in the 2nd-lab. The printed name is "side table".
Understand "side", "table", "flimsy" as the 2nd-lab-table.
Understand "heap", "pile", "heap of", "pile of", "supply", "supplies" as the 2nd-lab-table when the 2nd-lab-table is non-empty.
Rule for writing a paragraph about the 2nd-lab-table:
if the 2nd-lab-table is undiscovered:
say "You notice a heap of alchemical supplies piled on a table";
["everything" sucks]
repeat with T in raw contents of the 2nd-lab-table:
now T is ever-seen;
now T is mentioned;
say ". Next to the table, ";
else:
if the 2nd-lab-table is empty:
say "Next to a side table, ";
else:
say "On a side table, you see [a list of things *in the 2nd-lab-table roomily]";
say ". Next to the table, ";
say "an iron panel [if 2nd-hatch is closed]is set in the floor[else]stands open; you can see a crawlway below[end if]."
Check examining the 2nd-lab-table:
if the 2nd-lab-table is undiscovered:
now the 2nd-lab-table is discovered;
tutor tut-discover-table;
if the 2nd-lab-table is empty:
instead say "The flimsy side table is empty.";
instead say "Lying on the flimsy table [is-are a list of things *in the 2nd-lab-table roomily]."
Check searching the 2nd-lab-table:
instead try examining the 2nd-lab-table.
Check taking something supported by the 2nd-lab-table:
if the 2nd-lab-table is undiscovered:
now the 2nd-lab-table is discovered;
tutor tut-discover-table;
say "You take a look at the table first. Lying on it [is-are a list of things *in the 2nd-lab-table].";
if the noun is the sh-rust-remover:
[Too much words. Cut this off here.]
stop the action;
[But for ordinary things, continue.]
if the noun is not sh-rust-remover:
tutor tut-took-something with the noun.
Check taking the 2nd-lab-table:
if the 2nd-lab-table is undiscovered:
now the 2nd-lab-table is discovered;
tutor tut-discover-table;
say "You stop and take a closer look at the supplies";
if the 2nd-lab-table is empty:
instead say ". The table is empty.";
instead say ". On the table [is-are a list of things *in the 2nd-lab-table].";
instead say "The table is flimsy, but that doesn't mean you can drag it around the marcher with you[if the 2nd-lab-table is empty].[else]. (Or did you mean to take one of the items on the table?)[end if]".
Rule for deciding whether all includes something on the 2nd-lab-table while taking when the 2nd-lab-table is undiscovered:
it does not.
Rule for deciding whether all includes the 2nd-lab-table while taking when the 2nd-lab-table is undiscovered:
[Sneakily permit "get all" to cause discovery in a controlled way.]
it does.
Rule for deciding whether all includes the sh-rust-remover while taking:
[But exclude the sheet, because that's just messy.]
it does not.
Check pushing the 2nd-lab-table:
instead say "The table doesn't move much."
Check pulling the 2nd-lab-table:
instead try pushing the 2nd-lab-table.
Check shaking the 2nd-lab-table:
instead try pushing the 2nd-lab-table.
Check entering the 2nd-lab-table:
instead say "The side table doesn't look strong enough to support you."
Check climbing the 2nd-lab-table:
instead try entering the 2nd-lab-table.
The 2nd-lab-fracture is a fracture in the 2nd-Lab.
Understand "crystal", "crystals", "surface", "slick", "clear", "hard", "air" as the 2nd-lab-fracture.
To decide whether ruminate-fracture:
if the 2nd-lab-fracture is undiscovered:
now the 2nd-lab-fracture is discovered;
say "It's not crystal. It's more as if the [italic type]air[roman type] has cracked, right across the room, leaving a plane of cleavage which is visible only in refraction";
decide yes;
else:
decide no.
Check examining the 2nd-lab-fracture:
if not ruminate-fracture:
say "The fracture looks like the surface of faintly-warped crystal... although you cannot truly tell whether you are looking into it, or out of it. The far side of the room distorts slightly as you shift your position";
instead say "."
Check taking the 2nd-lab-fracture:
if ruminate-fracture:
say ".[para]";
instead say "Whatever this fracture is, you certainly can't carry it around."
Check touching the 2nd-lab-fracture:
if ruminate-fracture:
say ".[para]";
tutor tut-fail-exiting with 2nd-lab-fracture;
instead say "The fracture feels like slick, hard air."
Check entering the 2nd-lab-fracture:
if ruminate-fracture:
say ".[para]";
tutor tut-fail-exiting with 2nd-lab-fracture;
instead say "You try to push through the fracture, but the surface is impenetrable[first time]. The east side of the room -- and the supply closet -- are inaccessible[only]."
Check repairing the 2nd-lab-fracture:
instead say "The question is, how. Also why, when, and what the--?"
The 2nd-supply-closet is a far-sight. The 2nd-supply-closet is part of the 2nd-lab-fracture. The printed name is "supply closet".
Understand "supply", "closet" as the 2nd-supply-closet.
The reach-reason of the 2nd-supply-closet is "[if the 2nd-lab-fracture is undiscovered]The closet is blocked by some sort of crystal surface[else]You cannot reach the supply closet[end if]."
Check entering the 2nd-supply-closet:
if the 2nd-lab-fracture is undiscovered:
instead say "The closet is blocked by some sort of crystal surface.";
instead try entering the 2nd-lab-fracture.
Check examining the 2nd-supply-closet:
if the 2nd-lab-fracture is undiscovered:
instead try entering the 2nd-lab-fracture;
instead say "You can't see well into the supply closet -- not through this fracture in the air."
The 2nd-bench is a mineralish prominent-scenery ritual-bound in the 2nd-Lab. The printed name is "workbench bound".
The short-adjective is "workbench bound".
[No shelf here.]
The description is "The workbench is a broad slab of bluestone, chipped and scarred. A bound is incised in its surface[first time] -- the circular arc that contains and constrains works of alchemy[only]."
Understand "workbench", "work", "bench", "bluestone", "stone", "slab" as the 2nd-bench.
Rule for writing a paragraph about the 2nd-bench:
if the 2nd-bench is empty-inactive:
now the 2nd-bench is mentioned;
stop;
say the visible state of the 2nd-bench.
Carry out examining the 2nd-bench:
say "[description of the 2nd-bench][para]";
say the visible state of the 2nd-bench;
if the steel-bolt is not handled:
if the steel-bolt is undiscovered:
now the steel-bolt is discovered;
say "[br]You notice a worn steel bolt lying";
else:
say "[br]A worn steel bolt is lying";
say " under the workbench.";
stop the action.
Check looking under the 2nd-bench:
if the steel-bolt is not handled:
if the steel-bolt is undiscovered:
now the steel-bolt is discovered;
say "You notice a worn steel bolt lying";
else:
say "A worn steel bolt is lying";
instead say " under the bench."
The 2nd-hatch is a crawl-hatch.
The opening-goal is g-2nd-hatch.
The pull-side is 2nd-Lab.
The refer-name is "Secondary Alchemy Lab hatch".
The 2nd-hatch can be ever-tried. [resettable]
The 2nd-hatch is below the 2nd-Lab.
Understand "crawlway", "crawlspace", "crawl", "way", "space" as the 2nd-hatch when the location is the 2nd-Lab and the 2nd-hatch is open.
Check examining the 2nd-hatch when the location is the 2nd-Lab:
if the 2nd-hatch is open:
instead say "The iron panel is open now. You can see a gloomy space below -- some kind of crawlspace -- but you cannot make out what's down there.";
tutor tut-examine-closed-door with the 2nd-hatch;
say "You've seen the iron panel before, of course. It's some kind of service hatch";
if the 2nd-hatch is dirty:
say ". But it's apparently been shut since forever and a quarter. It's faintly rusty around all its edges, and the steel bolts that hold it down are worse";
else:
if the 2nd-hatch is not ever-tried:
say ". You've never seen it open, but the";
else:
say ". The";
say " bolts are now sparkling-clean";
instead say "."
Check examining the 2nd-hatch when the location is the 2nd-Crawl:
say "It's a service hatch in the ceiling, now unusually well-polished";
say ". It leads to the Secondary Alchemy Lab";
if the noun is closed:
say ". The panel is closed";
else:
say ". The panel is open, but you can't see much on the other side";
instead say "."
Check tapping the steel-bolt on the 2nd-hatch when the symbol-type of the steel-bolt is some-saturation-symbol:
say "You carefully lay the [symbol-type of the steel-bolt] symbol against the steel bolts";
uninscribe the steel-bolt;
if the 2nd-hatch is clean:
instead say ". The symbol discharges with a faint pop. The steel bolts shimmer slightly, but they're already about as clean as steel can get.";
now the 2nd-hatch is clean;
tutor tut-hatch-clean;
instead say ". The symbol discharges with a loud, crackling buzz. Sparks fly across the surface of the iron panel, and the bolt-heads rattle as their rust sublimes away.[para]The display of alchemical energies slowly dies away, leaving the hatch and its bolts bright and clean."
Check tapping the brass-pin on the 2nd-hatch when the symbol-type of the brass-pin is gensaturation-symbol:
say "You carefully lay the [symbol-type of the brass-pin] symbol against the steel bolts";
uninscribe the brass-pin;
if the 2nd-hatch is clean:
instead say ". The symbol discharges with a faint pop. The steel bolts shimmer slightly, but they're already about as clean as steel can get.";
now the 2nd-hatch is clean;
instead say ". The symbol discharges with a loud, crackling buzz. Sparks fly across the surface of the iron panel, and the bolt-heads rattle as their rust sublimes away.[para]The display of alchemical energies slowly dies away, leaving the hatch and its bolts bright and clean."
Check opening the 2nd-hatch when the 2nd-hatch is dirty:
if g-2nd-hatch is ever-done:
goal-perform g-2nd-hatch;
if the 2nd-hatch is open:
say "You pull the hatch open.";
stop the action;
tutor tut-fail-opening-hatch;
tutor tut-fail-exiting with 2nd-hatch;
instead say "You twist at the steel bolts, but they're rusty and they probably haven't turned since the [Retort] was built[first time]. The panel isn't moving anywhere[only]."
Report opening the 2nd-hatch when the 2nd-hatch is not ever-tried:
now the 2nd-hatch is ever-tried;
instead say "You twist at the first of the steel bolts. It's still tight, but it reluctantly begins to turn.[para]After several minutes of scraped and reddening hands, you've loosened all of the bolts. You lift the hatch open, and peer down into a dim crawlspace."
Carry out closing the 2nd-hatch:
now the 2nd-hatch is ever-tried.
Check repairing the dirty 2nd-hatch:
instead say "The question is, how."
Rule for writing a paragraph about the not handled steel-bolt:
now the steel-bolt is mentioned;
if the steel-bolt is discovered:
say "A worn steel bolt is lying half-hidden under the workbench."
Rule for deciding whether all includes the not handled undiscovered steel-bolt while taking:
it does not.
Report taking the not handled steel-bolt:
if the steel-bolt is not discovered:
now the steel-bolt is discovered;
instead say "Oh, there's a steel bolt under the bench... Taken.";
else:
instead say "You reach down and pluck the bolt from the floor."
The calipers are a symbolish takeable-thing. The printed name is "[if dirty]tarnished[else]gleaming[end if] calipers".
The calipers are plural-named. The indefinite article is "a pair of".
The calipers can be clean or dirty.
The lens-view is "Venus and Ganymede".
Understand "pair", "pair of", "caliper", "brass", "hinge" as the calipers.
Understand "tarnish", "tarnished" as the calipers when the calipers are dirty.
Understand "gleaming", "polished" as the calipers when the calipers are clean.
Check examining the calipers:
instead say "These are standard Naval chart calipers; you see the astrographers using them every time you walk past the tower[if dirty]. But the brass is badly tarnished, particularly around the hinge[else]. The brass gleams[end if]."
Check opening the calipers:
if the calipers are clean:
instead say "You flex the calipers. They move easily now.";
else:
instead say "The calipers are jammed half-open. The tarnished hinge doesn't give at all[one of][or], and if you push any harder, you'll probably break the thing[stopping]."
Check closing the calipers:
instead try opening the calipers.
Check pushing the calipers:
instead try opening the calipers.
Check pulling the calipers:
instead try opening the calipers.
Check repairing the dirty calipers:
instead say "The question is, how."
Check rubbing the calipers when the calipers are dirty:
instead say "The calipers are way past the point of scrubbing with your thumb[if 2nd-Crawl is not visited]. You should see about the alchemical recipe the Sarge left you[end if]."
Check tapping the brass-pin on the calipers when the symbol-type of the brass-pin is some-saturation-symbol:
say "You carefully lay the [symbol-type of the brass-pin] symbol against the calipers";
uninscribe the brass-pin;
if the calipers are clean:
tutor tut-calipers-clean-again;
instead say ". The symbol discharges with a faint pop. The calipers seem to glint even more brightly than before, but it's probably your imagination.";
now the calipers are clean;
tutor tut-calipers-clean;
instead say ". With a loud crackle, the symbol discharges. Sparks dance over the calipers; the tarnished brass flakes and vibrates. Within moments, the calipers are gleaming brightly. The alchemical energies fade, leaving a perfectly polished instrument.[para][sarge]Take that, Sarge,[/sarge] you think, with some smugness."
Check tapping the steel-bolt on the calipers when the symbol-type of the steel-bolt is gensaturation-symbol:
say "You carefully lay the [symbol-type of the steel-bolt] symbol against the calipers";
uninscribe the steel-bolt;
if the calipers are clean:
instead say ". The symbol discharges with a faint pop. The calipers seem to glint even more brightly than before, but it's probably your imagination.";
now the calipers are clean;
instead say ". With a loud crackle, the symbol discharges. Sparks dance over the calipers; the tarnished brass flakes and vibrates. Within moments, the calipers are gleaming brightly. The alchemical energies fade, leaving a perfectly polished instrument.[para][sarge]Take that, Sarge,[/sarge] you think, with some smugness."
Section - 2nd-Crawl
The 2nd-Crawl is a low-ceilinged room. The printed name is "Secondary Lab Crawlspace".
The zone is the lab-crawl-zone.
The 2nd-Crawl is below the 2nd-hatch.
The description of 2nd-crawl is "You are in a low[if Pneuma is not fixed], dimly lit[end if] corridor that runs from east to west. [if 2nd-hatch is open]A hatch by your (ducked) head opens to the laboratory above[else]The laboratory hatch above your (ducked) head is closed[end if]."
For room-visiting the 2nd-Crawl:
tutor tut-complete.
The initial appearance of the alcohol is "A chymic flask rests nearby; it reeks of rubbing alcohol."
The aroma-description of 2nd-Crawl is "The scent of cleaning alcohol is thick".
The can't-go of 2nd-Crawl is "You can go east or west... well, only west, it seems... or up through the hatch."
Check going east in the 2nd-Crawl:
instead try entering the 2nd-crawl-fracture.
The 2nd-crawl-fracture is a prominent-scenery fracture in the 2nd-Crawl.
The initial appearance is "[2nd-crawl-fracture-initial]".
The description is "It looks just like the fractures in the lab above: a plane of cleavage, cracked through the air, blocking the crawlway to the east."
To say 2nd-crawl-fracture-initial:
say "To the east, the crawlspace is interrupted by another fracture -- or perhaps the same one you saw in the lab";
if Ch1-Grafter is in 2nd-Crawl:
say ". [meet Ch1-Grafter]But this is different";
if reset-counter is zero:
say ": you can see a figure caught behind the fracture. You peer closer in the gloom...[para]That's Lieutenant Anderes, apparently frozen mid-step. What's she doing down here? And why is she carrying an alchemical reagent jar";
say question-mark;
stop;
say "; you can see Lieutenant Anderes caught behind the fracture, holding a reagent jar";
say period.
Section - Mech-Crawl
The Mech-Crawl is a recallable low-ceilinged room. The printed name is "Mech Lab Crawlspace".
Rule for printing the name of the Mech-Crawl while asking which do you mean: say "Lab Crawlspace". [We can't accept "mech" as a synonym, so we'll keep the disambiguation simple.]
The zone is the lab-crawl-zone.
The recall-minor is true.
Understand "crawl", "crawlspace", "crawlway", "lab", "laboratory" as the Mech-Crawl.
The Mech-Crawl is west of the 2nd-Crawl.
The description of Mech-Crawl is "The crawlspace runs west and east from here. There's another [if mech-hatch is closed]closed[else]open[end if] hatch above you[if mech-hatch is dirty]. It's even rustier than the last one[end if].[para]To the south, a few steps lead down to a dark doorway."
The can't-go of Mech-Crawl is "You can go west, east, up, or south."
Check going south in the Mech-Crawl:
instead try going down.
Report going when the door gone through is the void-door and the location is the Void-Room:
say "You step through the doorway, feeling blindly downward with your foot for the invisible floor..."
The void-door is an open scenery door. The printed name is "doorway".
The void-door is not openable.
The void-door is below the Mech-Crawl.
Understand "door", "doorway", "dark", "step", "steps", "stair", "stairs" as the void-door.
The description of the void-door is "The doorway is dark. Very dark. Pitch-dark. The crawlspace is [if Pneuma is not fixed]poorly-lit[else]well-lit[end if], but beyond the doorway no light seems to fall at all."
Check searching the void-door:
instead try examining the void-door.
Check opening the void-door:
instead say "It's just an open doorway -- no door there."
Check closing the void-door:
instead say "It's just an open doorway -- no door there."
Check climbing the void-door:
instead try going down.
Check taking the void-door:
tutor tut-take-void-stairs;
instead say "The doorway is built into the wall."
Check inspecting the void-door with the oculus:
instead say "The oculus shows the dark doorway as associated with time."
Section - Void-Room
The Void-Room is a recallable reset-room.
The near-room is the Mech-Crawl.
Understand "void", "reset", "restart", "start" as the Void-Room.
The Void-Room is below the void-door.
The description of Void-Room is "[Void-Room-desc]".
To say Void-Room-desc:
if the reset-counter is zero:
say "Something is wrong. Something is missing.[para]You are adrift, without referents. You never found the floor. You can't remember where it was supposed to be.[para]Something is drawing you in";
else:
say "You drift outside the world again";
say period.
Every turn when the location is a reset-room (this is the reset when in the void rule):
invoke reset.
Section - Herb-Crawl
The Herb-Crawl is a low-ceilinged room. The printed name is "Crawlspace Bend".
The zone is the lab-crawl-zone.
The Herb-Crawl is west of the Mech-Crawl.
The description of the Herb-Crawl is "The crawlway bends here, running from east to north. Another hatch is set into the floor; [if herb-hatch is open]this one is already open[else]it is closed[end if]."
The can't-go of the Herb-Crawl is "You can go east, north, or down through the hatch."
Check going up in Herb-Crawl:
instead say "There's no overhead hatch here."
Report going when the door gone through is the herb-hatch:
if the location is the Herbarium:
say "You climb down through the hatch.";
else:
say "You climb up the ladder and through the hatch."
The initial appearance of the sh-super-rust-remover is "A moldy sheet of paper is lying here. It looks like another alchemical recipe."
Section - Herbarium
The Herbarium is a recallable room. The printed name is "Herbarium Nook".
The zone is the herbarium-zone.
The Herbarium is not lamp-enabled.
Understand "nook" as the Herbarium.
The description of the Herbarium is "[Herbarium-desc]".
To say Herbarium-desc:
say "You are in the [Retort's] herb-house. [if not bool initial-marriage](Odd to reach it from the sub-basement; you usually come here through the [em]upper[/em] laboratory floor. But that's a marcher for you.) [end if]A short ladder leads up to the ceiling hatch through which you entered";
say ".[para]You [if not bool initial-marriage]seem to be[else]are[end if] trapped in the east corner of the greenhouse. The main space, with its trays of sun-lit herbs and vines, is blocked off by another fracture[if a not handled thing is on the herb-shelf]. Only a few bits of herbage remain within reach[end if]";
say ".[para]A shelf holds a small bin labelled 'mustard seed'[if the herb-shelf is non-empty]. Next to the bin [is-are a list of things *in the herb-shelf roomily][end if]";
say period.
For room-visiting the Herbarium:
mark g-herb-hatch as done;
now the mustard is ever-seen.
The aroma-description of the Herbarium is "You can smell green plants and warm moist soil. You've always liked the atmosphere of this place".
The can't-go of the Herbarium is "With the rest of the herb-house blocked off, your only exit is back up the ladder."
Check going west in the Herbarium:
instead try entering the herb-fracture.
The herb-shelf is a prominent-scenery supporter in the Herbarium. The printed name is "herb shelf".
Understand "shelf", "shelves", "herb", "herbage", "bits", "bits of" as the herb-shelf.
Rule for writing a paragraph about the herb-shelf:
now the herb-shelf is mentioned;
["everything" sucks]
repeat with T in raw contents of the herb-shelf:
now T is mentioned;
Check examining the herb-shelf:
instead say "The shelf contains a small bin labelled 'mustard seed'[if the herb-shelf is non-empty], along with [a list of things *in the herb-shelf roomily][end if]."
Check searching the herb-shelf:
instead try examining the herb-shelf.
The mustard-supply is in the Herbarium. [Not actually on the herb-shelf.]
The initial appearance of the zafranum is "You notice a few orange threads lying in a crack in the floor."
Check examining the undiscovered zafranum:
now the zafranum is discovered;
instead say "These look like -- yes -- it's a small quantity of orange zafranum, an extraordinarily expensive spice. Whoever spilled this was [em]very[/em] careless."
Report taking the not handled zafranum:
say "You gather up the orange threads";
if the zafranum is undiscovered:
now the zafranum is discovered;
say ".[para]These look like -- yes -- it's a small quantity of orange zafranum, an extraordinarily expensive spice. Whoever spilled this was [em]very[/em] careless";
instead say "."
The herb-hatch is a crawl-hatch.
The opening-goal is g-herb-hatch.
The pull-side is the Herb-Crawl.
The refer-name is "Herbarium hatch".
The herb-hatch is above the Herbarium and below the Herb-Crawl.
Check examining the herb-hatch:
let dir be the direction of the noun from the location;
if dir is up:
say "A few ladder rungs lead up to the service hatch, which is set into the roof";
else:
say "It's just another service hatch in the floor";
if the noun is closed:
say ". The panel is closed";
else:
say ". The panel is open, but you can't see much on the other side";
instead say "."
The herb-ladder is scenery in the Herbarium. The printed name is "ladder".
Understand "short", "ladder", "rung", "rungs" as the herb-ladder.
Check examining the herb-ladder:
instead try examining the herb-hatch.
Check entering the herb-ladder:
instead try going up.
Check climbing the herb-ladder:
instead try going up.
Check taking the herb-ladder:
instead say "The ladder rungs are fastened to the wall."
The herb-fracture is a fracture in the Herbarium.
The herb-greenhouse is a far-sight in the Herbarium. The printed name is "greenhouse".
The description is "The greenhouse is a lovely wide space, lit by beams of sunlight slanting down from windows above. Trays of foliage, blossoms, and vines bask everywhere.[para]Unfortunately, it's all on the other side of a fracture. You can't reach any of it."
The reach-reason is "The fracture to the west blocks you from the main greenhouse."
Understand "greenhouse", "herb-house", "house", "main", "space" as the herb-greenhouse.
The herb-foliage is a far-sight in the Herbarium. The printed name is "foliage".
The description is "The greenhouse is filled with plants of every description. You've spent many hours pruning and planting there as part of your alchemical training."
Understand "trays", "trays of", "foliage", "blossom", "blossoms", "vine", "vines", "plant", "plants", "herb", "herbs" as the herb-foliage.
The herb-sunlight is a far-sight in the Herbarium. The printed name is "sunlight".
The description is "The greenhouse is not lit by sophic lanterns, but by skylights that open onto Helian lands. Beams of sunlight lance down from a dozen different cloudless skies."
The reach-reason is "Beams of sunlight illuminate the greenhouse, but none are angled to shine across the fracture. This corner of the space is in shadow."
Understand "beam", "beams", "ray", "rays", "light", "sun", "sunlight", "skylight", "skylights", "window", "windows", "helian", "land", "lands", "sky", "skies" as the herb-sunlight.
The lens-view of the herb-sunlight is "Helian lands".
Section - Chem-Crawl
The Chem-Crawl is a low-ceilinged room. The printed name is "Chem Lab Crawlspace".
The zone is the lab-crawl-zone.
The Chem-Crawl is north of the Herb-Crawl.
The description of the Chem-Crawl is "The crawlspace ends here. The only way back is to the south[if the Chem-Lab is unvisited]. You're pretty sure that you're under the Chymic Lab now[end if].[para]You see one last hatch in the ceiling[if the chem-hatch is locked]. This one is not rusted in the slightest. In fact, it looks like someone recently oiled it. Unfortunately, whoever it was also affixed a heavy brass lock[else if the chem-hatch is closed]. The hatch is closed, but unlocked[else]. It's unlocked and standing open[end if]."
The initial appearance of the lubanja is "[if not chapter-0-done]Another stray flask is sitting on the ground. This one is labelled 'lubanja'[else]A flask of lubanja is sitting on the ground[end if]."
Understand "stray" as the lubanja when the lubanja is not handled.
The can't-go of the Chem-Crawl is "The only two ways out are south, or up through the hatch."
Section - Chem-Lab
The Chem-Lab is a recallable room. The printed name is "Chymic Lab".
The description is "[Chem-Lab-desc]".
The zone is the chem-lab-zone.
Understand "chem", "chymic", "chemistry", "lab", "laboratory" as Chem-Lab.
To say Chem-Lab-desc:
say "This wide room is dominated by a huge glass retort";
let N be the number of things in the retort; [the reservoir counts here]
if rstate is not active and N <= 1 and the reservoir comprises no-subst:
say ". You've practiced many chymical rituals in this apparatus. Hanging above the retort is an instructional sign";
if the burner is alight:
say ". The gas burner beneath the retort is alight";
else:
if rstate is active:
say ". Its bound is active, glowing [colorly of the env of rstate]";
if the burner is alight:
say ". The gas burner beneath the retort is alight";
if N <= 1:
if the reservoir does not comprise no-subst:
say ". The retort contains a quantity of [substance of the reservoir]";
else:
if the reservoir comprises no-subst:
say ". Lying in the retort [if N is 2]is[else]are[end if] [a list of not scenery things *in the retort]";
else:
say ". Lying in the retort [if N is 2]is[else]are[end if] [a list of not scenery things *in the retort], suspended in a quantity of [substance of the reservoir]";
if the fake-chem-door is in Chem-Lab:
say ".[para]The lab door [if fake-chem-door is closed]to the east is closed[else]stands open to the east, revealing a murky Thalassan seascape[end if]";
else:
say ".[para]The lab door to the east now opens onto the hallway, as it used to";
say ". The only other exit is the hatch in the floor, which is [if chem-hatch is open]open[else]closed[end if]";
say period.
For room-visiting the Chem-Lab:
[No reason to wait for the player to read the sign.]
mark the hermetic-seal-word as known.
The can't-go of the Chem-Lab is "[if fake-chem-door is undiscovered or fake-chem-door is not in Chem-Lab]The door is east, and the hatch is down[else]With the door blocked, the only way out is down[end if]."
The aroma-description of the Chem-Lab is "The laboratory smells faintly of every compound that's ever fumed, smoked, burned, or boiled here".
Check going east in the Chem-Lab when the fake-chem-door is in Chem-Lab:
instead try entering the fake-chem-door.
The retort is in the Chem-Lab.
The sign-chem-lab is readable scenery in the Chem-Lab. The printed name is "instructive sign".
The description is "The sign reads: 'Remember! Every chymical ritual begins in the retort, and each begins with the Hermetic Sealing!' This sovereign formula is spelled out below, with instructive accent marks.[para]You've survived many tedious lectures in this room by staring blankly at this sign. It hangs right over where the rector likes to stand, and its quirks of calligraphy are always more interesting than his somnolent drone[first time].[para]Just to be sure, though, you memorize the Hermetic sealing word again[only]."
Understand "instructive", "instruction", "sign" as the sign-chem-lab.
Check taking the sign-chem-lab:
instead say "The sign is nailed to the wall. Besides, why deprive the next generation of student alchemists?"
The fake-chem-door is a syn-gap-door in the Chem-Lab. The printed name is "lab door".
The examine-target is the chem-lab-landscape.
The refer-name is "Chymic Lab door".
Understand "door", "lab", "laboratory" as the fake-chem-door.
Understand "corridor", "hall", "hallway" as the fake-chem-door when the fake-chem-door is open.
Check opening the fake-chem-door when the fake-chem-door is closed:
now the fake-chem-door is open;
if the fake-chem-door is undiscovered:
now the fake-chem-door is discovered;
instead say "You pull the door open.[para]This door is no better than the last. You look out over a Thalassan land: thick grey waves heaving beneath a lowering brown sky. Fortunately, another fracture protects you from its no-doubt toxic airs.";
else:
instead say "You open the door again. The murky, toxic ocean is still out there."
Check closing the fake-chem-door when the fake-chem-door is open:
now the fake-chem-door is closed;
instead say "You shut the door on the Thalassan world."
The chem-lab-landscape is a far-sight in the fake-chem-door. The printed name is "Thalassan land".
Understand "thalassan", "land", "landscape", "seascape", "ocean", "sea", "wave", "waves", "thick", "grey", "gray" as the chem-lab-landscape.
The reach-reason is "The fracture blocks the ocean from you."
The description is "No land is visible in a Thalassan land; the world outside is water. Or some liquid -- you doubt you could drink it. The waves are slow and oil-thick. Bands of brown haze drift above them, beneath an impenetrable murky sky."
Check inspecting the chem-lab-landscape with the planetary-lens:
instead say "The lens displays the landscape's Thalassan nature."
The chem-lab-sky is a far-sight in the fake-chem-door. The printed name is "brown atmosphere".
The reach-reason is "The fracture blocks the ocean from you."
Understand "lowering", "brown", "sky", "skies", "murk", "murky", "toxic", "airs", "atmosphere" as the chem-lab-sky.
The description is "A few Thalassan lands have breathable air, but you doubt this murk-shrouded prospect is one of them."
The chem-fracture is a fracture in the fake-chem-door.
The description is "It's another crack in the air, just beyond the lab door. On the other side, grey waves roll endlessly past."
The chem-rack is a prominent-scenery supporter in the Chem-Lab. The printed name is "rack".
Understand "supply", "supplies", "rack" as the chem-rack.
Rule for writing a paragraph about the chem-rack:
let N be the number of things on the chem-rack;
now the chem-rack is mentioned;
if N is zero:
do nothing;
else if N is one:
say "[A first thing held by the chem-rack roomily] rests on a supply rack.";
else:
say "A supply rack holds [a list of things *in the chem-rack roomily]";
if N is the number of chem-flasks on the chem-rack:
say ", neatly lined up";
say "."
Check taking the chem-rack:
say "The rack is fastened to the wall";
if the chem-rack is not empty:
say ". (Or did you mean to take one of the items on the rack?)";
else:
say ".";
stop the action.
Check inserting something into the chem-rack:
instead try putting the noun on the chem-rack.
Definition: a paper-sheet is chem-sheet-pair if it is sh-chem-lab-1 or it is sh-chem-lab-2.
Rule for writing a paragraph about a chem-sheet-pair paper-sheet:
if sh-chem-lab-1 is in the location and sh-chem-lab-2 is in the location:
say "Two papers, [a sh-chem-lab-1] and [a sh-chem-lab-2], are lying here.";
else if sh-chem-lab-1 is in the location:
say "[A sh-chem-lab-1] of paper is lying here.";
else if sh-chem-lab-2 is in the location:
say "[A sh-chem-lab-2] of paper is lying here."
The chem-hatch is a lockable crawl-hatch.
The opening-goal is g-chem-hatch.
The pull-side is Chem-Lab.
The refer-name is "Chymic Lab hatch".
The chem-hatch has a number called the lock-counter.
Understand "brass", "lock", "dial", "heavy", "planetary", "combination" as chem-hatch.
The chem-hatch is above the Chem-Crawl and below the Chem-Lab.
Check examining the chem-hatch when the chem-hatch is locked:
if the location is the Chem-Lab:
instead say "The service hatch in the floor is closed, and presumably still locked.";
instead say "The brass lock is a common planetary combination affair. It's jammed through a hole drilled in the hatch coaming, though, and that can't possibly be Service standard. Somebody added this, and fairly recently, it appears."
Check examining the chem-hatch when the chem-hatch is unlocked and the location is the Chem-Crawl:
instead say "The brass lock is now unlocked, though still wedged into the lip of the hatch. The hatch itself is [if chem-hatch is open]open[else]still closed[end if]."
Check inspecting the chem-hatch with the planetary-lens:
instead say "You peer at the combination lock through the lens, and a sequence becomes visible: Mars, the Moon, Jupiter."
Check recalling the chem-hatch when the chem-combo-note is known:
[Might come up if the player types "recall combination" when the hatch is in scope.]
instead say "You recall the note that refers to the combination lock. [description of chem-combo-note][br]".
Check taking the chem-hatch:
instead say "The lock is jammed through the edge of the hatch[if the chem-hatch is locked] and locked[else]; you can't remove it, even when it's unlocked[end if]."
Check pushing the locked chem-hatch when the location is the Chem-Crawl:
instead say "You rattle the hatch against its lock."
Check pulling the locked chem-hatch when the location is the Chem-Lab:
instead say "You rattle the hatch against its lock."
Check opening the locked chem-hatch:
if the location is the Chem-Lab:
instead say "You can't unlock the hatch from above. The lock is down underneath.";
if g-chem-hatch is ever-done:
goal-perform g-chem-hatch;
if the chem-hatch is open:
say "You open the hatch.";
stop the action;
tutor tut-open-combo-lock;
instead say "The lock dial is inscribed with the astrological planets, in the familiar European tradition."
Check locking the locked chem-hatch with:
instead say "The combination lock is already locked."
Check locking the unlocked chem-hatch with:
if the location is the Chem-Lab:
instead say "You can't lock the hatch from above.";
if the chem-hatch is open:
instead say "The hatch isn't closed.";
now the lock-counter of the chem-hatch is zero;
now the chem-hatch is locked;
instead say "(It's a combination lock, not a key lock.) You give it a few twists."
Check unlocking the unlocked chem-hatch with:
instead say "The combination lock is already unlocked."
Check unlocking the locked chem-hatch with:
if g-chem-hatch is ever-done:
tutor tut-just-open-it with the chem-hatch;
instead say "It's a combination lock, not a key lock."
Check turning the locked chem-hatch:
instead try opening the chem-hatch.
Check turning the unlocked chem-hatch:
if the location is the Chem-Lab:
instead say "You can't lock the hatch from above.";
if the chem-hatch is open:
instead say "The hatch isn't closed.";
now the lock-counter of the chem-hatch is zero;
now the chem-hatch is locked;
instead say "You give the lock a few twists, re-locking it."
Check vague-setting the chem-hatch:
instead try turning the chem-hatch;
Check setting the chem-hatch to:
if the location is the Chem-Lab:
instead say "You can't [if chem-hatch is locked]unlock[else]lock[end if] the hatch from above.";
if the chem-hatch is open:
instead say "The hatch isn't closed.";
if the chem-hatch is unlocked:
now the chem-hatch is locked;
now the lock-counter of the chem-hatch is zero;
say "You re-lock the combination lock.[para]";
if the topic understood unlocks the chem-hatch via chem-hatch-checking:
now the g-chem-hatch is ever-done; [yes, earlier than usual for door goals]
say "The lock snaps open.";
now the chem-hatch is unlocked;
stop the action.
To decide what number is chem-hatch-check (L - lock-symbol) (this is chem-hatch-checking):
if L is no-lock-symbol:
decide on 3;
if L is not common-planet-symbol:
decide on -2;
if L is Pluto-ls:
decide on -2;
if L is:
-- mars-ls: decide on 0;
-- luna-ls: decide on 1;
-- jupiter-ls: decide on 2;
-- otherwise: decide on -1.
To refuse the combination for (T - chem-hatch) with (newsnip - snippet) and (L - lock-symbol) and (isnumber - truth state):
if L is Pluto-ls:
say "This is a cheap lock, with only the eight old-fashioned astrological planets. (Of course [em]really[/em] new locks wouldn't have Pluto either, not since the Imperial Society got through with it. But really new locks wouldn't be cheap eight-setting models anyhow.)";
else if newsnip matches "[number]":
say "The lock is set in planets, not numbers.";
else:
say "The lock has no '[newsnip]' setting."
Section - Mech-Lab
The Mech-Lab is a recallable room. The printed name is "Mechanica Lab".
Understand "mech", "mechanica", "mechana", "lab", "laboratory" as Mech-Lab.
The zone is the mech-lab-zone.
The description of the Mech-Lab is "[Mech-Lab-desc]".
To say Mech-Lab-desc:
say "This workshop features two of the more mundane devices of the alchemist's life: a hand-cranked wire-drawer, and the wire-splicer wheel";
let M be the number of things in the wire-drawer;
let N be the number of things in the wire-splicer;
if M is not zero and N is not zero:
say ". The drawer contains [a list of things *in the wire-drawer]; the splicer contains [a list of things *in the wire-splicer]";
else if M is not zero:
say ". [A list of things *in the wire-drawer] [has-have M] been fed into the wire-drawer";
else if N is not zero:
say ". [A list of things *in the wire-splicer] [has-have N] been fed into the wire-splicer";
say ".[para]";
if mech-door is dirty:
say "The lab door is to the north, but it's crusted over with some horrible-looking mold[period][first time] (What's [em]happened[/em] here[question-mark])[only]";
else if mech-door is closed:
say "The lab door to the north is clean now, but still closed[period]";
else:
say "The lab door to the north is open[period]";
say " The crawlway hatch[if mech-hatch is dirty] is rusted shut[else if mech-hatch is closed] is closed[else] is open[end if]. You also see a small storeroom to the west";
say period.
The aroma-description of the Mech-Lab is "You detect mold in the air, and a trace of metal dust".
The can't-go of the Mech-Lab is "The exits are north, west, and down[if the mech-door is dirty]. But the door to the north is blocked[end if]."
For room-visiting the Mech-Lab:
[This terrible hack ensures that the game stays playable if the player avoids the Void-Room in chapter 0. For continuity we should really display some sort of message, but I think this is a slim enough contingency to let slide.]
now the Void-Room is visited.
The mech-hatch is a crawl-hatch.
The opening-goal is g-mech-hatch.
The pull-side is Mech-Lab.
The refer-name is "Mechanica Lab hatch".
The mech-hatch can be ever-tried. [saturation has failed; not resettable]
The mech-hatch is below the Mech-Lab. The mech-hatch is above the Mech-Crawl.
Check examining the mech-hatch when the mech-hatch is dirty:
let dir be the direction of the noun from the location;
say "It's another service hatch, leading to [if dir is up]another lab[else]the crawlway[end if]. But if the last hatch was rusty, this one is a disaster -- the bolts are indistinct lumps of corrosion";
if dir is up and the Mech-Lab is unvisited:
say ".[para]If you have your bearings right, the Mechanica Lab is above you";
instead say "."
Check opening the mech-hatch when the mech-hatch is dirty:
if g-mech-hatch is ever-done:
goal-perform g-mech-hatch;
if the mech-hatch is open:
say "You open the hatch.";
stop the action;
instead say "This hatch is even rustier than the first one. The bolts won't turn at all."
Check tapping the steel-bolt on the mech-hatch when the mech-hatch is dirty and the symbol-type of the steel-bolt is some-saturation-symbol:
say "You carefully lay the [symbol-type of the noun] symbol against [the second noun]";
if the symbol-type of the steel-bolt is saturation-symbol:
uninscribe the steel-bolt;
now the mech-hatch is ever-tried;
instead say ". The symbol discharges with a muted buzzing sound. Sparks fly from the bolts, and a bit of rust sifts down, but the charge doesn't seem to be sufficient this time. This hatch is going to require something stronger.";
uninscribe the steel-bolt;
now the mech-hatch is clean;
instead say ". The symbol discharges. Orange sparks crackle everywhere, nearly singeing your fingers. For a moment you think this inscription will fail[if the mech-hatch is ever-tried] as well[end if] -- but rust rains down, and the bolts slowly emerge from their corrosion. By the time the energy has cleared, the hatch is as good as new."
Check tapping the brass-pin on the mech-hatch when the mech-hatch is dirty and the symbol-type of the brass-pin is gensaturation-symbol:
say "You carefully lay the [symbol-type of the noun] symbol against [the second noun]";
uninscribe the brass-pin;
now the mech-hatch is clean;
instead say ". The symbol discharges. Orange sparks crackle everywhere, nearly singeing your fingers. For a moment you think this inscription will fail[if the mech-hatch is ever-tried] as well[end if] -- but rust rains down, and the bolts slowly emerge from their corrosion. By the time the energy has cleared, the hatch is as good as new."
Check repairing the dirty mech-hatch:
instead say "The question is, how."
Check putting alcohol on the dirty mech-hatch:
instead try tapping alcohol on the mech-hatch.
Check tapping alcohol on the dirty mech-hatch:
instead say "You splash some alcohol onto the hatch, but it doesn't seem to cut the rust."
Check putting lubanja on the dirty mech-hatch:
instead try tapping lubanja on the mech-hatch.
Check tapping lubanja on the dirty mech-hatch:
instead say "You splash some lubanja onto the hatch, but it doesn't seem to cut the rust."
The mech-door is a lockable scenery door. The printed name is "pine Mechanica door".
The opening-goal is g-mech-door.
The pull-side is the Lab-Hall-SW.
The refer-name is "Mechanica Lab door".
The mech-door can be clean or dirty.
Understand "pine", "door", "mechanica", "mechana", "mech", "stain", "stained", "grey", "gray" as the mech-door.
Understand "mold", "mould", "fungus", "lumpy", "crust", "crusty", "crusted", "encrusted", "encrustation", "green", "greenish", "swath" as the mech-door when the mech-door is dirty.
The mech-door is north of the Mech-Lab. The mech-door is south of Lab-Hall-SW.
Check examining the mech-door when the mech-door is dirty:
if the location is the Mech-Lab:
instead say "A lumpy, greenish-grey swath is crusted down the wall and across the door. It looks like some kind of mold. You have no idea what could have caused such a growth in a well-maintained marcher... but this room doesn't look so well-maintained as it did yesterday.";
else:
instead say "You can see greenish-gray mold creeping through the hinges."
Check examining the mech-door:
if the location is the Mech-Lab:
say "[The mech-door] is still stained grey, but the mold is gone";
else:
say "[The mech-door] doesn't look so bad from this side";
if the mech-door is open:
say ". The door is open";
else:
say ". The door is closed";
instead say "."
Check taking the mech-door when the mech-door is dirty:
instead say "The mold, the door, and the frame are all stuck together."
Check touching the mech-door when the mech-door is dirty:
instead say "The mold, or whatever it is, is dry and hard. Better than slimy and nasty, you think, but you can't just brush it off the door either."
Check rubbing the mech-door when the mech-door is dirty:
instead try touching the mech-door.
Check smelling the mech-door:
instead say "The door smells faintly musty."
Check tasting the mech-door:
instead say "The door tastes faintly musty. (You hope that wasn't a bad idea.)"
Check unlocking the mech-door with the fungicide:
instead try putting the fungicide on the mech-door.
Check opening the mech-door when the mech-door is dirty:
if g-mech-door is ever-done:
goal-perform g-mech-door;
if the mech-door is open:
say "You open the door.";
stop the action;
instead say "The encrustations of mold prevent the door from opening."
Report topically-applying the fungicide to the mech-door:
if the mech-door is clean:
instead say "You splash more fungicide onto the door, but the wood is as clean as it's going to get.";
now the mech-door is clean;
instead say "You splash the fungicide onto the door. The mold bubbles and shrivels away, leaving the wood clean -- well, only a bit stained. The hinges seem to be clear now, anyway."
Check repairing the dirty mech-door:
instead say "The question is, how."
Check putting a nontopical chem-source on the dirty mech-door:
instead try tapping the noun on the mech-door.
Check tapping a nontopical chem-source on the dirty mech-door:
instead say "You sprinkle some [short-description of noun] onto the door, but it doesn't affect the mold at all."
The wire-drawer is in the Mech-Lab.
The wire-splicer is in the Mech-Lab.
The mech-cabinet is a prominent-scenery standard-cabinet in the Mech-Lab.
The opening-goal is g-mech-cabinet.
Understand "hinge", "hinges" as the mech-cabinet.
The mech-cabinet can be clean or dirty.
Understand "corroded", "corrosion" as the mech-cabinet when the mech-cabinet is dirty.
Understand "clean" as the mech-cabinet when the mech-cabinet is not dirty.
Rule for writing a paragraph about the mech-cabinet:
if the mech-cabinet is closed:
if the mech-cabinet is dirty:
say "An extremely corroded cabinet is fastened to the wall. It is closed";
else:
say "A clean cabinet is fastened to the wall; it is closed";
else:
say "A clean cabinet is fastened to the wall. It is open";
if the mech-cabinet is empty:
say ", but empty";
else:
say "; inside you see [a list of things *in the mech-cabinet roomily]";
instead say "."
Check examining the mech-cabinet:
if the mech-cabinet is closed:
if the mech-cabinet is dirty:
say "The cabinet looks strangely dingy; the metal surface is pitted, and the hinges are a swollen mass of corrosion. Very strange. The cabinet was fine yesterday, and you'd have bet that it was rust-proof to begin with. Half the marcher's fittings are made from this alloy";
else:
say "The cabinet is clean now, but still closed";
else:
say "The cabinet is a squarish compartment of some anonymous alloy. It is open";
if the mech-cabinet is empty:
say ", but empty";
else:
say ".[para]Inside you see [a list of things *in the mech-cabinet roomily]";
instead say "."
Check touching the dirty mech-cabinet:
instead say "The cabinet feels somewhat pitted and rough."
Check rubbing the dirty mech-cabinet:
instead say "You rub at the cabinet, but the corrosion doesn't flake off. It's not rust, clearly."
Check opening the dirty mech-cabinet:
if g-mech-cabinet is ever-done:
goal-perform g-mech-cabinet;
if the mech-cabinet is open:
say "You de-corrode and open the cabinet";
if the mech-cabinet is empty:
say ", which is empty";
else:
say ", revealing [a list of things *in the mech-cabinet]";
say ".";
stop the action;
instead say "The cabinet won't open. Its hinges are corroded into an immovable mass."
Check tapping the brass-pin on the dirty mech-cabinet when the symbol-type of the brass-pin is gensaturation-symbol:
say "You carefully lay the [symbol-type of the noun] symbol against [the second noun]";
uninscribe the brass-pin;
now the mech-cabinet is not dirty;
mark g-mech-cabinet as done;
now the tool-used of g-mech-cabinet is brass-pin;
instead say ". The symbol discharges; the cabinet vibrates. Corrosion falls away in a dusty shower, leaving the cabinet shiny-clean -- or as shiny as it's ever been, anyhow."
Check tapping the steel-bolt on the dirty mech-cabinet when the symbol-type of the steel-bolt is gensaturation-symbol:
say "You carefully lay the [symbol-type of the noun] symbol against [the second noun]";
uninscribe the steel-bolt;
now the mech-cabinet is not dirty;
mark g-mech-cabinet as done;
now the tool-used of g-mech-cabinet is steel-bolt;
instead say ". The symbol discharges; the cabinet vibrates. Corrosion falls away in a dusty shower, leaving the cabinet shiny-clean -- or as shiny as it's ever been, anyhow."
Check tapping the brass-pin on the dirty mech-cabinet when the symbol-type of the brass-pin is some-saturation-symbol:
say "You carefully lay the [symbol-type of the noun] symbol against [the second noun]";
instead say ". The symbol does not discharge, since the cabinet isn't brass."
Check tapping the steel-bolt on the dirty mech-cabinet when the symbol-type of the steel-bolt is some-saturation-symbol:
say "You carefully lay the [symbol-type of the noun] symbol against [the second noun]";
instead say ". The symbol does not discharge, since the cabinet isn't steel."
Check repairing the dirty mech-cabinet:
instead say "The question is, how."
Check putting a chem-source on the dirty mech-cabinet:
instead try tapping the noun on the mech-cabinet.
Check tapping a chem-source on the dirty mech-cabinet:
say "You sprinkle some [short-description of noun] onto the cabinet";
if the noun is mineral-oil:
instead say ". Sadly, the corrosion is far too serious to be solved by a little lubrication.";
if the noun is muriatic acid or the noun is vitriolic acid:
instead say ". Sadly, this is ordinary acid, not some magical acid that dissolves all metal instantly.";
instead say ", but it doesn't affect the corrosion at all."
The mech-counter is a prominent-scenery supporter in Mech-Lab. The printed name is "counter".
Understand "shelf", "counter", "table" as the mech-counter.
Rule for writing a paragraph about the mech-counter:
let N be the number of things on the mech-counter;
now the mech-counter is mentioned;
if N is zero:
do nothing;
else if N is one:
say "[A first thing held by the mech-counter roomily] is lying on the counter.";
else:
say "To one side, some supplies are lying on a counter: [a list of things *in the mech-counter roomily]."
The initial appearance of the glass-loop is "Something glitters on the floor. It looks like a circle of fine glass thread."
Section - Mech-Store
The Mech-Store is a recallable room. The printed name is "Materials Store".
The zone is mech-lab-zone.
Understand "material", "materials", "store", "storage", "storeroom" as the Mech-Store.
The Mech-Store is west of Mech-Lab.
The description of the Mech-Store is "You are in a small storage area. The Mechanica Lab is back to the east."
The can't-go of the Mech-Store is "The only exit is east."
Check going outside in the Mech-Store:
instead try going east.
The groove-bench is a recallable prominent-scenery ritual-bound in the Mech-Store. The printed name is "adjustable bound".
The short-adjective is "adjustable bound".
[No shelf here either.]
The description is "The table bears a ritual bound, whose edge is an incised groove[if the wire-groove is empty]. The groove is currently empty.[para]This is an adjustable bound, a handy device. By placing a metal wire in the groove, one can set up a ritual of any desired elemental association[else]. The groove contains [a first thing held by the wire-groove], which circumscribes the bound[end if]."
Understand "heavy", "table", "tabletop", "adjustable" as the groove-bench.
Rule for writing a paragraph about the groove-bench:
if the groove-bench is empty-inactive:
now the groove-bench is mentioned;
say "To one side stands a heavy table, upon which is another ritual bound. This one is adjustable";
if the wire-groove is empty:
say "; it is currently empty.";
else:
say "; it has been fitted with [a first thing held by the wire-groove], but the arc is empty.";
stop;
if the wire-groove is non-empty:
say "[A first thing held by the wire-groove] has been laid into the groove on the table. ";
say the visible state of the groove-bench.
Check inserting a metal-wire into the groove-bench:
instead try inserting the noun into the wire-groove.
The wire-groove is a scenery container in the Mech-Store. The printed name is "groove".
Understand "groove", "incised" as the wire-groove.
Check examining the wire-groove:
if the wire-groove is empty:
instead say "The groove contains no wire at the moment.";
instead say "[A first thing held by the wire-groove] lies in the groove, circumscribing the bound."
Check searching the wire-groove:
instead try examining the wire-groove.
Check putting something on the wire-groove:
instead try inserting the noun into the wire-groove.
Check inserting something into the wire-groove when the noun is not a metal-wire:
if the noun is mercury:
instead say "You try to coax the mercury droplet into the groove, but it just rolls off. Surface tension! You give up and scoop the droplet back up.";
if the noun is a chem-source:
instead say "Pouring reagents into the groove would be messy. Stick to wire; that's what it's designed for.";
instead say "The groove in the table is too narrow to accept anything except wire."
Check inserting a metal-wire into the wire-groove when the wire-groove is not empty:
let T be the first thing held by the wire-groove;
instead say "[The T] is already in the groove. Only one wire at a time will fit."
Check inserting a metal-wire into the wire-groove when rstate is active:
instead say "Putting [the noun] into the groove would break the ritual, and probably give you a nasty jolt. Unseal the bound first."
Report inserting something into the wire-groove:
instead say "You carefully press [the noun] into the groove. It forms a complete circuit around the arc."
Check taking a metal-wire when the noun is in the wire-groove and rstate is active:
instead say "Pulling [the noun] out of the groove would break the ritual, and probably give you a nasty jolt. Unseal the bound first."
Report taking a metal-wire when the thing-taken-from is the wire-groove:
instead say "You extract [the noun] from the groove."
Check inspecting the wire-groove with the oculus:
instead try inspecting the groove-bench with the oculus.
The gold-cabinet is a prominent-scenery lockable standard-cabinet in the Mech-Store.
The opening-goal is g-gold-cabinet.
Understand "alchemy", "file", "lock", "clean" as the gold-cabinet.
Rule for writing a paragraph about the gold-cabinet:
say "There's another cabinet here";
if the gold-cabinet is closed:
if the gold-cabinet is locked:
say ". This one is clean, but locked";
else:
say ". It is closed but unlocked";
else:
say ". It is open";
if the gold-cabinet is empty:
say " but empty";
else:
say "; inside [is-are a list of things *in the gold-cabinet roomily]";
instead say "."
Check examining the gold-cabinet:
say "The cabinet is a squarish compartment of some anonymous alloy";
if the gold-cabinet is closed:
if the gold-cabinet is locked:
say ". It is locked with an Alchemy File lock, to keep out nosy low-rankers like yourself. A seal of that File would open it[if the player does not carry the rutilum-seal], if you had one[end if]";
else:
say ". It is closed, but the Alchemy File lock is unlocked";
else:
say ", with an Alchemy File lock. It is wide open";
if the gold-cabinet is empty:
say ", but empty";
else:
say ".[para]Inside you see [a list of things *in the gold-cabinet roomily]";
instead say "."
Check opening the locked gold-cabinet:
if g-gold-cabinet is ever-done:
goal-perform g-gold-cabinet;
if the gold-cabinet is open:
say "You unlock and open the cabinet";
if the gold-cabinet is empty:
say ", which is empty";
else:
say ", revealing [a list of things *in the gold-cabinet]";
say ".";
stop the action;
instead say "The cabinet is locked with an Alchemy File lock."
Check putting a metal-seal on the gold-cabinet:
instead try unlocking the gold-cabinet with the noun.
Check tapping a metal-seal on the gold-cabinet:
instead try unlocking the gold-cabinet with the noun.
Check inspecting the gold-cabinet with the oculus:
instead say "Through the oculus, you perceive the symbolism of the Alchemy File: [symbol-assoc of alchemy-file]."
Check unlocking the gold-cabinet with a clay-mold:
instead say "An inverse impression of a seal isn't the same as a seal."
Report unlocking the gold-cabinet with:
now g-gold-cabinet is ever-done;
now the tool-used of g-gold-cabinet is the second noun;
instead say "You touch [the second noun] to the cabinet, and the lock snaps complaisantly open."
Report locking the gold-cabinet with:
instead say "You lock the cabinet again, using [the second noun]."
Lock-matching rule for the gold-cabinet when key-param is a metal-seal:
if the file of key-param is alchemy-file:
rule succeeds;
else:
rule fails.
The materials-bin is a prominent-scenery container in Mech-Store. The printed name is "storage bin".
Understand "storage", "bin", "untidy" as the materials-bin.
Rule for writing a paragraph about the materials-bin:
let N be the number of things in the materials-bin;
now the materials-bin is mentioned;
if N is zero:
do nothing;
else if N is one:
say "A storage bin contains [a first thing held by the materials-bin roomily].";
else:
say "An untidy storage bin contains [a list of things *in the materials-bin roomily]."
Check taking the materials-bin:
instead say "The bin is screwed down. Besides, why lug a bulky bin all over the place?"
Check examining the materials-bin:
if the materials-bin is empty:
say "The storage bin is empty";
else:
say "You see [a list of things *in the materials-bin roomily] in the bin";
instead say "."
Check searching the materials-bin:
instead try examining the materials-bin.
The initial appearance of the H-chime is "Someone has dropped a standard glass chime, the sort used in musical rituals. It's marked as being in the key of H."
The initial appearance of the sh-gen-rust-remover is "A crumpled recipe sheet is lying by the ritual bound."
Chapter - Other Labs
Section - Four Lab Hallways
The Lab-Hall-SW is a room. The printed name is "Lab Hall Southwest".
The zone is lab-hall-zone.
The description is "This is the southwest corner of the laboratory access hallway. It's done up in rough wallpaper, faintly scruffy and very familiar[first time] -- these halls are the center of your student life[only]. The hall runs north and east from here.[para]To the south, the door to the Mechanica Lab is [if mech-door is open]open[else]closed[end if]. The Chymic Lab door is to the west; it's [if the fake-door-SW is in Lab-Hall-SW]closed[else]open[end if]. The lab stairwell opens to the northeast, but a fracture prevents entry."
Understand "sw-lab-hall" as Lab-Hall-SW.
The can't-go of Lab-Hall-SW is "The hall runs north and east. The Mechanica Lab is south, the Chymic Lab is west, and the stairwell is northeast."
Check going west in Lab-Hall-SW when the fake-door-SW is in Lab-Hall-SW:
instead try opening the fake-door-SW.
Check going northeast in the Lab-Hall-SW:
instead try entering the stairwell-fracture-SW.
The initial appearance of the sh-oculus is "A sheet of paper lies discarded in the hall.[first time][para][sarge]A swabbie out of the lab is like a fish out of the sea.[/sarge][para][sarge]Thanks, Sarge, I'll remember that.[/sarge][only]"
The fake-door-SW is scenery in Lab-Hall-SW. The printed name is "oak Chymic door".
Understand "oak", "chem", "chymic", "door" as the fake-door-SW.
The description of the fake-door-SW is "[The item described] is closed.";
Check opening the fake-door-SW:
instead say "The Chymic door won't open; it won't even[if fake-chem-door is discovered] rattle. (You recall the fracture that blocks it on the other side.)[else] rattle.[end if]"
Check entering the fake-door-SW:
instead try opening the fake-door-SW.
Check closing the fake-door-SW:
instead say "That's already closed."
The real-door-SW is a syn-bridge-door. The printed name is "oak Chymic door".
The pull-side is Lab-Hall-SW.
The refer-name is "Chymic Lab door".
Understand "oak", "chem", "chymic", "door" as the real-door-SW.
The real-door-SW is west of Lab-Hall-SW. The real-door-SW is east of Chem-Lab.
The stairwell-fracture-SW is a fracture in the Lab-Hall-SW.
The description is "A fracture blocks the entrance to the central stairwell of the lab wing."
Understand "stairs", "lab", "central" as the stairwell-fracture-SW.
Check climbing the stairwell-fracture-SW:
instead try entering the stairwell-fracture-SW.
The Lab-Hall-NW is a room. The printed name is "Lab Hall Northwest".
The zone is lab-hall-zone.
The description is "The laboratory hallway runs east and south from this junction. Another corridor runs west, towards the rest of the marcher.[para]To the north, the door to the Main Store is [if store-door is open]open[else]closed[end if]."
Understand "nw-lab-hall" as Lab-Hall-NW.
The can't-go of Lab-Hall-NW is "The hallways run east, west, and south. To the north is the Main Store."
The hall-script is prominent-scenery alien-script in Lab-Hall-NW.
The description is "Twisting, involuted strokes of black are scrawled across one wall. The graffito is irregular -- neither artistically symmetrical nor ink-splotch random. But if this is a script, it is utterly foreign to your understanding."
The initial appearance is "[first time]How bizarre! [only][if initial-marriage is not true]Someone has scrawled graffiti[else]Graffiti has been scrawled[end if] on the wall here. The black marks are curiously twisted[if not script-legible]; they hint at meaning, but you cannot read them[else if the radix-pattern is not known]; they hint at meaning, but... wait[else]; they refer to [em]radix access[/em][end if]."
Check examining the hall-script when script-legible:
say "Twisting, involuted strokes of black are scrawled across one wall";
if the radix-pattern is not known:
mark the radix-pattern as known;
say alien-script-understanding about "the root, the entry point, gaining entry";
say " The black marks represent a sequence of geometrical transformations. They mean [em]radix access,[/em] the passage of the root. You stare at them, blinking tears from your eyes, until you have them memorized.";
else:
say ".[para]The pattern means [em]radix access,[/em] the passage of the root.";
stop the action.
The Lab-Hall-SE is a room. The printed name is "Lab Hall Southeast". [South alcove is cut off by fracture]
The zone is lab-hall-zone.
The description is "The laboratory hallway runs north and west from this corner. The Secondary Lab, where you awoke, is to the south; its door is [if the fake-door-SE is in Lab-Hall-SE]closed[else]open[end if]. The door to the Opticks Lab is [if opt-door is open]open[else]closed[end if] to the east."
Understand "se-lab-hall" as Lab-Hall-SE.
The can't-go of Lab-Hall-SE is "The hall runs north and west. The Secondary Alchemy Lab is south, and the Opticks Lab is east."
Check going south in Lab-Hall-SE when the fake-door-SE is in Lab-Hall-SE:
instead try opening the fake-door-SE.
The fake-door-SE is scenery in Lab-Hall-SE. The printed name is "pine Alchemy door".
Understand "pine", "alchemy", "alchemical", "secondary", "door" as the fake-door-SE.
The description of the fake-door-SE is "[The item described] is closed.";
Check opening the fake-door-SE:
instead say "The Alchemy door won't open; it won't even rattle."
Check entering the fake-door-SE:
instead try opening the fake-door-SE.
Check closing the fake-door-SE:
instead say "That's already closed."
The real-door-SE is a syn-bridge-door. The printed name is "pine Alchemy door".
The pull-side is Lab-Hall-SE.
The refer-name is "Secondary Alchemy Lab door".
Understand "pine", "alchemy", "alchemical", "secondary", "door" as the real-door-SE.
The real-door-SE is south of Lab-Hall-SE. The real-door-SE is north of 2nd-Lab.
The Lab-Hall-NE is a room. The printed name is "Lab Hall Northeast".
The zone is lab-hall-zone.
The description is "This is the northeast corner of the laboratory hallway, which runs south and west. The lab stairwell opens to the southwest, but a fracture prevents entry. The Tertiary Lab is to the east; its door is [if 3rd-door is closed]closed[else]open[end if]. The Pyrics Lab door to the north is[if open-property 3rd-door matches fire-door] also[end if] [if fire-door is closed]closed[else]open[end if]."
Understand "ne-lab-hall" as Lab-Hall-NE.
The can't-go of Lab-Hall-NE is "The hall runs south and west. The Tertiary Alchemy Lab is east, the Pyrics Lab is north, and the stairwell is southwest."
Check going southwest in the Lab-Hall-NE:
instead try entering the stairwell-fracture-NE.
The stairwell-fracture-NE is a fracture in the Lab-Hall-NE.
The description is "A fracture blocks the entrance to the central stairwell of the lab wing."
Understand "stairs", "lab", "central" as the stairwell-fracture-NE.
Check climbing the stairwell-fracture-NE:
instead try entering the stairwell-fracture-NE.
Lab-Hall-SW is south of Lab-Hall-NW.
Lab-Hall-SE is south of Lab-Hall-NE.
Lab-Hall-SW is west of Lab-Hall-SE.
Lab-Hall-NW is west of Lab-Hall-NE.
Lab-Hall-SW is wallpaper-enabled.
Lab-Hall-SE is wallpaper-enabled.
Lab-Hall-NE is wallpaper-enabled.
Lab-Hall-NW is wallpaper-enabled.
Section - Opt-Lab
The Opt-Lab is a recallable room. The printed name is "Opticks Lab".
The zone is opt-lab-zone.
The description is "This chamber is dedicated to experiments involving rays of light. A solid block of bluestone forms an immense workbench in the center of the room."
Understand "opticks", "optick", "optics", "optic", "lab", "laboratory" as Opt-Lab.
The Opt-Lab is east of the opt-door. Lab-Hall-SE is west of the opt-door.
The can't-go of the Opt-Lab is "The hallway is to the west, an annex is south, and the closet door is east."
Check going east in the Opt-Lab when the fake-opt-door is in Opt-Lab:
instead try entering the fake-opt-door.
The opt-door is a lockable scenery door. The printed name is "oak Opticks door".
The opening-goal is g-opt-door.
The pull-side is the Lab-Hall-SE.
The refer-name is "Opticks Lab door".
Understand "oak", "door", "opticks", "optick", "optics", "optic" as the opt-door.
The glass-heap is glassy fixed in place in the Opt-Lab. The printed name is "heap of broken glass".
Understand "broken", "shattered", "glass", "shards", "pieces", "pieces of", "heap", "heap of" as the glass-heap.
Understand "mirrors", "lenses", "prisms", "optical", "optickal", "equipment" as the glass-heap.
Understand "disaster", "catastrophe" as the glass-heap.
The description is "Some complex optickal assembly has defenestrated itself off the bench into utter catastrophe. Pieces of lenses, bits of mirror, broken prisms, and shards of who-knows-what lie in a slumped heap on the floor[first time]. You feel at once horrified and relieved that it wasn't your fault[only]."
Rule for writing a paragraph about the glass-heap:
say "Whatever mirrors, prisms, and lenses are supposed to be arranged on the bench are there no longer. The equipment lies shattered on the floor -- all just an inextricable heap of broken glass, now.[para]";
say "The lab's door stands [if opt-door is open]open[else]closed[end if] to the west";
if fake-opt-door is in Opt-Lab:
if fake-opt-door is closed:
say ". A closet door to the east is[if opt-door is closed] also[end if] closed";
else:
say ". Another door to the east is open, revealing an Erebian land where the closet should be";
else:
say ". A closet door to the east is open, revealing a closet";
say ". To the south is a storage annex."
Check taking the glass-heap:
instead say "You'd slice up your fingers, and just wind up with a handful of broken glass anyway."
Check touching the glass-heap:
instead say "Sticking your fingers into broken glass is not your best idea."
Check pushing the glass-heap:
instead try touching the glass-heap.
Check rubbing the glass-heap:
instead try touching the glass-heap.
Check squeezing the glass-heap:
instead try touching the glass-heap.
Check inspecting the glass-heap with the planetary-lens:
instead say "Through the lens, you see a confused glitter of [if the el-earth is part of the glass-heap]Earth and [end if]light."
Check inspecting the glass-heap with the oculus:
instead say "Through the oculus, you see the fragments of some complex ritual, now destroyed."
Check searching the glass-heap:
if the el-earth is part of the glass-heap and the el-earth-location is ever-done:
instead try taking the el-earth;
instead say "You stir the broken glass carefully with your foot, but nothing turns up that doesn't look like more broken glass."
Check looking under the glass-heap:
instead try searching the glass-heap.
Check tasting the glass-heap:
instead say "Do not lick."
Check repairing the glass-heap:
instead say "That is obviously in need of more repair than you can possibly manage."
Check smashing the glass-heap:
instead say "It's thoroughly smashed already!"
Check inserting something into the glass-heap:
if the noun is el-earth:
instead say "You just got the shard [em]out[/em] of the heap.";
instead say "No reason to throw anything in there."
Check putting something on the glass-heap:
if the noun is el-earth:
instead say "You just got the shard [em]out[/em] of the heap.";
instead say "No reason to throw anything in there."
To uncover the el-earth:
now the el-earth is in the location;
set pronouns from the el-earth;
if el-earth-location is ever-done:
say " swinging. The arc angles sharply towards the heap of glass.[para]You move the lodestone slowly over the heap, until the elemental earth is uncovered once again.";
stop;
mark el-earth-location as done;
say " swinging. The arc angles sharply towards the heap of glass.[para]Interesting. You step towards the heap, and move the lodestone slowly over it, keeping an eye on the angle of its swing. Yes -- [em]there;[/em] a shard of crystal which is not broken at all. You nudge it free of the heap. This must be the elemental earth from the experiment."
The initial appearance of the sh-earth-note is "A scrawled sheet lies next to the glass disaster."
The initial appearance of el-earth is "A shard of elemental earth has been moved free of the heap; it's safe to pick up now."
The blue-bench is a scenery supporter in the Opt-Lab. The printed name is "workbench".
Understand "block", "block of", "bluestone", "stone", "solid", "work", "bench", "workbench" as the blue-bench.
Check examining the blue-bench:
say "The bluestone block is an absolutely stable base, intended to support carefully-aligned mirrors and prisms";
if the blue-bench is empty:
say ". Unfortunately it has been swept clean";
else:
say ". It now holds only [a list of things *in the blue-bench roomily]";
instead say "."
Check taking the blue-bench:
instead say "The point of the bluestone block is that no force will ever, ever move it."
Check pushing the blue-bench:
instead try taking the blue-bench.
Check pulling the blue-bench:
instead try taking the blue-bench.
Check entering the blue-bench:
instead say "There's no point climbing on the workbench."
Check climbing the blue-bench:
instead try entering the blue-bench.
The fake-opt-door is a syn-gap-door in the Opt-Lab. The printed name is "closet door".
The examine-target is the opt-lab-landscape.
The refer-name is "Opticks closet door".
Understand "door", "closet" as the fake-opt-door.
Check opening the fake-opt-door when the fake-opt-door is closed:
now the fake-opt-door is open;
if the fake-opt-door is undiscovered:
now the fake-opt-door is discovered;
instead say "You take a deep breath and pull the door open. Once again, a foreign world breaks the [Retort's] familiar boundaries.[para]This time it is an Erebian land -- cracked slabs of ice tilting up above ancient snow.";
else:
instead say "You open the door, revealing starlit ice and snow."
Check closing the fake-opt-door when the fake-opt-door is open:
now the fake-opt-door is closed;
instead say "You shut the door on the Erebian world."
The opt-lab-landscape is a far-sight in the fake-opt-door. The printed name is "Erebian land".
Understand "erebian", "land", "landscape", "snowscape", "ancient", "old", "snow", "snowdrift", "abyss", "abysses", "cracked", "ice", "frost", "slabs", "slabs of" as the opt-lab-landscape.
The reach-reason is "The fracture blocks the snowscape from you."
The description is "The landscape beyond the door is buried in snow. It is old snow, aeons old; it has the faint bands of color that you've heard mark the most ancient of Erebian lands. Blue frost laps over snowdrifts of pale violet, which fall into dim green abysses beneath slabs of ice. Stars hang above, and a brooding red coal of a sun."
Check inspecting the opt-lab-landscape with the planetary-lens:
instead say "The lens displays the landscape's Erebian nature."
The opt-lab-sky is a far-sight in the fake-opt-door. The printed name is "starry sky".
The reach-reason is "The fracture blocks the starry sky from you."
Understand "sky", "skies", "star", "stars", "starry", "red", "coal", "sun", "old" as the opt-lab-sky.
The description is "The sun above the snow is dim, red, shrunken, and old. It is outshone by the stars behind it."
The opt-fracture is a fracture in the fake-opt-door.
The description is "It's another crack in the air, just beyond the closet door. On the other side is a world of ancient snow."
Section - Opt-Store
The Opt-Store is a recallable room. The printed name is "Opticks Annex".
The zone is opt-lab-zone.
The recall-minor is true.
The description is "This is a quiet corner south of the Opticks laboratory. You've spent many hours here with the other scrubs, snatching extra practice time in your spare hours.[para]A round standing table in back is set up for ritual use. A gestalt shelf is fastened above it."
The Opt-Store is south of Opt-Lab.
Understand "opticks", "optick", "optics", "optic", "annex" as Opt-Store.
The can't-go of the Opt-Store is "You can only go north, back to the Opticks Lab."
Check going outside in Opt-Store:
instead try going north.
The opt-bench is a prominent-scenery ritual-bound in the Opt-Store. The printed name is "tabletop bound".
The short-adjective is "tabletop bound".
The description is "The table in the back corner has a functional ritual bound and gestalt shelf[if the opt-bench is empty-inactive]. It is the unofficial province of ensigns and other lowly forms of life, to practice alchemy when the labs are booked[end if]."
Understand "table", "tabletop", "round", "standing" as the opt-bench.
Rule for writing a paragraph about the opt-bench:
if the opt-bench is empty-inactive:
now the opt-bench is mentioned;
stop;
say the visible state of the opt-bench.
The opt-shelf is a ritual-shelf in the Opt-Store.
The description is "You see a small shelf fastened to the wall above the tabletop -- the sort that holds symbolically relevant objects during a ritual[if the opt-shelf is empty]. The gestalt shelf is empty[end if]."
The linked-shelf of the opt-bench is the opt-shelf.
Understand "small" as the opt-shelf.
The opt-store-bin is a prominent-scenery container in Opt-Store. The printed name is "storage bin".
Understand "storage", "bin", "neglected" as the opt-store-bin.
Rule for writing a paragraph about the opt-store-bin:
let N be the number of things in the opt-store-bin;
now the opt-store-bin is mentioned;
if N is zero:
do nothing;
else if N is one:
say "A storage bin contains [a first thing held by the opt-store-bin roomily].";
else:
say "A neglected storage bin contains [a list of things *in the opt-store-bin roomily]."
Check taking the opt-store-bin:
instead say "The bin is screwed down."
Check examining the opt-store-bin:
if the opt-store-bin is empty:
say "The storage bin is empty";
else:
say "You see [a list of things *in the opt-store-bin roomily] in the bin";
instead say "."
Check searching the opt-store-bin:
instead try examining the opt-store-bin.
The initial appearance of the feather is "A white feather has fallen to the floor near the table."
Section - Opt-Closet
The Opt-Closet is a recallable room. The printed name is "Opticks Closet".
The zone is opt-closet-zone.
The recall-minor is true.
The description is "This closet is sometimes used for storage, but the whims of marcher scheduling have left it empty at the moment."
Understand "opticks", "optick", "optics", "optic", "closet" as Opt-Closet.
For room-visiting the Opt-Closet:
mark g-optcloset-door as done.
The can't-go is "The door is west."
Check going outside in the Opt-Closet:
instead try going west.
The real-opt-door is a syn-bridge-door. The printed name is "closet door".
The pull-side is Opt-Lab.
The refer-name is "Opticks closet door".
Understand "door", "closet" as the real-opt-door.
The real-opt-door is east of the Opt-Lab. The real-opt-door is west of the Opt-Closet.
The initial appearance of the dusty-bubble is "In one dusty corner you notice a fist-sized glass bubble, which is rather dusty itself."
Section - 3rd-Lab
The 3rd-Lab is a recallable room. The printed name is "Tertiary Alchemy Lab".
Understand "tertiary", "third", "alchemy", "lab", "laboratory" as 3rd-Lab.
The zone is 3rd-lab-zone.
The description is "This is the [Retort's] fanciest lab, all shiny and new. Of course, the rectors usually have it reserved for fancy shiny work.[para]The center of the room is a dais, built with a ritual arc in bright platinum inlay. The door to the west is [open-closed 3rd-door]."
The can't-go is "The only way out is west."
The aroma-description is "The room even smells new".
Check going outside in the 3rd-lab:
instead try going west.
The 3rd-bench is a prominent-scenery ritual-bound in the 3rd-Lab. The printed name is "catalytic bound".
The short-adjective is "catalytic bound".
The description is "The dais is a catalytic ritual bound, an arc of platinum inlaid directly into the floor. It's the newest, fanciest style of alchemical workmanship, built into the marcher only last year, and you've never, ever gotten a chance to use it -- until today."
Understand "platinum", "bright", "inlay", "inlaid", "catalytic", "dais" as the 3rd-bench.
Rule for writing a paragraph about the 3rd-bench:
if the 3rd-bench is empty-inactive:
now the 3rd-bench is mentioned;
stop;
say the visible state of the 3rd-bench.
Check taking the 3rd-bench:
instead say "The platinum inlay is part of the dais[one of][or]. The dais is part of the floor[stopping]."
The 3rd-door is a lockable scenery door. The printed name is "pine Tertiary door".
The matching key of the 3rd-door is the 3rd-key.
The opening-goal is g-3rd-door.
The pull-side is the Lab-Hall-NE.
The refer-name is "Tertiary Lab door".
Understand "pine", "door", "tertiary" as the 3rd-door.
The 3rd-door is west of the 3rd-Lab. The 3rd-door is east of Lab-Hall-NE.
The description of the 3rd-door is "[The 3rd-door] is [open-closed 3rd-door][if 3rd-door is locked] and locked[end if]."
Check going when the door gone through is the 3rd-door and the 3rd-door is locked and the player carries the 3rd-key:
say "(first unlocking and opening [the 3rd-door], with [the 3rd-key])[command clarification break]";
silently try unlocking the 3rd-door with the 3rd-key;
if the 3rd-door is locked:
stop the action;
silently try opening the 3rd-door;
if the 3rd-door is closed:
stop the action.
Check opening the 3rd-door when the 3rd-door is locked and the player carries the 3rd-key:
say "(first unlocking [the 3rd-door] with [the 3rd-key])[command clarification break]";
silently try unlocking the 3rd-door with the 3rd-key;
if the 3rd-door is locked:
stop the action.
Check opening the 3rd-door when the 3rd-door is locked:
if g-3rd-door is ever-done:
goal-perform g-3rd-door;
if the 3rd-door is open:
say "You open the door.";
stop the action.
Definition: a chem-vial is 3rd-vial-pair if it is anti-Tellurian-dist or it is nickel-filings.
Rule for writing a paragraph about a 3rd-vial-pair not handled chem-vial:
if anti-Tellurian-dist is not handled and nickel-filings is not handled:
now anti-Tellurian-dist is mentioned;
now nickel-filings is mentioned;
say "You notice two vials here: a blue vial labelled 'anti-Tellurian distillate' and a pale-gold vial labelled 'nickel'.";
else if anti-Tellurian-dist is not handled:
now anti-Tellurian-dist is mentioned;
say "You notice a blue vial labelled 'anti-Tellurian distillate'.";
else if nickel-filings is not handled:
now nickel-filings is mentioned;
say "You notice a pale-gold vial labelled 'nickel'."
Section - Fire-Lab
The Fire-Lab is a recallable room. The printed name is "Pyrics Lab".
The zone is fire-lab-zone.
The description is "Waves of heat fill this room, radiating from a massive brick kiln and the roaring gas burners that fire it.[para]The lab door to the south is [if fire-door is open]open[else]closed[end if]. A storage area lies to the east."
Understand "fire", "pyric", "pyrics", "lab", "laboratory" as Fire-Lab.
The Fire-Lab is north of the fire-door. Lab-Hall-NE is south of the fire-door.
For room-visiting the Fire-Lab:
mark g-fire-door as done;
now the cedar is ever-seen.
The can't-go of the Fire-Lab is "The lab door is south, and a storage area is to the east."
The aroma-description of the Fire-Lab is "The air is hot and smells of burnt brick".
The cedar-supply is in the Fire-Lab.
The fire-door is a lockable scenery door. The printed name is "oak Pyrics door".
The opening-goal is g-fire-door.
The pull-side is the Lab-Hall-NE.
The refer-name is "Pyrics Lab door".
Understand "door", "pyrics", "pyric" as the fire-door.
Understand "oak" as the fire-door when the location is the Lab-Hall-NE.
The kiln is in the Fire-Lab.
The kiln-burner is in the Fire-Lab.
The kiln is prominent-scenery.
Rule for writing a paragraph about the kiln:
now the kiln is mentioned;
if the kiln is not empty:
say "Within the kiln, half-obscured by rippling heat, you can see [a list of things *in the kiln roomily].";
stop.
The hall-key is a takeable-thing [in the kiln]. The printed name is "thick key".
Understand "thick", "alloy", "hall key", "key" as the hall-key.
The description of the hall-key is "This is a thick key of some cheap alloy. You recognize the shape -- it's one of the keys used to unlock fire doors in the marcher, after an all-sections drill[if the hall-key is not handled]. Why anybody would have tossed it into the kiln, you have no way to guess[end if]."
The crock is in the Fire-Lab.
The fire-table is a prominent-scenery supporter in the Fire-Lab. The printed name is "table".
Understand "table" as the fire-table.
Rule for writing a paragraph about the fire-table:
now the fire-table is mentioned;
now the crock is mentioned;
say "A table at the other end of the room supports a glass vapor crock";
say ". The crock is [if crock is open]open[else]closed[end if]";
if the crock is empty:
say " and empty";
else:
say "; it contains [a list of things *in the crock roomily]";
say ".[para]You also see a jar of cedar splints on the table";
let N be the number of things on the fire-table;
if N > 0:
if N >= 3 and N is the number of wood-splints on the fire-table:
say ". Next to this are [N in words] splints of assorted woods: ";
begin cheap list for N;
repeat with T running through wood-splints on the fire-table:
say cheap list T with "[short-description of substitution-variable][if substitution-variable is alight] (alight)[end if]";
now T is mentioned;
now T is ever-seen;
end cheap list;
else:
say ". Next to this [is-are a list of things *in the fire-table roomily]";
say "."
Check examining the fire-table:
say "The table supports the vapor crock and a jar of cedar splints";
if the fire-table is not empty:
say ". You also see [a list of things *in the fire-table roomily]";
instead say "."
Check searching the fire-table:
instead try examining the fire-table.
Section - Fire-Store
The Fire-Store is a recallable room. The printed name is "Pyrics Store".
The zone is fire-lab-zone.
The recall-minor is true.
The description is "This is a tangle of storage racks, mostly empty. The Pyrics Lab is to the west.[para]On one rack you notice a jar of camphrost lumps."
Understand "fire", "pyric", "pyrics", "store", "storage", "storeroom" as Fire-Store.
The Fire-Store is east of the Fire-Lab.
For room-visiting the Fire-Store:
now the camphrost is ever-seen.
The can't-go of the Fire-Store is "The only way out is west."
The aroma-description is "You can smell hot brick".
Check going outside in the Fire-Store:
instead try going west.
The camphrost-supply is in the Fire-Store.
The fire-store-rack is a prominent-scenery supporter in the Fire-Store. The printed name is "rack".
Understand "rack", "racks" as the fire-store-rack.
Rule for writing a paragraph about the fire-store-rack:
now the fire-store-rack is mentioned;
let N be the number of things on the fire-store-rack;
if N is not zero:
if N is one:
say "[A first thing held by the fire-store-rack roomily] lies on another rack.";
else:
say "[A list of things *in the fire-store-rack roomily] lie on another rack."
The fire-bench is a prominent-scenery ritual-bound in the Fire-Store. The printed name is "brick bound".
The short-adjective is "brick bound".
The description is "In one corner is a stack of firebrick. Somebody has scratched a crude but functional ritual bound into its top. An extra brick forms a gestalt shelf."
Understand "brick", "firebrick", "stack", "stack of", "crude" as the fire-bench.
Rule for writing a paragraph about the fire-bench:
if the fire-bench is empty-inactive:
now the fire-bench is mentioned;
say "A stack of firebrick in back serves as a crude ritual bound, complete with gestalt shelf.";
stop;
say the visible state of the fire-bench.
Check taking the fire-bench:
instead say "The firebrick is fused into a solid mass[first time]. Wonder how that happened[only]."
Check pushing the fire-bench:
instead try taking the fire-bench.
Check pulling the fire-bench:
instead try taking the fire-bench.
The fire-shelf is a ritual-shelf in the Fire-Store.
The description is "An extra brick on the stack serves as a gestalt shelf -- the sort that holds symbolically relevant objects during a ritual[if the fire-shelf is empty]. The gestalt shelf is empty[end if]."
The linked-shelf of the fire-bench is the fire-shelf.
Understand "extra", "brick" as the fire-shelf.
Check taking the fire-shelf:
instead try taking the fire-bench.
Check pushing the fire-shelf:
instead try taking the fire-bench.
Check pulling the fire-shelf:
instead try taking the fire-bench.
Section - Safe-Store
The Safe-Store is a recallable room. The printed name is "Main Store".
The zone is safe-store-zone.
The description is "This is the general storeroom for the [Retort's] laboratories. Shelves begin here and extend to the east and west. However, a fracture to the east blocks a large part of the room. The door to the south is [if store-door is open]open[else]closed[end if][if Ch1-Scholar is in Safe-Store].[para]You recognize a figure to the east, beyond the fracture. [meet Ch1-Scholar]It's Ensign Ctesc. He is moving towards you -- or would be, if he were not frozen in place[end if]."
Understand "store", "storage", "storeroom", "main", "general" as Safe-Store.
The can't-go of the Safe-Store is "The room extends east and west, but a fracture blocks the way east. The door is south."
For room-visiting the Safe-Store:
mark g-store-door as done.
The store-safe is a lockable openable metallic prominent-scenery container in the Safe-Store. The printed name is "safe".
The store-safe has a number called the lock-counter.
Understand "safe", "door", "combination", "dial", "lock", "plain", "heavy", "steel", "block" as the store-safe.
Understand "locked", "sealed" as the store-safe when the store-safe is locked.
Understand "open", "opened" as the store-safe when the store-safe is open.
Understand "closed" as the store-safe when the store-safe is closed.
Rule for writing a paragraph about the store-safe:
say "A steel safe is set into one wall";
if the store-safe is closed and the store-safe is locked:
say ". The safe is closed and locked with a heavy combination lock";
else if the store-safe is closed:
say ". The safe is closed, but not locked";
else:
say ". The safe is open";
if the store-safe is empty:
say ", but empty";
else:
say ", revealing [a list of things *in the store-safe roomily]";
instead say "."
Check examining the store-safe:
if the store-safe is closed:
say "The safe is a plain steel block set into the wall. The combination dial shows the thirteen Zodiacal constellations -- slightly quaint, but the Service is slow to change a good thing";
if the store-safe is locked:
say ".[para]The safe is closed and locked";
else:
say ".[para]The safe is closed, but still unlocked";
else:
say "The safe is a plain steel block set into the wall. It is wide open";
if the store-safe is empty:
say ", but empty";
else:
say ".[para]Inside you see [a list of things *in the store-safe roomily]";
instead say ".";
Check searching the store-safe:
instead try examining the store-safe.
Check inspecting the store-safe with the planetary-lens:
mark safe-combo-note as known;
instead say "You peer through the planetary lens. The alignment of the safe dial is clearly visible: Libra, Ophiuchus, Taurus, Scorpio[one of].[para](Does such basic alchemy really circumvent Navy-standard locks? Maybe some protection has come adrift. Lucky day for you.)[or].[stopping]".
Check recalling the store-safe when the safe-combo-note is known:
instead try recalling the safe-combo-note.
Check taking the store-safe:
instead say "The safe is built into the wall."
Check pulling the store-safe:
instead try opening the store-safe.
Check freeing the store-safe:
instead try opening the store-safe.
Check opening the locked store-safe:
if g-store-safe is ever-done:
goal-perform g-store-safe;
if the store-safe is open:
say "You open the safe";
if the store-safe is empty:
say ", which is empty";
else:
say ", revealing [a list of things *in the store-safe]";
say ".";
stop the action;
instead say "The safe is locked. Its dial is inscribed with the thirteen zodiacal signs." [### parser clue for "set" syntax]
Check unlocking the store-safe with:
instead say "It's a combination lock, not a key lock[if the store-safe is unlocked]. Anyhow, the safe is already unlocked[end if]."
Check locking the locked store-safe with:
instead say "The safe is already locked."
Check locking the unlocked store-safe with:
if the store-safe is open:
instead say "The safe isn't closed.";
now the lock-counter of the store-safe is zero;
now the store-safe is locked;
instead say "(It's a combination lock, not a key lock.) You give it a few twists."
Check turning the locked store-safe:
instead try opening the store-safe.
Check turning the unlocked store-safe:
if the store-safe is open:
instead say "The safe isn't closed.";
now the lock-counter of the store-safe is zero;
now the store-safe is locked;
instead say "You give the lock a few twists, re-locking it."
Check vague-setting the store-safe:
instead try turning the store-safe;
Check setting the store-safe to:
if the store-safe is open:
instead say "The safe isn't closed.";
if the store-safe is unlocked:
now the store-safe is locked;
now the lock-counter of the store-safe is zero;
say "You re-lock the combination lock.[para]";
if the topic understood unlocks the store-safe via store-safe-checking:
now the g-store-safe is ever-done;
mark safe-combo-note as known;
say "The safe's lock clicks and releases!";
now the store-safe is unlocked;
instead try opening the store-safe;
stop the action.
To decide what number is store-safe-check (L - lock-symbol) (this is store-safe-checking):
if L is no-lock-symbol:
decide on 4;
if L is not a common-zodiac-symbol:
decide on -2;
if L is:
-- Libra-ls: decide on 0;
-- Ophiuchus-ls: decide on 1;
-- Taurus-ls: decide on 2;
-- Scorpio-ls: decide on 3;
-- otherwise: decide on -1.
To refuse the combination for (T - store-safe) with (newsnip - snippet) and (L - lock-symbol) and (isnumber - truth state):
if L is a common-planet-symbol:
say "This lock is set in astrological signs, not planets.";
else if newsnip matches "[number]":
say "The lock is set in astrological signs, not numbers.";
else:
say "The lock has no '[newsnip]' setting."
First magnetization rule when the item described is in the store-safe:
if the store-safe is closed:
say "Something rattles around inside the safe.";
rule fails;
else:
say "[The item described] vibrates in response, and bounces out of the safe into your hand.";
rule succeeds.
The store-shelves is a prominent-scenery plural-named supporter in the Safe-Store. The printed name is "shelves".
Understand "shelf", "shelves" as the store-shelves.
Rule for writing a paragraph about the store-shelves:
now the store-shelves is mentioned;
let N be the number of things on the store-shelves;
if N is 0:
stop;
if N is 1:
say "The nearest shelves are mostly empty, but you see [a first thing held by the store-shelves roomily] within reach.";
stop;
say "The nearest shelves are mostly empty, but [a list of things *in the store-shelves roomily] are within reach."
The safe-store-fracture is a fracture in the Safe-Store.
The description is "This fracture blocks the entire east side of the storeroom. Pity -- most of the interesting supplies are over there[if Ch1-Scholar is in Safe-Store].[para]Ensign Ctesc, another Alchemy ensign, is visible on the other side of the fracture[end if]."
The store-door is a lockable scenery door. The printed name is "oak Store door".
The opening-goal is g-store-door.
The pull-side is the Lab-Hall-NW.
The refer-name is "Main Store door".
Understand "oak", "door", "store", "storage", "storeroom", "alchemic" as the store-door.
The store-door is south of the Safe-Store. The store-door is north of Lab-Hall-NW.
Section - Safe-Nook
The Safe-Nook is a recallable room. The printed name is "Storage Nook".
The zone is safe-store-zone.
The recall-minor is true.
The description is "You are in an awkward nook behind the storeroom's last shelf. The rest of the room is east."
Understand "store", "storage", "storeroom", "nook" as the Safe-Nook.
The Safe-Nook is west of the Safe-Store.
The can't-go of the Safe-Nook is "The only way out is east."
Check going outside in the Safe-Nook:
instead try going east.
Check going down in the Safe-Nook:
instead try entering the nook-cabinet.
The nook-shelf is scenery in the Safe-Nook. The printed name is "last shelf".
The description is "The back of the shelf is entirely uninteresting."
Understand "last", "shelf" as the nook-shelf.
Check putting something on the nook-shelf:
instead say "You can't put things on the shelf from this side."
Check inserting something into the nook-shelf:
instead say "You can't put things on the shelf from this side."
Check searching the nook-shelf:
instead say "Sadly, you find nothing of interest."
Check looking under the nook-shelf:
instead try searching the nook-shelf.
The nook-cabinet is a prominent-scenery standard-cabinet in the safe-nook. The printed name is "lead panel".
The opening-goal is g-nook-cabinet.
The nook-cabinet has a symbol-type. [even though it's not inscribable] [resettable]
Understand "panel", "compartment", "storage", "cover", "hatch", "floor", "heavy", "solid", "lead" as the nook-cabinet.
Understand "gossamer", "gossamerity", "symbol" as the nook-cabinet when the symbol-type of the nook-cabinet is gossamerity-symbol.
Understand "ponderous", "ponderosity", "symbol" as the nook-cabinet when the symbol-type of the nook-cabinet is ponderosity-symbol.
The lens-view of the nook-cabinet is "Saturn".
Rule for writing a paragraph about the nook-cabinet:
say "You see another hatch in the floor, though it's too small for a person. The cover seems to be solid lead";
if the nook-cabinet is closed:
say ". It is closed";
if the symbol-type of the nook-cabinet is not no-symbol:
say "; the [symbol-type of the nook-cabinet] symbol shines on it";
else:
say ". It is open";
if the symbol-type of the nook-cabinet is not no-symbol:
say "; the [symbol-type of the nook-cabinet] symbol still shines on it";
if the nook-cabinet is empty:
say ". The compartment beneath is empty";
else:
say ". Within [is-are a list of things *in the nook-cabinet roomily]";
instead say "."
Check examining the nook-cabinet:
if the nook-cabinet is closed:
say "This lead panel must cover some kind of shielded storage compartment. It's closed";
if the symbol-type of the nook-cabinet is not no-symbol:
say "; the [symbol-type of the nook-cabinet] symbol shines on it";
else:
say "The lead panel lies open, revealing a storage compartment";
if the nook-cabinet is empty:
say ", which is empty";
if the symbol-type of the nook-cabinet is not no-symbol:
say ". The [symbol-type of the nook-cabinet] symbol shines on the lead";
else:
if the symbol-type of the nook-cabinet is not no-symbol:
say ". The [symbol-type of the nook-cabinet] symbol shines on the lead";
say ".[para]Inside you see [a list of things *in the nook-cabinet roomily]";
instead say "."
Check taking the nook-cabinet:
if the nook-cabinet is closed:
instead try opening the nook-cabinet;
else:
instead say "The cover is open, but it's still fastened to the floor."
Check opening the closed nook-cabinet:
if the symbol-type of the nook-cabinet is ponderosity-symbol:
instead say "Turkish wrestlers couldn't lift the lead panel right now.";
if the symbol-type of the nook-cabinet is not gossamerity-symbol:
if g-nook-cabinet is ever-done:
goal-perform g-nook-cabinet;
if the nook-cabinet is open:
say "You apply the gossamerity symbol and open the compartment";
if the nook-cabinet is empty:
say ", which is empty";
else:
say ", revealing [a list of things *in the nook-cabinet]";
say ".";
stop the action;
instead say "You try to lift the panel, but it's too heavy to move.";
continue the action.
Check closing the open nook-cabinet:
if the symbol-type of the nook-cabinet is ponderosity-symbol:
instead say "Turkish wrestlers couldn't move the lead panel right now.";
if the symbol-type of the nook-cabinet is not gossamerity-symbol:
instead say "You try to move the panel, but it's too heavy.";
continue the action.
Report opening the nook-cabinet:
mark g-nook-cabinet as done;
say "The lead cover retains a massy inertia, but you can lift it. The compartment opens in surreal slow motion";
if the nook-cabinet is empty:
say ". It is empty";
else:
say ". You discover [a list of things *in the nook-cabinet] inside";
instead say "."
Report closing the nook-cabinet:
instead say "You heave the lead panel back over. It sinks shut with a slow-motion [em]thump[/em]."
Check entering the nook-cabinet:
if the nook-cabinet is closed:
instead say "Even if the hatch were open, you wouldn't fit.";
else:
instead say "The compartment is too small for a person."
Check tapping a pebble on the nook-cabinet when the symbol-type of the noun is ponderosity-symbol:
say "You carefully lay the [symbol-type of the noun] symbol against the lead";
uninscribe the noun;
if the symbol-type of the nook-cabinet is ponderosity-symbol:
instead say ". It discharges, but the symbol on the panel does not change.";
say ". The symbol flares brightly and transfers to the panel";
let old-symbol be the symbol-type of the nook-cabinet;
if the symbol-type of the nook-cabinet is gossamerity-symbol:
say ", replacing the [symbol-type of the nook-cabinet] symbol";
now the symbol-type of the nook-cabinet is ponderosity-symbol;
instead say ". The lead cover now looks even heavier, if that's possible."
Check tapping a pebble on the nook-cabinet when the symbol-type of the noun is gossamerity-symbol:
say "You carefully lay the [symbol-type of the noun] symbol against the lead";
uninscribe the noun;
if the symbol-type of the nook-cabinet is gossamerity-symbol:
instead say ". It discharges, but the symbol on the panel does not change.";
say ". The symbol flares brightly and transfers to the panel";
let old-symbol be the symbol-type of the nook-cabinet;
if the symbol-type of the nook-cabinet is ponderosity-symbol:
say ", replacing the [symbol-type of the nook-cabinet] symbol";
now the symbol-type of the nook-cabinet is gossamerity-symbol;
instead say ". The lead cover somehow looks less massive now."
Instead of tapping the nook-cabinet on the dispersal-brush:
instead try tapping the second noun on the noun.
Instead of putting the dispersal-brush on the nook-cabinet when the symbol-type of the nook-cabinet is not no-symbol:
instead try tapping the noun on the second noun.
Check tapping the dispersal-brush on the nook-cabinet when the symbol-type of the nook-cabinet is not no-symbol:
say "You brush the feather across the lead panel. The [symbol-type of the nook-cabinet] symbol blurs and fades away";
now the symbol-type of the nook-cabinet is no-symbol;
instead say "."
Check inspecting the nook-cabinet with the oculus when the symbol-type of the nook-cabinet is not no-symbol:
instead say "The oculus magnifies the [symbol-type of the nook-cabinet] symbol, but the lead hatch is otherwise unchanged."
The initial appearance of the rutilum-seal is "A glint of light reveals an Alchemy File seal lying near the hatch. Some officer will be in deep trouble for losing it."
Understand "glint", "glint of", "light" as the rutilum-seal when the rutilum-seal is not handled and the rutilum-seal is in Safe-Nook.
Section - Lab-Library
The Library is a recallable room. The printed name is "Library".
The zone is lab-hall-zone.
The description is "This library serves the laboratory wing. You haven't spent much time here -- the trainees have their own study room -- but you have often admired the rows of fat musty tomes on their elegantly-carved shelves. The archway is north."
The can't-go of the Library is "The only exit is north."
The aroma-description of the Library is "The room smells pleasantly of old books and new ink".
Check going outside in the Library:
instead try going north.
The library-arch is an open unopenable scenery door. The printed name is "archway".
The description is "The archway is entirely mundane. People walk [if the location is the Library]out of[else]into[end if] the Library through it. That is all."
Understand "arch", "archway" as the library-arch.
Understand "library" as the library-arch when the location is the Lab-Wing-Hall.
The library-arch is north of the Library. The library-arch is south of the Lab-Wing-Hall.
Check searching the library-arch:
instead say "It's easier to walk through the archway and look than to peer through."
The library-proxy is a room-proxy in the Library. The printed name is "library".
The description is "You look around again, but nothing has changed."
Understand "library", "room" as the library-proxy.
Check searching the library-proxy:
instead try searching the library-books.
Check reading the library-proxy:
instead try examining the library-books.
Check entering the library-proxy:
instead say "You are already in the library."
The library-books are plural-named readable scenery in the Library. The printed name is "books".
The library-books has a number called the current-count.
Understand "book", "books", "tome", "tomes", "rows", "rows of", "fat", "musty", "shelf", "shelves" as the library-books.
Check examining the library-books:
increment the current-count of library-books;
if the current-count of library-books is:
-- 1: instead say "You pick up a book and flip through it. The text is opaque; this must be a high-level theory text. Disappointed, you replace it on the shelf.";
-- 2: instead say "You look at another book. This one, too, is a haze of obscure alchemical theory.";
-- 3: instead say "You look at another book. Strange -- you have trouble even focussing on the lettering. You begin to wonder if there's something wrong with your eyesight.";
-- 4: instead say "You peer intently at another book. The words seem to swirl away in a haze of mathematical terminology. You give up and return the book to the shelf.";
-- 5: instead say "You pick up a book and flip through it. It's no more comprehensible than the last one.";
-- 6:
now the current-count of library-books is 3;
instead say "You look at another book. You're not sure whether the problem is you or the text, but you are making no progress either way. You put it back.";
-- otherwise: instead say "You are unable to make sense of the book."
Check searching the library-books:
instead say "You scan rows of titles. These are all alchemy texts, but none of them stands out in particular."
Check taking the library-books:
instead try examining the library-books.
Check opening the library-books:
instead try examining the library-books.
Check entering the library-books:
instead say "Getting lost in a book is an idiom."
Check smelling the library-books:
instead try smelling the location.
Check rubbing the library-books:
instead say "The staff keep these books well-dusted."
Check inspecting the library-books with the oculus:
instead say "Through the oculus, the books are a great mass of information. Not a collection of works, oddly, but a single indistinct mass."
Definition: a paper-sheet is library-sheet-pair if it is sh-lab-library-1 or it is sh-lab-library-2.
Rule for writing a paragraph about a library-sheet-pair paper-sheet:
if sh-lab-library-1 is in the location and sh-lab-library-2 is in the location:
say "Two papers, [a sh-lab-library-1] and [a sh-lab-library-2], lie unregarded on the floor.";
else if sh-lab-library-1 is in the location:
say "[A sh-lab-library-1] of paper is lying here.";
else if sh-lab-library-2 is in the location:
say "[A sh-lab-library-2] of paper is lying here."
The initial appearance of the infotater is "You notice a rotor card sticking out from between two books."
Section - Lab-Wing-Hall
The Lab-Wing-Hall is a recallable room. The printed name is "Lab Wing Hallway".
The zone is lab-hall-zone.
The description is "This hallway runs east and west. [if hall-door is closed and hall-door is locked]However, the fire door to the west is locked, sealing you off from the rest of the [Retort][else if hall-door is closed]The fire door to the west is closed, but not locked[else]To the west, beyond an open fire door, is the rest of the [Retort][end if]. A smaller door to the north leads to the Primary Alchemy Lab; it is[if hall-door is open] also[end if] open, but blocked by another fracture. An archway to the south leads to the Library."
Understand "lab", "laboratory", "wing", "hall", "hallway" as the Lab-Wing-Hall.
Lab-Wing-Hall is west of Lab-Hall-NW.
Lab-Wing-Hall is wallpaper-enabled.
The can't-go of Lab-Wing-Hall is "The laboratory wing is east; the rest of the [Retort] is west; the Primary Alchemy Lab is north, and the Library is south."
Check going north in the Lab-Wing-Hall:
instead try entering the 1st-fracture.
The hall-door is a lockable scenery door. The printed name is "heavy fire door".
The matching key of the hall-door is the hall-key.
The opening-goal is g-hall-door.
The pull-side is the Lab-Wing-Hall.
The refer-name is "Lab Wing fire door".
Understand "heavy", "massive", "thick", "fire", "door" as the hall-door.
The hall-door is west of the Lab-Wing-Hall. The hall-door is east of the East-Side-Hall.
Check examining the hall-door:
if the hall-door is open:
instead say "The massive fire door is open, as usual.";
say "The massive swinging door that separates the laboratories from the rest of the marcher is";
if the hall-door is unlocked:
say " unlocked, but still closed";
else:
say " closed and locked";
if g-hall-door is not ever-done:
if the hall-door is locked:
say ".[para]You've never seen this door closed except during an all-sections drill";
say ". The [Retort's] emergency animations must have been triggered by... whatever has happened";
instead say "."
Check going when the door gone through is the hall-door and the hall-door is locked and the player carries the hall-key:
say "(first unlocking and opening [the hall-door], with [the hall-key])[command clarification break]";
silently try unlocking the hall-door with the hall-key;
if the hall-door is locked:
stop the action;
silently try opening the hall-door;
if the hall-door is closed:
stop the action.
Check opening the hall-door when the hall-door is locked and the player carries the hall-key:
say "(first unlocking [the hall-door] with [the hall-key])[command clarification break]";
silently try unlocking the hall-door with the hall-key;
if the hall-door is locked:
stop the action.
Check opening the hall-door when the hall-door is locked:
if g-hall-door is ever-done:
goal-perform g-hall-door;
if the hall-door is open:
say "You open the heavy door.";
stop the action.
The 1st-fracture is a fracture in the Lab-Wing-Hall.
The description is "Another fracture blocks the Primary Lab to the north."
The fake-1st-door is a far-sight in the Lab-Wing-Hall. The printed name is "pine Primary door".
The description is "You try to peer into the Primary Lab, but the room is darkened."
The reach-reason is "The Primary Lab is on the far side of the fracture."
Understand "primary", "lab", "laboratory", "door", "pine" as the fake-1st-door.
The initial appearance of the G-flat-chime is "Another standard glass chime lies in the middle of the hall. This one is a glass G-flat."
Chapter - Airlock and East Side
Section - East Side Hall
The East-Side-Hall is a room. The printed name is "East Side Hallway".
The zone is core-hall-zone.
The description is "This broad hall runs from the Nave, to the west, through a fire door to the east and on towards the laboratory wing[if hall-door is closed]. The fire door is closed, however[end if]. A smaller hallway heads south towards the medical wing.[para]To the north[if inner-door is open], an enormous circular doorway leads to the [Retort's] main airlock. The inner airlock door is open[else] is an enormous circular slab -- the closed inner door of the [Retort's] main airlock[end if].[first time][para][sarge]Ever think that door might have been closed for a reason, kid? Are you sure you know what you're doing?[/sarge][para][sarge]Working on it...[/sarge][only]".
East-Side-Hall is east of the Nave.
East-Side-Hall is wallpaper-enabled.
The can't-go of East-Side-Hall is "You can go west towards the Nave, east towards the laboratories, south towards medical, or north to the airlock."
Check going inside in East-Side-Hall:
instead try going north.
Check going outside in East-Side-Hall:
instead try going north.
Check going south from East-Side-Hall:
[set a flag about just having entered Med-Wing-Hall (from this side only)]
now Med-Wing-Hall is not shifted;
continue the action.
Section - Airlock
The Airlock is a recallable room.
The zone is airlock-zone.
The description is "The airlock is a stumpy cylindrical chamber, ten feet long and ten feet across. It is used whenever the [Retort] is rigged into a non-Gaian land. The chamber walls are bare steel. At each end is a circular slab of a door[airlock-door-state]."
To say airlock-door-state:
if the inner-door is closed and the outer-door is closed:
say "; both doors are closed";
else if the inner-door is open and the outer-door is open:
say ". (BUG) Both doors are open, which is impossible";
else if the outer-door is closed:
say ". The inner door to the south is open; the outer door to the north is closed";
else if the inner-door is closed:
say ". The outer door to the north is open; the inner door to the south is closed";
else:
say ". (BUG) Something is wrong with the doors".
The can't-go is "You can go north (outside) or south (inside)."
The aroma-description is "You catch a faint gunpowdery whiff of Hadean dust".
Check going outside in the Airlock:
instead try going north.
Check going inside in the Airlock:
instead try going south.
The airlock-walls are metallic plural-named scenery in the Airlock. The printed name is "steel walls".
The description is "The walls are heavy, curved steel; they're meant to contain the pressure difference between the [Retort] and whatever foreign land it visits. Narrow vents are ready to [if the atmosphere of the Airlock is normal-atm]draw the air away when the lever is pulled[else]let air back in when the lever is pushed[end if]."
The lens-view is "Mars".
Understand "steel", "wall", "walls", "narrow", "vent", "vents" as the airlock-walls.
Check touching the airlock-walls:
instead say "They feel like foot-thick steel. (Somehow you can tell.)"
Check searching the airlock-walls:
instead say "You can't see through the vents."
The airlock-lever is metallic fixed in place in the Airlock. The printed name is "airlock lever".
The initial appearance is "The pressurization lever on the wall is [if the atmosphere of the Airlock is vacuum-atm]pulled up. The chamber has the eerie silence of vacuum[else]pushed down[end if]."
The airlock-lever can be ever-tried.
The airlock-lever can be breath-vacuum-glossed.
Understand "lever", "valve", "master", "pressure", "control" as the airlock-lever.
The lens-view of the airlock-lever is "Pneuma[if Pneuma is not fixed], though it is weak[end if]".
Check examining the airlock-lever:
say "The airlock's master pressure control is a clunky iron lever set in the wall. The shorthand symbol for Pneuma is engraved above it";
say ".[para]The lever is currently";
if the atmosphere of the Airlock is vacuum-atm:
say " pulled up. Pushing it will repressurize the airlock";
else:
say " pushed down. You know that pulling it will depressurize the airlock[if the airlock-lever is not ever-tried]. Not that you've ever been allowed to do anything that interesting[end if]";
instead say "."
Check pushing the airlock-lever when the atmosphere of the Airlock is not vacuum-atm:
instead say "The lever is already pushed all the way."
Check pushing the airlock-lever:
if Pneuma is not fixed:
instead say "The lever seems to be locked in place. You're not sure what's wrong with it.";
if outer-door is open:
say "The outer door swings shut, and air";
now the outer-door is closed;
else:
say "Air";
say " blasts into the airlock for several moments. When the rush dies, you hear -- oh yes, you can hear again -- the [em]clunk[/em] of the inner door unsealing";
now the atmosphere of the Airlock is normal-atm;
now the inner-door is not shifted;
instead say "."
Check pulling the airlock-lever when the atmosphere of the Airlock is vacuum-atm:
instead say "The lever is already pulled all the way."
Check pulling the airlock-lever:
if Pneuma is not fixed:
instead say "The lever seems to be locked in place. You're not sure what's wrong with it.";
if inner-door is open:
say "You pull the lever. The inner door swings shut, and air";
now the inner-door is closed;
else:
say "You pull the lever. Air";
if vacuum-potion-remaining is zero:
now the inner-door is shifted;
say " begins hissing out of the airlock; you feel your ears pop.[para]Gah! You push the lever back, before the pressure can drop further. Suffocating yourself is not on the agenda";
say breath-vacuum-potion-gloss airlock-lever;
stop the action;
say " hisses out of the airlock. After several long moments, the sound fades -- all sound, in fact";
now the atmosphere of Airlock is vacuum-atm;
say ".[para][vacuum-entry-reaction].";
perform room vacuumization in the Airlock;
stop the action.
Check closing the airlock-lever:
instead try opening the airlock-lever.
Check turning the airlock-lever:
instead try opening the airlock-lever.
Check switching on the airlock-lever:
instead try opening the airlock-lever.
Check switching off the airlock-lever:
instead try opening the airlock-lever.
Check vague-setting the airlock-lever:
instead try opening the airlock-lever.
Check opening the airlock-lever:
if the atmosphere of the Airlock is vacuum-atm:
instead say "Push the lever to repressurize the airlock.";
else:
instead say "Pull the lever to depressurize the airlock."
Report topically-applying the clock-tincture to the airlock-lever:
say "You carefully pour the tincture over the lever. It soaks in, but you see no other effect";
if Pneuma is not fixed:
say ". The fault must not lie in the mechanism";
instead say "."
The yourself can be breath-vacuum-glossed. [special case flag]
To say breath-vacuum-potion-gloss (T - thing):
if vacuum-potion-remaining is not zero:
say ". (BUG) breath-vacuum-potion-gloss when protected.";
stop;
if breath-potion-remaining is zero:
[the usual case -- you haven't drunk the breath potion]
say ".";
stop;
if the player is not breath-vacuum-glossed:
say ". (And you can't hold your breath in a vacuum.)[para][sarge]Drill! What happens if you try to hold your breath when the air blows out the door?[/sarge][para][sarge]My lungs blow out of my ears, Sarge.[/sarge][para][sarge]Don't you forget it![/sarge][line break]";
now the player is breath-vacuum-glossed;
stop;
if T is not breath-vacuum-glossed:
say ". (And you can't hold your breath in a vacuum, as months of emergency drills remind you.)";
now T is breath-vacuum-glossed;
stop;
say ". (And you can't hold your breath in a vacuum.)"
The inner-door is a scenery door. The printed name is "inner airlock door".
Understand "inner", "airlock", "door", "doorway", "enormous", "circular", "slab" as the inner-door.
The pull-side is East-Side-Hall.
The refer-name is "Airlock inner door".
The opening-goal is g-airlock-inner-door.
The inner-door can be shifted. [small pressure difference; resettable]
The inner-door is north of East-Side-Hall and south of the Airlock.
The description of the inner-door is "The inner door is a circular slab, thick with leather and rubber seals. It is [if inner-door is open]open[else]closed[end if]."
Check opening the inner-door when the atmosphere of the Airlock is vacuum-atm:
instead say "The airlock inner door is sealed[if the location is the Airlock], since the airlock is depressurized[else]; the airlock must still be depressurized[end if]."
Carry out opening the inner-door:
if the inner-door is shifted and currently trying silently:
now the inner-door is not shifted;
say "There is a brief hiss as the pressure re-equalizes.";
continue the action.
Report opening the inner-door:
say "You swing open the inner door";
if the inner-door is shifted:
now the inner-door is not shifted;
say "; there is a brief hiss as the pressure re-equalizes";
instead say "."
Report closing the inner-door:
instead say "The inner door is massive but well-balanced. It swings shut with a muffled [em]whoomp[em]."
Check going when the door gone through is the inner-door and (the atmosphere of the Airlock is vacuum-atm):
[Dunno why I need the parens above]
if g-airlock-inner-door is ever-done:
if the location is Airlock:
instead goal-travel to East-Side-Hall;
else:
instead goal-travel to Airlock.
Carry out going when the door gone through is the inner-door:
now g-airlock-inner-door is ever-done.
The outer-door is a scenery door. The printed name is "outer airlock door".
Understand "outer", "airlock", "door", "doorway", "enormous", "circular", "slab" as the outer-door.
The pull-side is the Out-Plain.
The refer-name is "Airlock outer door".
The opening-goal is g-airlock-outer-door.
The outer-door is south of the Out-Plain and north of the Airlock.
The description of the outer-door is "The outer door is a circular slab, thick with leather and rubber seals. A peephole in the center permits you to look [if the location is the Airlock]outside[else]inside[end if]. The door is [if outer-door is open]open[else]closed[end if]."
Check opening the outer-door when the atmosphere of the Airlock is not vacuum-atm:
instead say "The airlock outer door is sealed[if the location is the Airlock]; the world outside must not have Gaian air pressure[else]; the airlock must still be pressurized[end if]."
Check searching the outer-door:
if the outer-door is closed:
instead try examining the peephole;
else:
if the location is the Airlock:
instead try examining the airlock-view;
else:
instead say "You see the airlock."
Report opening the outer-door:
instead say "You [if the location is the Airlock]lean[else]haul[end if] on the outer door, and it swings slowly open[if the location is the Airlock and the Out-Plain is not visited]. Outside is a stark grey Hadean landscape[end if]."
Report closing the outer-door:
instead say "You swing the outer door shut. It seals silently, but you feel the impact in your feet."
Check going when the door gone through is the outer-door and (the atmosphere of the Airlock is not vacuum-atm):
[Dunno why I need the parens above]
if g-airlock-outer-door is ever-done:
if the location is Airlock:
instead goal-travel to Out-Plain;
else:
instead goal-travel to Airlock.
The peephole is scenery glassy part of the outer-door.
Understand "lens", "peep", "hole" as the peephole.
Check examining the peephole when in the Airlock:
if the outer-door is open:
instead say "The door is open. You don't need the peephole to see the Hadean landscape outside.";
else:
instead say "Through the peephole, you can see a grey, stony wasteland. The sky above is pitch-night with stars and an icy bright sun."
Check examining the peephole when in the Out-Plain:
if the outer-door is open:
instead say "The door is open, so the peephole is irrelevant.";
else:
instead say "Through the peephole, you can see the airlock."
Check searching the peephole:
instead try examining the peephole.
The airlock-view is a far-sight in the Airlock. The printed name is "wasteland".
Understand "wasteland", "grey", "gray", "stony", "stark", "hadean", "land", "landscape", "black", "sky", "star", "stars", "icy", "tiny", "bright", "sun" as the airlock-view.
The description is "[if the outer-door is closed]Through the peephole[else]Outside[end if], you see a wasteland of grey stone and grey dust -- a Hadean land. The sky is black ink and ice-clear stars, with a tiny bright sun, for there is no air to blur it, and no movement, and no life."
The reach-reason is "The wasteland is[if the outer-door is closed] on the other side of the door[else]outside[end if]."
Check entering the airlock-view:
instead try going north.
Check inspecting the airlock-view with the planetary-lens:
instead say "The lens displays the landscape's Hadean nature."
Chapter - Med Wing
Section - Med Wing Hall
The Med-Wing-Hall is a room. The printed name is "Medical Wing Hallway".
The zone is core-hall-zone.
The description is "[med-wing-hall-desc]".
Med-Wing-Hall is south of East-Side-Hall.
Med-Wing-Hall is wallpaper-enabled.
Med-Wing-Hall can be shifted. [just walked into room; does not need to be reset]
To say med-wing-hall-desc:
say "This short corridor leads to the medical wing, whose entrance is south";
say "";
if the med-gunk-cabinet is closed:
if the med-gunk-cabinet is dirty:
say ".[para]Another alloy cabinet is fastened to the wall. It's supposed to be for dropping off samples, but something has (again) gone wrong. Some horrible gunk is leaking out at the seams; the whole cabinet is crusted with it";
else:
say ".[para]The alloy cabinet on the wall is cleaner but still closed";
else:
if the med-gunk-cabinet is empty:
say ".[para]The alloy cabinet on the wall is open";
else:
say ".[para]The cabinet on the wall is open, revealing [a list of things *in the med-gunk-cabinet roomily]";
if the aura-mod-type is invisibility-symbol or the aura-mod-type is impermeability-symbol:
say ".[para]The open door to the south no longer feels threatening";
else:
if Med-Wing-Hall is not shifted:
say ".[para]As you approach the open door to the south, a disquieting sense of menace steals over you";
else:
say ".[para]A disquieting sense of menace radiates from the open door to the south";
now Med-Wing-Hall is shifted;
say period.
The can't-go of Med-Wing-Hall is "The corridor runs north and south."
The aroma-description of Med-Wing-Hall is "[if desc-aroma is no-odor]The air has no physical aroma[else]The air smells only of [desc-aroma][clear-desc-aroma][end if]. The door's aura is a purely psychic sense, an impression of hungry malevolence".
Check going inside in Med-Wing-Hall:
instead try going south.
Check going outside in Med-Wing-Hall:
instead try going north.
The med-wing-door is a scenery door. The printed name is "pine Medical door".
Understand "pine", "door", "med", "medical" as the med-wing-door.
The description is "The door stands open... but not [em]invitingly[/em] open. A malevolent hunger hangs around it, like a cloud[if the location is Med-Wing-Hall], or a stench[end if]."
The pull-side is Med-Wing-Hall.
The refer-name is "Medical Wing door";
[No goal, because this door never closes. The pass-through goal is g-in-med-wing/g-out-med-wing.]
The med-wing-door is south of the Med-Wing-Hall.
The med-wing-door is north of the Med-Wing.
Check closing the med-wing-door:
instead say "Close it? You don't even want to touch it."
Check touching the med-wing-door:
instead say "You don't want to touch the door at all."
Check going when the door gone through is the med-wing-door:
[Handle successful passes...]
if the miasma-gong is charged:
say "The door feels quite ordinary now. You walk through without any fuss.[para]Behind you, the sound of the gong fades, and the aura-cloud comes rushing back in all its hunger. You quickly step away from the doorway.";
now the ring-time of the miasma-gong is zero;
now the miasma-gong is uncharged;
mark the g-out-med-wing as done;
now the aura-cloud is ever-tried;
continue the action;
if the aura-mod-type is invisibility-symbol:
say "You walk towards the door, without quite letting your eyes focus on it. The malevolent chill is still present, but it feels distant, irrelevant to you.[para]Then it doesn't feel quite so distant. Your protection is wearing away. You hurriedly step through the door.";
now the aura-mod-time is one;
mark the g-in-med-wing as done;
now the symbol-type of g-in-med-wing is invisibility-symbol;
now the aura-cloud is ever-tried;
continue the action;
if the aura-mod-type is impermeability-symbol:
say "You walk towards the door, unafraid. The malevolent chill is still present, but it feels trivial, a problem for someone else to worry about.[para]Then it doesn't feel quite so trivial. Your protection is wearing away. You hurriedly step through the door.";
now the aura-mod-time is one;
mark the g-in-med-wing as done;
now the symbol-type of g-in-med-wing is impermeability-symbol;
now the aura-cloud is ever-tried;
continue the action;
if the aura-mod-type is imitation-symbol:
instead say "You take another step towards the door, but the sense of hungry menace intensifies. Apparently the aura cloud is as dangerous to a higher officer as to an ensign.";
[Handle auto-solutions...]
if the location is Med-Wing-Hall:
if g-in-med-wing is ever-done and the aura-mod-type is no-symbol:
instead goal-travel to Med-Wing;
else:
if g-out-med-wing is ever-done:
instead goal-travel to Med-Wing-Hall;
if the location is Med-Wing:
instead say "The malevolent cloud still hovers around the door, as powerful as ever. Getting out of here will be as difficult as getting in.";
say "You take another step towards the door, but the sense of hungry menace intensifies. Another step, and your head starts to ache; chills crawl in your guts and nest there";
say the aura-cloud explanation;
instead say ".[para]You back away before you suffer any more serious harm."
Check inspecting the med-wing-door with the oculus:
instead try inspecting the aura-cloud with the oculus.
The aura-cloud is a scenery part of the med-wing-door. The printed name is "malevolent cloud".
The aura-cloud can be ever-tried. [resettable]
Understand "malevolent", "malice", "menace", "hunger", "hungry", "intangible", "sense", "sense of", "cloud", "cloud of", "aura", "psychic", "vortex", "outbreak" as the aura-cloud.
Check examining the aura-cloud:
if the miasma-gong is charged:
instead say "The cloud is almost undetectable now.";
if the aura-mod-type is invisibility-symbol:
instead say "The sense of malice around the door feels distant and irrelevant to you.";
if the aura-mod-type is impermeability-symbol:
instead say "The sense of malice around the door feels trivial now.";
say "You can see nothing, but the sense of malice around the door is unmistakable";
if the aura-cloud is ever-tried:
say ". The aura cloud is still present";
say the aura-cloud explanation;
instead say "."
To say the aura-cloud explanation:
if the aura-cloud is not ever-tried:
now the aura-cloud is ever-tried;
mark aura-cloud-fact as known;
say ".[para]You have heard of this phenomenon[one of], although you've never encountered it -- certainly not on a marcher as well-run as the [Retort]. At least, not as well-run as the [Retort] used to be[ellipsis][para][or]. [stopping]An aura cloud is an uncontained psychic outbreak, a sucking vortex of vital energies. It's not a ghost, or a demon, but a less scientific age would certainly have viewed it as such. Any living aura that falls into resonance with the cloud will be drained black in moments. You'll have to protect or disguise your psychic signature, somehow, to pass by";
To decide whether near-aura-cloud:
if the location is Med-Wing or the location is Med-Wing-Hall:
decide yes.
Check inspecting the aura-cloud with the planetary-lens:
instead say "The aura cloud is not visible through the lens."
Check inspecting the aura-cloud with the oculus:
instead say "The oculus makes the cloud visible as a whirling vortex of negative energy. Which you already knew, really."
Check taking the aura-cloud:
instead say "[The aura-cloud] is intangible."
Check pushing the aura-cloud:
instead try taking the aura-cloud.
Check pulling the aura-cloud:
instead try taking the aura-cloud.
Check turning the aura-cloud:
instead try taking the aura-cloud.
Check touching the aura-cloud:
instead try taking the aura-cloud.
Check waving the aura-cloud:
instead try taking the aura-cloud.
Check shaking the aura-cloud:
instead try taking the aura-cloud.
Check tapping something on the aura-cloud:
instead say "[The aura-cloud] is intangible."
Check entering the aura-cloud:
instead try entering the med-wing-door.
Check smelling the aura-cloud:
instead try smelling the location.
Check searching the aura-cloud:
instead try examining the aura-cloud.
Check attacking the aura-cloud:
instead say "Striking an intangible cloud of menace would be futile, even if approaching it were possible."
Check putting something on the aura-cloud:
instead say "Any notion of physical contact with the cloud is futile. It's not tangible."
Check inserting something into the aura-cloud:
instead say "Any notion of physical contact with the cloud is futile. It's not tangible."
The med-gunk-cabinet is a standard-cabinet in the Med-Wing-Hall.
The opening-goal is g-med-gunk-cabinet.
Understand "hinge", "hinges", "seam", "seams" as the med-gunk-cabinet.
Understand "crusty", "crusted", "dirty", "filthy", "gunk", "guck" as the med-gunk-cabinet.
The med-gunk-cabinet can be clean or dirty.
Check examining the med-gunk-cabinet:
if the med-gunk-cabinet is closed:
if the med-gunk-cabinet is dirty:
say "The cabinet is filthy. Unnameable substances have leaked out at the seams and dribbled over the hinges";
else:
say "The cabinet is cleaner now, but still closed";
else:
say "The cabinet is a squarish compartment of some anonymous alloy. It is open";
if the med-gunk-cabinet is empty:
say ", but empty, except for traces of whatever that gunk was";
else:
say ". The inside is still rather gunky; you also see [a list of things *in the med-gunk-cabinet roomily]";
instead say ".";
Check rubbing the dirty med-gunk-cabinet:
instead say "You scrub at the cabinet, but you can't get the guck off of it."
Check rubbing the clean med-gunk-cabinet:
instead say "The cabinet is clean enough to open, and that's all you care about."
Check smelling the med-gunk-cabinet:
instead say "Whatever's on the cabinet seems to have dried there. So it doesn't smell too bad. Small favors."
Check tasting the med-gunk-cabinet:
instead say "No."
Check opening the dirty med-gunk-cabinet:
if g-med-gunk-cabinet is ever-done:
goal-perform g-med-gunk-cabinet;
if the med-gunk-cabinet is open:
say "You open the cabinet";
if the med-gunk-cabinet is empty:
say ", which is empty";
else:
say ", revealing [a list of things *in the med-gunk-cabinet]";
say ".";
stop the action;
instead say "The cabinet won't open. Its hinges are crusted with something awful."
Report opening the med-gunk-cabinet:
say "You open the cabinet. The inside is still pretty filthy";
if the med-gunk-cabinet is empty:
say ", but otherwise empty";
else:
say "; you see [a list of things *in the med-gunk-cabinet] inside";
instead say "."
Check putting the el-water on the med-gunk-cabinet:
instead try tapping the el-water on the med-gunk-cabinet.
Check tapping the el-water on the dirty med-gunk-cabinet:
retire the el-water by applying to the med-gunk-cabinet;
now the med-gunk-cabinet is clean;
mark g-med-gunk-cabinet as done;
now the tool-used of g-med-gunk-cabinet is el-water;
instead say "You dribble elemental water over the cabinet, and the guck starts to dissolve away. You can't get the cabinet entirely clean, but you manage to free up the hinges, at least."
Check tapping the el-water on the clean med-gunk-cabinet:
instead say "The cabinet is clean enough to open already."
Check putting a charged bubble on the med-gunk-cabinet:
instead try tapping the noun on the med-gunk-cabinet.
Check tapping a charged bubble on the dirty med-gunk-cabinet:
[Not really "tapping", but we want to cover "apply to".]
now the noun is uncharged;
now the med-gunk-cabinet is clean;
mark g-med-gunk-cabinet as done;
now the tool-used of g-med-gunk-cabinet is the noun;
instead say "You hold [the noun] by the cabinet, and twist the valve. Elemental air hisses out. The guck recedes in the blast! You can't get the cabinet entirely clean, but you manage to free up the hinges, at least."
Check tapping a charged bubble on the clean med-gunk-cabinet:
instead say "The cabinet is clean enough to open already."
Check putting the fungicide on the dirty med-gunk-cabinet:
[The "convert putting a topical chem-source on to inserting" rule bypassed us, so we have to trigger topically-applying manually.]
retire the noun by applying to the second noun;
instead try topically-applying the noun to the second noun;
Check tapping the fungicide on the dirty med-gunk-cabinet:
retire the noun by applying to the second noun;
instead try topically-applying the noun to the second noun;
Report topically-applying the fungicide to the med-gunk-cabinet:
instead say "You carefully drip the fungicide over the cabinet. It fumes away in a vile purple cloud, but the gunk is not affected. It may be organic but it's not fungus."
Check putting the coralicide on the dirty med-gunk-cabinet:
[The "convert putting a topical chem-source on to inserting" rule bypassed us, so we have to trigger topically-applying manually.]
retire the noun by applying to the second noun;
instead try topically-applying the noun to the second noun;
Check tapping the coralicide on the dirty med-gunk-cabinet:
retire the noun by applying to the second noun;
instead try topically-applying the noun to the second noun;
Report topically-applying the coralicide to the med-gunk-cabinet:
instead say "You carefully drip the coralicide over the cabinet. It fumes away in a bitter pink haze, but the gunk is not affected. It may be organic but it's not coral."
Check putting a nontopical chem-source on the med-gunk-cabinet:
instead try tapping the noun on the med-gunk-cabinet.
Check tapping the bamuriatic acid on the dirty med-gunk-cabinet:
retire the bamuriatic acid by applying to the med-gunk-cabinet;
now the med-gunk-cabinet is clean;
mark g-med-gunk-cabinet as done;
now the tool-used of g-med-gunk-cabinet is bamuriatic acid;
instead say "You dribble the bamuriatic acid over the cabinet, and the guck starts to dissolve away. (The smell is horrific.) You can't get the cabinet entirely clean, but you manage to free up the hinges, at least."
Check tapping the bamuriatic acid on the clean med-gunk-cabinet:
instead say "The cabinet is clean enough to open already."
Check tapping a nontopical chem-source on the dirty med-gunk-cabinet:
say "You sprinkle some [short-description of noun] onto the cabinet, but it doesn't affect the gunk";
if the noun is muriatic acid or the noun is vitriolic acid:
instead say " much.";
instead say " at all."
Check tapping the brass-pin on the dirty med-gunk-cabinet when the symbol-type of the brass-pin is gensaturation-symbol:
say "You carefully lay the [symbol-type of the noun] symbol against [the second noun]";
uninscribe the noun;
instead say ". The symbol discharges, but the cabinet doesn't get any cleaner. The metal is covered with gunk, not corroded."
Check tapping the steel-bolt on the dirty med-gunk-cabinet when the symbol-type of the steel-bolt is gensaturation-symbol:
say "You carefully lay the [symbol-type of the noun] symbol against [the second noun]";
uninscribe the noun;
instead say ". The symbol discharges, but the cabinet doesn't get any cleaner. The metal is covered with gunk, not corroded."
Section - Med Wing
The Med-Wing is a recallable room. The printed name is "Medical Wing".
The zone is med-wing-zone.
The description is "This would be a waiting room, were it not as cluttered as every other part of the medical wing. The uncomfortable-looking chairs are outnumbered by the obscure-looking equipment.[para]You know that the [if aeroclave is open]open[else]sealed[end if] glass box is an aeroclave. Next to it rests a heavy steel tank, a pressurized container of elemental air. A miasma gong hangs by the door.[para]You see a workroom to the east, and a very dark doorway to the west. A passage south leads to more of the medical wing, but a fracture blocks it."
Understand "med", "medical", "wing" as Med-Wing.
The can't-go of Med-Wing is "Exits are north, east, and west, plus the blocked passage south."
The aroma-description of Med-Wing is "[if desc-aroma is no-odor]You detect only a lingering trace of disinfectant[else]You smell only the [desc-aroma][clear-desc-aroma], and a lingering trace of disinfectant[end if]".
For room-visiting Med-Wing:
now Med-Wing-Hall is shifted.
Check going south in Med-Wing:
instead try entering the med-fracture.
Check going outside in Med-Wing:
instead try going north.
The aeroclave is in the Med-Wing. The aeroclave is prominent-scenery.
The air-tank is in the Med-Wing.
The miasma-gong is in the Med-Wing.
Rule for writing a paragraph about the aeroclave:
now the aeroclave is mentioned;
if the aeroclave is not empty:
say "Inside the aeroclave [is-are a list of things *in the aeroclave roomily]";
say ". The aeroclave is [open-closed aeroclave]."
Check waving the purity-lodestone in Med-Wing:
instead say "The silver chain points straight at the tank, no matter what you do."
The med-void-door is an open unopenable scenery door. The printed name is "dark doorway".
The description is "The doorway is very, very dark."
Understand "door", "doorway", "dark", "very" as the med-void-door.
The Med-Void-Room is west of the med-void-door.
The Med-Wing is east of the med-void-door.
Check searching the med-void-door:
instead try examining the med-void-door.
Check inspecting the med-void-door with the oculus:
instead say "The oculus shows the dark doorway as associated with time."
The med-fracture is a fracture in the Med-Wing.
The description is "A fracture blocks the passage south."
The med-seats are a plural-named scenery supporter in the Med-Wing. The printed name is "chairs".
The description is "The seats are not designed to make waiting a pleasant experience."
Understand "seat", "seats", "chair", "chairs", "uncomfortable" as the med-seats.
Check entering the med-seats:
instead say "You've spent enough hours of your life in these chairs, waiting to be treated for burns, alchemical dermatitis, or that embarrassing situation last year."
Check taking the med-seats:
instead say "The chairs don't need to be rearranged."
Check pushing the med-seats:
instead try taking the med-seats.
Check pulling the med-seats:
instead try taking the med-seats.
The med-equipment is a far-sight in the Med-Wing. The printed name is "equipment".
The reach-reason is "You'll have to be more specific."
The description is "The aeroclave, the steel tank, and the gong are most prominent."
Understand "obscure", "obscure-looking", "equipment" as the med-equipment.
Section - Med Void Room
The Med-Void-Room is a reset-room.
The near-room is the Med-Wing.
The description is "You find yourself drifting through a familiar void."
Section - Med Lab
The Med-Lab is a recallable room. The printed name is "Medical Workroom".
The zone is med-wing-zone.
The description is "This side room is equipped for routine medical workings. You see a white workbench with a ritual bound and gestalt shelf. The only exit is back west."
Understand "med", "medical", "lab", "laboratory", "workroom" as Med-Lab.
Med-Lab is east of Med-Wing.
The can't-go is "The only exit is west."
The aroma-description is "The room smells scrubbed clean".
The med-bench is a mineralish prominent-scenery ritual-bound in the Med-Lab. The printed name is "workbench bound".
The short-adjective is "workbench bound".
The description is "The lab is furnished with an alchemical workbench of clean white fused quartz. An alchemical bound is incised in the surface."
Understand "workbench", "work", "bench", "clean", "white", "fused", "quartz" as the med-bench.
Rule for writing a paragraph about the med-bench:
if the med-bench is empty-inactive:
now the med-bench is mentioned;
stop;
say the visible state of the med-bench.
The med-shelf is a ritual-shelf in the Med-Lab.
The description is "You see a small shelf just above and behind the workbench[if the med-shelf is empty]. The gestalt shelf is empty[end if]."
The linked-shelf of the med-bench is the med-shelf.
Understand "small" as the med-shelf.
The initial appearance of the aithery-mold is "You see a small clay disk on the floor[if Captain-Quarters is visited]. It looks like another reverse mold -- this one is for Aithery File[else]. It has an imprinted design -- it looks like a reverse mold for an Aithery File badge[end if]."
The initial appearance of the scratched-bubble is "You[if aithery-mold is not handled] also[end if] notice a fist-sized glass bubble with a valve on it."
Chapter - Nave and West Side
Section - The Nave
The Nave is a recallable room.
The zone is core-hall-zone.
The description is "[Nave-desc]".
Understand "nave-room" as the Nave.
To say Nave-desc:
say "The Nave is the marcher's heart, though the rows of benches are empty now. The seats face a pedestal, on which is a ritual bound and shelf. The side walls boast symbolic frescos; the south wall is a high, ornamented metal mesh -- the writ screen -- which separates the Nave from the Chancel";
if initial-marriage is false:
say ".[para]A mural has been defaced with more of those twisted black marks";
else:
if Nave-Crawl is not visited:
say ".[para]Something has happened here";
say ".[para]The murals are badly cracked. One to the southwest has collapsed entirely, leaving a ragged gap which leads down into a crawlspace";
say ".[para]The main corridors run east and west from here, and the [Retort's] entry hall is north";
say period.
For room-visiting the Nave:
mark nave-ritual-location as done.
The can't-go of the Nave is "You can go east, west, or north[if initial-marriage is true]. There's also a crack leading down[end if]."
The aroma-description of the Nave is "[if desc-aroma is no-odor]The Nave has always smelled faintly of oranges. You're not sure why. Something about the oil they use to polish the woodwork[else]The Nave smells faintly of oranges[end if]".
Check going south in the Nave:
instead try entering the writ-screen.
Check going down from the Nave when initial-marriage is false:
instead say "[can't-go of the Nave][line break]".
Check going down from the Nave when initial-marriage is true:
say "You twist yourself through the crack."
Check going southwest in the Nave when initial-marriage is true:
instead try going down.
The nave-script is alien-script in the Nave.
The description is "More twisting black marks crawl up one corner of the mural and across the ceiling. They are as incomprehensible as the first set... although you are left with an itching sense of familiarity in the back of your mind."
[Removed after initial-marriage.]
The nave-mural is readable scenery in the Nave. The printed name is "mural".
The description is "The murals depict Alchemical Man passing through the Eight Stages of calcination, dissolution, sublimation and so on. It's wonderfully detailed and you can stare at it for hours, which is of course the point, even though these medieval theories have long since been subsumed into modern alchemical science.[para][if initial-marriage is false]A mural has been defaced with more of those twisted black marks. It's the scene of conjunction, in the southwest corner. (Always a favorite.)[else]In the southwest corner, the mural depicting conjunction has collapsed in on itself. Behind it is a ragged crack, and rubble which slopes down into an open space. It's wide enough for your body.[end if]".
Understand "symbolic", "fresco", "frescos", "frescoes", "mural", "murals", "wall", "walls", "alchemical", "man", "eight", "stages", "conjunction", "calcination", "sublimation", "dissolution", "fermentation", "coagulation" as the nave-mural.
Understand "crack", "gap", "ragged", "broken", "crawlspace" as the nave-mural when initial-marriage is true.
Check reading the nave-mural when the nave-script is in the Nave:
instead try examining the nave-script.
Check rubbing the nave-mural when the nave-script is in the Nave:
instead try rubbing the nave-script.
Check entering the nave-mural:
if initial-marriage is true:
instead try going down;
instead say "You're not paint."
Check repairing the nave-mural:
if the nave-script is in the Nave:
instead try rubbing the nave-script;
instead say "The mural is beyond repair."
Check inspecting the nave-mural with the oculus:
instead say "When viewed through the oculus, the mural is a wonderful spectrum of alchemical operations, interrupted by [if initial-marriage is false]the alien symbology[else]the crack[end if]."
The writ-screen is a metallic scenery backdrop. The printed name is "writ screen".
The description is "The writ screen is a mesh barrier[if the location is the Nave] which forms the south wall of the Nave. You recall the ceremonies of the [Retort's] first launch: alchemical energies crackling over the screen, as the high rectors enacted potent rituals on the other side[else] which forms the north wall of the Chancel[end if]."
Understand "writ", "screen", "metal", "mesh", "barrier", "high", "ornament", "ornamented", "wall", "walls" as the writ-screen.
The writ-screen is in the Nave. The writ-screen is in the Chancel.
Check entering the writ-screen:
if the location is the Nave:
instead say "The Chancel is south of the Nave, but there is no passage between them; the writ screen blocks your way[if the Chancel is not visited]. The higher officers enter the Chancel from another door on the far side[else]. You'll have to go around through the high wing[end if].";
else:
instead say "The Nave is north of the Chancel, but there is no passage between them; the writ screen blocks your way."
Check opening the writ-screen:
instead say "The writ screen is an unbroken wall of mesh; it cannot be opened."
Check searching the writ-screen:
if the location is the Nave:
instead try examining the chancel-view;
else:
instead try examining the nave-view.
Check climbing the writ-screen:
instead say "That's the sort of exercise that you excel at failing in your physical training drills. Anyway, the mesh is too tight to get your toes into."
Check taking the writ-screen:
instead say "That's not portable at all."
Check shaking the writ-screen:
instead say "The screen yields a bit when you lean on it, but you're not going to shift it."
Check pushing the writ-screen:
instead try shaking the writ-screen.
Check pulling the writ-screen:
instead try shaking the writ-screen.
Check inserting something into the writ-screen:
instead say "The mesh is too tight to push anything through."
Check inspecting the writ-screen with the planetary-lens:
instead say "When viewed through the lens, the writ screen is entirely opaque."
Check inspecting the writ-screen with the oculus:
instead say "When viewed through the oculus, the writ screen is entirely opaque."
The nave-benches are a plural-named scenery supporter in the Nave. The printed name is "benches".
The description is "The crew gathers here every time the [Retort] rigs out. You recall Captain Hart at the pedestal, the Master Rector behind the writ screen, and the rows of bowed heads as every marchman concentrates on the rituals that will translate the [Retort] to the higher spheres."
Understand "bench", "benches", "seat", "seats", "rows", "rows of" as the nave-benches.
Check entering the nave-benches:
instead say "Now is not the time to rest."
Check looking under the nave-benches:
instead say "This place is always kept tidy."
The nave-bound is a mineralish prominent-scenery nave-bound-level ritual-bound in the Nave. The printed name is "pedestal bound".
The short-adjective is "pedestal bound".
The description is "The ceremonial pedestal is carved of serpentine, with an ornate ritual bound on top. The gestalt shelf is a wrought-iron affair on the side[if the nave-bound is empty-inactive]. Important rituals are often performed here by the rectors, although of course the [Retort's] most powerful rituals occur in the Chancel[end if]."
Understand "pedestal", "serpentine", "ceremonial" as the nave-bound.
Rule for writing a paragraph about the nave-bound:
if the nave-bound is empty-inactive:
now the nave-bound is mentioned;
stop;
say the visible state of the nave-bound.
The nave-shelf is a metallic ritual-shelf in the Nave.
The description is "A wrought-iron shelf extends to one side of the pedestal[if the nave-shelf is empty]. The gestalt shelf is empty[end if]."
Understand "wrought", "iron", "wrought-iron" as the nave-shelf.
The linked-shelf of the nave-bound is the nave-shelf.
The chancel-view is a far-sight in the Nave. The printed name is "Chancel".
The description is "The Chancel is a smaller chamber to the south. You can see another ritual bound there, and other alchemical accoutrements[if the Chancel is not visited]. Of course you've never set foot on that side of the screen. Only the [Retort's] senior officers and rectors are permitted inside, and they enter from the high wing where scrubs never venture[end if]."
Understand "chancel" as the chancel-view.
The reach-reason is "The Chancel is on the other side of the writ screen."
Check entering the chancel-view:
instead try entering the writ-screen.
Check inspecting the chancel-view with the oculus:
instead try inspecting the writ-screen with the second noun.
Check inspecting the chancel-view with the planetary-lens:
instead try inspecting the writ-screen with the second noun.
Section - Nave Crawl
The Nave-Crawl is a recallable low-ceilinged room. The printed name is "Nave Crawlway".
The zone is nave-crawl-zone.
The recall-minor is true.
Understand "crawl", "crawlspace", "crawlway", "nave" as the Nave-Crawl.
The description is "This was once the north end of a crawlway, but the passage has collapsed, leaving only this small space. Debris is heaped up to the south. Light slants in from a gap in the ceiling."
The Nave-Crawl is below the Nave.
The can't-go is "The only way out is crawling up, to the northeast."
Check going up from the Nave-Crawl:
say "You pull yourself back out into open air."
Check going northeast in the Nave-Crawl:
instead try going up.
Check going outside in the Nave-Crawl:
instead try going up.
Check going south in the Nave-Crawl:
instead say "The crawlway is entirely blocked by fallen debris."
Check going north in the Nave-Crawl:
instead say "The crawlway ends here."
The nave-debris is scenery in the Nave-Crawl. The printed name is "debris".
The description is "The crawlway to the south has collapsed. Slabs of rock lie half-buried in a spill of earth. It doesn't look very stable, even now."
The nave-debris can be shifted. [got sheet out; resettable]
The nave-debris can be ever-tried. [tried digging; resettable]
Understand "debris", "rubble", "heap", "fallen", "slab", "slabs", "rock", "earth", "crawl", "crawlway" as the nave-debris.
Definition: the nave-debris is search-ready if nave-debris-fact is known and the nave-debris is not shifted.
Check searching the nave-debris when the nave-debris is search-ready:
now the nave-debris is shifted;
now the nave-debris is ever-tried;
now the sh-aither-protection is in Nave-Crawl;
instead say "You locate the correct slabs and dig between them, trying to disturb the earth as little as possible. After a few moments, the corner of a dirty sheet of paper becomes visible. You work your fingers in and yank; the sheet falls to the floor."
Check examining the nave-debris when the nave-debris is search-ready:
instead try searching the nave-debris.
Check pushing the nave-debris when the nave-debris is search-ready:
instead try searching the nave-debris.
Check searching the nave-debris:
if the nave-debris is ever-tried:
instead say "You dig a little more, but it's clear that any serious excavation is going to bring the entire rubble heap down. You give it up.";
now the nave-debris is ever-tried;
instead say "You tentatively dig under one of the slabs. It shifts, and an alarming runnel of earth slides down past it. You quickly back away, hoping that the entire heap isn't about to envelop you."
Check pushing the nave-debris:
if the nave-debris is ever-tried:
instead say "You push a little more, but it's clear that any serious excavation is going to bring the entire rubble heap down. You give it up.";
now the nave-debris is ever-tried;
instead say "You tug on one of the slabs. It shifts, and an alarming runnel of earth slides down past it. You quickly back away, hoping that the entire heap isn't about to envelop you."
Check pulling the nave-debris:
instead try pushing the nave-debris.
Check turning the nave-debris:
instead try pushing the nave-debris.
Check touching the nave-debris:
instead say "You gingerly poke at one of the slabs. It doesn't move."
Check taking the nave-debris:
instead say "You can't haul all of this rubble away by yourself."
Check repairing the nave-debris:
instead say "Repairing the collapsed crawlway is a job for a team of engineers, not a trainee alchemist."
Check rubbing the nave-debris:
[Supports "clean/sweep", not so good for "rub"]
instead try repairing the nave-debris.
Check entering the nave-debris:
instead try going south.
Check climbing the nave-debris:
instead try going south.
Check recalling the nave-debris when the nave-debris-fact is known:
instead try recalling the nave-debris-fact.
Report topically-applying the polar-oil to the nave-debris:
instead say "You carefully pour the polar oil over the debris. For a moment it seems to puddle oddly, but then it all drips away, leaving no trace."
The initial appearance of the highlime is "You see a vial of white powder lying in the rubble. It's labelled 'highlime'."
Section - Portico
The Portico is a recallable room.
The zone is core-hall-zone.
The description is "You stand in the foyer of the marcher. It's wide and comfortably appointed, with lounging seats and potted tropical ferns. The [Retort] likes to look its best for visitors.[para]The main doors to the north are closed, however. A broad window in the east wall reveals the reason: the world outside is a Hadean land, grey and lifeless[if the F-sharp-chime is part of the p-window]. The F-sharp chime is embedded in the window[end if].[para]The Nave is south, and a narrow dark doorway opens to the west."
The Portico is north of the Nave.
The can't-go of the Portico is "With the main doors closed, you can only go south or west[if g-portico-window is ever-done] -- or east through the window[end if]."
The aroma-description of the Portico is "You can detect traces of the aromas of many lands".
Check look-outward-ing in the Portico:
instead try searching the p-window.
The p-window is a glass-window.
[Glass-passable door "window"; really always open]
[See also sv-window]
The p-window can be ever-tried. [resettable]
The p-window can be breath-vacuum-glossed.
The p-window is east of the Portico and west of the Out-Plain.
Understand "heavy", "broad", "glass", "eastern", "window" as the p-window.
Check examining the p-window:
if the location is the Portico:
say "The thick glass is a bit wavy, but you can see a grey, stony wasteland outside. The sky above is pitch-night with stars and an icy bright sun";
else:
say "The thick glass is a bit wavy, but you can see the portico on the other side";
if the F-sharp-chime is part of the p-window:
say ".[para][The F-sharp-chime] is stuck in the glass, vibrating steadily";
instead say "."
Check searching the p-window:
instead try examining the p-window.
Check touching the p-window:
if the F-sharp-chime is part of the p-window:
instead say "You feel a steady vibration... and a yielding, as the glass slides through your flesh. It's rather unnerving.";
instead say "It feels like solid glass."
Check opening the p-window:
instead say "The window can't be opened. (There's vacuum on the other side, anyhow.)"
Check closing the p-window:
instead say "The window is fixed closed."
Check listening to the p-window when the F-sharp-chime is part of the p-window:
instead try listening to the F-sharp-chime.
Check attacking the p-window:
instead try smashing the p-window.
Check smashing the p-window:
if the F-sharp-chime is part of the p-window:
instead say "You probably couldn't break it in this state.";
instead say "The glass won't break; nor would you want it to."
Check going when the door gone through is the p-window:
if the F-sharp-chime is part of the p-window:
if the location is Portico and vacuum-potion-remaining is zero:
[Handle auto-solutions... for this sub-case]
if g-portico-window is ever-done:
instead goal-travel to Out-Plain;
say "You press your fingers against the glass. You feel a steady vibration... and a yielding, as the glass slides through your flesh. It's rather unnerving.[para]More unnerving, however, is the suction you feel on the other side. Walking through into vacuum would be deadly";
say breath-vacuum-potion-gloss p-window;
stop the action;
mark the g-portico-window as done;
if the p-window is not ever-tried:
now the p-window is ever-tried;
say "You press your fingers against the glass. You feel a steady vibration... and a yielding, as the glass slides through your flesh. It's rather unnerving, and you push the rest of your body through as quickly as possible.";
else:
say "You slide back through the vibrating glass.";
if the location is Portico:
say "[line break][vacuum-entry-reaction].";
perform inventory vacuumization in the Out-Plain;
continue the action;
[Handle auto-solutions...]
if g-portico-window is ever-done:
if the location is Portico:
instead goal-travel to Out-Plain;
else:
instead goal-travel to Portico;
instead say "The window is solid glass."
Check putting the F-sharp-chime on the p-window when the ring-time of the F-sharp-chime is not zero:
instead try tapping the F-sharp-chime on the p-window.
Check inserting the F-sharp-chime into the p-window when the ring-time of the F-sharp-chime is not zero:
instead try tapping the F-sharp-chime on the p-window.
Check tapping the F-sharp-chime on the p-window when the ring-time of the F-sharp-chime is not zero:
if the symbol-type of the F-sharp-chime is decoherence-symbol:
invoke reset, involuntarily;
instead say "You press the chime against the window. The glass vibrates, and the bronze sinks slowly into it. The frequency of the vibration rises as you push. The glass seem to ripple -- and then explodes into splinters, all at once.[para]Unfortunately the glass explodes in all directions, much of it through you. Somewhere there is a rising howl of air escaping through the window, but you are already slipping into unconsciousness.";
if the symbol-type of the F-sharp-chime is permeability-symbol:
if the F-sharp-chime is part of the p-window:
instead say "It's already stuck in the window.";
now the ring-time of the F-sharp-chime is three;
now the F-sharp-chime is part of the p-window;
instead say "You press the chime against the window. The glass vibrates, and the bronze sinks slowly into it -- not like metal into tar, but like a knife sliding between infinitesimal layers of glass.[para]When you draw your hand away, the chime remains suspended in the glass. Its vibration continues at a steady pitch.";
instead say "(BUG) F-sharp-chime on p-window: [symbol-type of the F-sharp-chime]."
Check inserting something into the p-window when the F-sharp-chime is part of the p-window:
instead say "You're not sure about the mechanics of pushing things through permeable glass. Easier to walk through yourself."
Check inserting something into the p-window:
instead say "You can't push things through solid glass."
The portico-view is a far-sight in the Portico. The printed name is "wasteland".
Understand "wasteland", "world", "grey", "gray", "stony", "hadean", "land", "landscape", "black", "sky", "star", "stars", "icy", "tiny", "bright", "sun", "lifeless", "desolate", "desolation" as the portico-view.
The description is "Through the eastern window, you see a wasteland of grey stone and grey dust -- a Hadean land. The sky is black ink and ice-clear stars, with a tiny bright sun, for there is no air to blur it, and no movement, and no life."
The reach-reason is "The wasteland is on the other side of the window."
Check entering the portico-view:
instead try going east.
Check inspecting the portico-view with the p-window:
instead try examining the portico-view.
Check inspecting the portico-view with the planetary-lens:
instead say "The lens displays the landscape's Hadean nature."
The porti-void-door is an open unopenable scenery door. The printed name is "dark doorway".
The description is "The doorway is very, very dark."
Understand "door", "doorway", "dark", "narrow" as the porti-void-door.
The Portico-Void-Room is west of the porti-void-door.
The Portico is east of the porti-void-door.
Index map with the Portico-Void-Room mapped west of the Portico.
Check searching the porti-void-door:
instead try examining the porti-void-door.
Check inspecting the porti-void-door with the oculus:
instead say "The oculus shows the dark doorway as associated with time."
The porti-main-doors are a plural-named scenery unopenable scenery door. The printed name is "main doors".
The description is "When the [Retort] is home, or grounded in a Gaian land, these doors open wide. But the marcher's interior can't be exposed to the desolation you see through the window. In a land such as this, the crew can only come and go through the airlock, or perhaps the exoscaphe."
The refer-name is "Portico main doors".
Understand "door", "doors", "main", "twin" as the porti-main-doors.
The porti-main-doors are north of the Portico.
[Fake connection so that I7 compiles a found_in property.]
The porti-main-doors are south of the Portico-Void-Room.
Check opening the porti-main-doors:
instead say "The main doors are sealed. And for good reason."
The portico-seats are a plural-named scenery supporter in the Portico. The printed name is "seats".
The description is "The seats are overstuffed, cozy-looking, and never ever to be sat upon by lowly ensigns."
Understand "lounge", "lounging", "seat", "seats", "chair", "chairs", "overstuffed" as the portico-seats.
Check entering the portico-seats:
instead say "The terror of Sergeant Brooks restrains you, even now."
Check taking the portico-seats:
instead say "Rearranging the furniture on the deck of the [Retort]? No thanks."
Check pushing the portico-seats:
instead try taking the portico-seats.
Check pulling the portico-seats:
instead try taking the portico-seats.
The porti-plants are plural-named scenery in the Portico. The printed name is "ferns".
The description is "They're not actually tropical ferns. They're artfully sewn silk imitation ferns. The real ones kept dying for some reason, and the Captain got tired of paying for replacements out of the marcher's purse."
Understand "tropical", "fern", "ferns", "plants", "silk", "imitation", "fake", "potted", "pot", "pots" as the porti-plants.
Check taking the porti-plants:
instead say "You have no need of leaves from the fake plants."
Check smelling the porti-plants:
instead say "The plants have no scent."
Check inspecting the porti-plants with the oculus:
instead say "Through the oculus, the plants look tacky."
Section - Portico Void Room
The Portico-Void-Room is a reset-room.
The near-room is the Portico.
The description is "You find yourself drifting through a familiar void."
Section - West Side Hall
The West-Side-Hall is a room. The printed name is "West Side Hallway".
The zone is core-hall-zone.
The description is "The [Retort's] main hallway continues from the Nave, to the east, towards the exoscaphe bay to the west. A cross-corridor runs north towards quarters wing and south to the paper garden."
West-Side-Hall is west of the Nave.
West-Side-Hall is wallpaper-enabled.
The can't-go of West-Side-Hall is "You can go east to the Nave, west towards the exoscaphe bay, north towards quarters, or south to the garden."
Chapter - Quarters
Section - Quarters Hall
The Quarters-Hall is a room. The printed name is "Quarters Access".
The zone is core-hall-zone.
The description is "This wing of the [Retort] is all quartering and mess. The hall continues north to the elevated realms of the officers. Your lowly domain is to the west. The body of the marcher is south."
The Quarters-Hall is north of West-Side-Hall.
The Quarters-Hall is wallpaper-enabled.
The can't-go of Quarters-Hall is "You can go north, west, or south."
Check going up in the Quarters-Hall:
instead say "Officer country is metaphorically above you, but in fact to the north."
Section - Officer Country
Officer-Hall is a room. The printed name is "Officer Country".
The zone is core-hall-zone.
The description is "It is widely rumored that an ensign walking this far up the hall will instantly combust[if not currently fireproof]. You still might, you suppose[else] -- although you suppose you're safe from that now[end if]. The officer's mess is somewhere up there, but a fracture prevents you from going any farther.[para]The senior officers['] quarters are east, and the juniors['] are west."
Officer-Hall is north of Quarters-Hall.
The Officer-Hall is wallpaper-enabled.
The can't-go is "The hall north is blocked, so you can only go east, west, or back south."
Check going north in the Officer-Hall:
instead try entering the offhall-fracture.
The offhall-fracture is a fracture in the Officer-Hall.
The description is "A fracture lies to the north, blocking the rest of the hallway[if Ch1-Captain is in Officer-Hall]. Captain Hart is standing frozen on the other side[end if]."
Check entering the offhall-fracture:
instead say "This fracture is as impermeable as all the others."
The initial appearance of Ch1-Captain is "[meet Ch1-Captain][one of]That's the Captain leaning against the wall! You freeze in reflexive panic, before realizing that she is behind the fracture, frozen herself[or]You see the Captain leaning against the wall, caught behind the fracture[stopping]."
Section - Junior Quarters
Junior-Quarters is a recallable room. The printed name is "Junior Quarters".
The zone is core-hall-zone.
The description is "This long room is the bunk space of the junior officers -- 'junior' meaning 'still above you,' of course. The bunks are narrow but fussily neat, with a locker next to each. The exit is to the east."
Junior-Quarters is west of Officer-Hall.
Understand "junior", "quarters" as the Junior-Quarters.
The can't-go is "You can only exit east."
The aroma-description is "Despite the painful attention to cleanliness, the room retains the aroma of overworked marchmen".
Check going outside in Junior-Quarters:
instead try going east.
The junior-fuse-cabinet is a prominent-scenery standard-cabinet in the Junior-Quarters. The printed name is "large locker".
The opening-goal is g-junior-fuse-cabinet.
The junior-fuse-cabinet can be clean or dirty.
Understand "locker", "lockers", "latch", "large", "largest" as the junior-fuse-cabinet.
Understand "fuse", "white", "white-fuse", "white-cord", "glittering", "cord", "knot" as the junior-fuse-cabinet when the junior-fuse-cabinet is dirty.
[See also scaphe-fuse-cabinet.]
Rule for writing a paragraph about the junior-fuse-cabinet:
if the junior-fuse-cabinet is closed:
if the junior-fuse-cabinet is dirty:
say "The largest locker draws your eye: its latch is tied shut with a knot of white cord";
else:
say "The large locker is closed";
else:
say "The large locker is open";
if the junior-fuse-cabinet is empty:
say " but empty";
else:
say "; inside [is-are a list of things *in the junior-fuse-cabinet roomily]";
if the sh-gold-ignite is in Junior-Quarters:
now the sh-gold-ignite is mentioned;
say ". A broad sheet of paper is pinned next to the locker";
instead say "."
Check examining the junior-fuse-cabinet:
if the junior-fuse-cabinet is closed:
if the junior-fuse-cabinet is dirty:
say "The locker is closed. The latch is bound up with a tight knot of glittering white cord";
else:
say "The locker is unlocked, but closed";
else:
say "The locker is open";
if the junior-fuse-cabinet is empty:
say ", but empty";
else:
say ". Inside you see [a list of things *in the junior-fuse-cabinet roomily]";
instead say ".";
Check freeing the dirty junior-fuse-cabinet:
instead say "You pick at the white cord, but the knot is too tight."
Check cutting the dirty junior-fuse-cabinet:
if the player carries the scalpel:
instead try unlocking the junior-fuse-cabinet with the scalpel;
instead say "You have nothing to cut the cord with."
Check unlocking the dirty junior-fuse-cabinet with the scalpel:
now the junior-fuse-cabinet is clean;
mark g-junior-fuse-cabinet as done;
now the tool-used of g-junior-fuse-cabinet is the scalpel;
instead say "You hack at the white-fuse with the scalpel. It's a messy job, but after a few moments, the cord falls to bits. You try to ignore the feeling that you've cheated on a test.";
Check igniting the dirty junior-fuse-cabinet with el-fire:
now the junior-fuse-cabinet is clean;
mark g-junior-fuse-cabinet as done;
now the tool-used of g-junior-fuse-cabinet is the second noun;
now the fire-source-used of g-junior-fuse-cabinet is the second noun;
instead say "You hold [the second noun] under the white-fuse. The cord ignites with a flash and a [em]pop![/em] It burns away almost instantly, leaving only the smell of burnt metal in the air."
Check igniting the dirty junior-fuse-cabinet with something:
instead say "You wave [the second noun] under the white-fuse, but the cord refuses to ignite."
Check igniting the clean junior-fuse-cabinet with something:
instead say "You've already burned off the white-fuse."
Check opening the dirty junior-fuse-cabinet:
if g-junior-fuse-cabinet is ever-done:
goal-perform g-junior-fuse-cabinet;
if the junior-fuse-cabinet is open:
say "You open the locker";
if the junior-fuse-cabinet is empty:
say ", which is empty";
else:
say ", revealing [a list of things *in the junior-fuse-cabinet]";
say ".";
stop the action;
instead say "The locker won't open -- its latch is tied shut."
Does the player mean burning the dirty junior-fuse-cabinet:
it is very likely.
Does the player mean burning the dirty junior-fuse-cabinet with something:
it is very likely.
The junior-bunks are a plural-named bunk in Junior-Quarters. The printed name is "bunks".
The description is "The bunks look more comfortable than yours. Not a difficult constraint, to be sure."
Understand "bunks", "beds", "narrow" as the junior-bunks.
Check looking under the junior-bunks when the labyrinth-tile is in Junior-Quarters and the labyrinth-tile is not handled:
instead say "A clay tile is lying under one of the bunks. It is imprinted with a labyrinth pattern."
The initial appearance of the labyrinth-tile is "You also notice a clay tile lying under one of the bunks."
Section - Deck Suite
The Deck-Suite is a recallable room. The printed name is "Deck Suite".
The zone is core-hall-zone.
The description is "[deck-suite-desc]".
Deck-Suite is east of Officer-Hall.
Understand "deck", "suite" as the Deck-Suite.
To say deck-suite-desc:
say "This looks like a comfortable place to drink tea. It must be a lounge set aside for the deck officers -- the three important enough to rate private staterooms";
if the fake-arms-door is in Deck-Suite and fake-arms-door is closed:
if recq-door is closed and capq-door is closed:
say ". The three doors are marked with the symbols of Venture (north), Alchemy (south), and Aithery (east). All three are closed";
else if recq-door is closed and capq-door is open:
say ". The Venture door (north) and the Alchemy door (south) are closed; the Aithery door to the east is open";
else if recq-door is open and capq-door is closed:
say ". The Venture door (north) and the Aithery door (east) are closed; the Alchemy door to the south is open";
else:
say ". The Venture door to the north is closed; the Aithery door (east) and the Alchemy door (south) are both open";
else:
[fake-arms-door is gone or open]
if recq-door is closed and capq-door is closed:
say ". The Aithery door (east) and the Alchemy door (south) are both closed. The Venture door[if the fake-arms-door is not in Deck-Suite] to the north[end if] is open";
else:
say ". The Alchemy door to the south is [open-closed recq-door]; the Aithery door to the east is [open-closed capq-door]. The Venture door[if the fake-arms-door is not in Deck-Suite] to the north[end if] is also open";
if the fake-arms-door is in Deck-Suite:
say ", but rather than a stateroom, you see a fracture and a black Hadean land beyond";
else:
say "; it appears to be a normal door now";
say period;
The can't-go of the Deck-Suite is "The hallway is west; doors are north, south, and east."
Check going north in the Deck-Suite when the fake-arms-door is in Deck-Suite:
instead try entering the fake-arms-door.
Check going outside in the Deck-Suite:
instead try going west.
The no-tea is a far-sight in the Deck-Suite. The printed name is "no tea".
The description is "Sadly, no tea is present."
The reach-reason is "You can't see any such tea."
The lens-view is "a bowl of petunias and a sperm whale".
Understand "tea", "no tea" as no-tea.
The deck-cabinet is a lockable prominent-scenery standard-cabinet in the Deck-Suite.
The opening-goal is g-deck-cabinet.
Understand "aithery", "file", "lock" as the deck-cabinet.
Rule for writing a paragraph about the deck-cabinet:
if the deck-cabinet is closed:
if the deck-cabinet is locked:
say "A locked cabinet hangs on the wall";
else:
say "A cabinet on the wall is closed, though not locked";
else:
say "A cabinet on the wall is open";
if the deck-cabinet is empty:
say ", but empty";
else:
say "; inside [is-are a list of things *in the deck-cabinet roomily]";
instead say "."
Check examining the deck-cabinet:
say "The cabinet is a squarish compartment of some anonymous alloy";
if the deck-cabinet is closed:
if the deck-cabinet is locked:
say ". It is locked with an Aithery File lock";
else:
say ". It is closed, but the Aithery File lock is unlocked";
else:
say ", with an Aithery File lock. It is wide open";
if the deck-cabinet is empty:
say ", but empty";
else:
say ".[para]Inside you see [a list of things *in the deck-cabinet roomily]";
instead say "."
Check opening the locked deck-cabinet:
if g-deck-cabinet is ever-done:
goal-perform g-deck-cabinet;
if the deck-cabinet is open:
say "You unlock and open the cabinet";
if the deck-cabinet is empty:
say ", which is empty";
else:
say ", revealing [a list of things *in the deck-cabinet]";
say ".";
stop the action;
instead say "The cabinet is locked with an Aithery File lock."
Check putting a metal-seal on the deck-cabinet:
instead try unlocking the deck-cabinet with the noun.
Check tapping a metal-seal on the deck-cabinet:
instead try unlocking the deck-cabinet with the noun.
Check inspecting the deck-cabinet with the oculus:
instead say "Through the oculus, you perceive the symbolism of the Aithery File: [symbol-assoc of aithery-file]."
Check unlocking the deck-cabinet with a clay-mold:
instead say "An inverse impression of a seal isn't the same as a seal."
Report unlocking the deck-cabinet with:
now g-deck-cabinet is ever-done;
instead say "You touch [the second noun] to the cabinet, and the lock snaps calmly open."
Report locking the deck-cabinet with:
instead say "You lock the cabinet again, using [the second noun]."
Lock-matching rule for the deck-cabinet when key-param is a metal-seal:
if the file of key-param is aithery-file:
rule succeeds;
else:
rule fails.
The fake-arms-door is a syn-gap-door in the Deck-Suite. The printed name is "Venture door".
The examine-target is the arms-lab-landscape.
The refer-name is "Deck Suite Venture door".
Understand "door", "venture" as the fake-arms-door.
Understand "master", "master's", "masters", "arms", "master-at-arms", "quarters" as the fake-arms-door.
Check examining the fake-arms-door when the fake-arms-door is closed:
instead say "This should be the quarters of the Master-at-Arms. [The fake-arms-door] is [open-closed fake-arms-door]."
Check opening the fake-arms-door when the fake-arms-door is closed:
now the fake-arms-door is open;
if the fake-arms-door is undiscovered:
now the fake-arms-door is discovered;
instead say "You open the door, and discover another Hadean landscape.[para]This world is dark, layered with black dust -- not the common stone-grey of most Hadean lands. The sun is a blinding pinprick on the horizon.";
else:
instead say "You open the door, revealing a landscape buried in black dust."
Check closing the fake-arms-door when the fake-arms-door is open:
now the fake-arms-door is closed;
instead say "You shut the door on the Hadean land."
The arms-lab-landscape is a far-sight in the fake-arms-door. The printed name is "Hadean land".
Understand "hadean", "land", "landscape", "world", "drifted", "black", "dusty", "dust", "sea", "sea of" as the arms-lab-landscape.
The reach-reason is "The fracture blocks the landscape from you."
The description is "The landscape beyond the Venture door is a sea of drifted black dust beneath a sky of Hadean clarity. The sun is a blue-white pinpoint on the horizon."
Check inspecting the arms-lab-landscape with the planetary-lens:
instead say "The lens displays the landscape's Hadean nature."
The arms-lab-sky is a far-sight in the fake-arms-door. The printed name is "starry sky".
The reach-reason is "The fracture blocks the starry sky from you."
Understand "sky", "skies", "star", "stars", "starry", "blue", "white", "blue-white", "sun", "pinpoint", "pinprick" as the arms-lab-sky.
The description is "The sun beyond the door is no larger than a star, but it has an eye-stabbing blue-white brightness."
The arms-fracture is a fracture in the fake-arms-door.
The description is "It's another crack in the air, just beyond the Venture door. On the other side is a dusty world."
The initial appearance of the kelp-impet is "You notice another aromatic impet nearby. It's labelled 'kelp'.[first time][para][sarge]Prying into the business of your superiors, now. Maybe there's hope for you, kid.[/sarge][only]"
Section - Captain's Quarters
The Captain-Quarters is a recallable room. The printed name is "High Tower".
The zone is cap-quarters-zone.
The description is "You have found Captain Hart's private quarters. In marcher lore (though never in the Captain's presence) this hallowed spot is called the High Tower. It looks disappointingly un-medieval, though: spartan decor, a bunk of regulation width and crispness."
Understand "high", "tower", "captain", "captains", "captain's", "quarters" as the Captain-Quarters.
The can't-go is "The door is west."
Check going outside in the Captain-Quarters:
instead try going west.
The cap-bunk is a prominent-scenery bunk in the Captain-Quarters.
The description is "Rumor lied -- there's not a fluffy pillow or sheepskin in sight[one of][or]. Not that you'd ever imagine Captain Hart lolling on a sheepskin. That is -- no, you scrub that image from your mind forever[or][stopping]."
Definition: a thing is non-clay-mold if it is not a clay-mold.
Rule for writing a paragraph about the cap-bunk:
now cap-bunk is mentioned;
let N be the number of things on cap-bunk;
if N is not zero:
let M be the number of clay-molds on cap-bunk;
if M is zero:
say "You see [a list of things *in cap-bunk roomily] on the bunk.";
else:
if M is 1:
let T be a random clay-mold on cap-bunk;
say "A clay disk -- a reverse mold for the [file of T] file badge -- is sitting on the bunk.";
now T is mentioned;
else:
say "[if M is 2]A couple of[else]Some[end if] small clay disks are strewn on the bunk. They have designs imprinted on them -- are these reverse molds for the [Retort's] file badges? The ";
begin cheap list for M;
repeat with T running through clay-molds on cap-bunk:
say cheap list T with "[file of substitution-variable]";
now T is mentioned;
now T is ever-seen;
end cheap list;
say " molds are visible.";
let diff be N - M;
if diff is not zero:
say "[line break][A list of non-clay-mold things *in cap-bunk roomily] [if diff is 1]is[else]are[end if] also lying on the bunk."
The capq-door is a scenery door. The printed name is "Aithery door".
The opening-goal is g-capq-door.
The pull-side is Deck-Suite.
The refer-name is "Deck Suite Aithery door".
The description is "[if the location is Deck-Suite]This must be Captain Hart's quarters; the Captain is formally the head of Aithery file. [end if]The Aithery door is [open-closed capq-door]."
Understand "aithery", "door" as the capq-door.
Understand "captain", "captains", "captain's", "quarters" as the capq-door when the location is the Deck-Suite.
Captain-Quarters is east of the capq-door. The capq-door is east of the Deck-Suite.
The capq-cabinet is a lockable prominent-scenery standard-cabinet in the Captain-Quarters.
The opening-goal is g-capq-cabinet.
Understand "cover", "plate", "rutilum", "fancy" as the capq-cabinet.
Understand "alchemical", "symbol", "inscription", "inscribed", "sign", "attraction" as the capq-cabinet when the capq-cabinet is locked.
The lens-view is "Callisto".
Rule for writing a paragraph about the capq-cabinet:
if the capq-cabinet is closed:
if the capq-cabinet is locked:
say "Another cabinet hangs on the wall. This one has no seal or keyhole, but an alchemical symbol shines on the cover";
else:
say "A cabinet on the wall is closed, though not locked";
else:
say "A cabinet on the wall is open";
if the capq-cabinet is empty:
say ", but empty";
else:
say "; inside [is-are a list of things *in the capq-cabinet roomily]";
instead say "."
Check examining the capq-cabinet:
say "The cabinet is a squarish compartment made of plate rutilum";
if the capq-cabinet is closed:
if the capq-cabinet is locked:
say ". (Fancy. Or perhaps practical; rutilum is supposed to have spiritual qualities.)[para]The cabinet is closed. The alchemical symbol for attraction shines on its surface";
else:
say ". (Fancy.) It is closed, but the attraction symbol is gone";
else:
say ". (Fancy.) It is wide open";
if the capq-cabinet is empty:
say ", but empty";
else:
say ".[para]Inside you see [a list of things *in the capq-cabinet roomily]";
instead say "."
Check touching the locked capq-cabinet:
instead say "You touch the attraction symbol, but nothing happens. The inscription is clearly meant to affect only rutilum."
Check opening the locked capq-cabinet:
if g-capq-cabinet is ever-done:
goal-perform g-capq-cabinet;
if the capq-cabinet is open:
say "You disperse the symbol and open the cabinet";
if the capq-cabinet is empty:
say ", which is empty";
else:
say ", revealing [a list of things *in the capq-cabinet]";
say ".";
stop the action;
instead say "You pull on the cabinet, but the cover is stuck tight. The symbol must be holding it closed."
Check putting a metal-seal on the capq-cabinet:
instead try unlocking the capq-cabinet with the noun.
Check tapping a metal-seal on the capq-cabinet:
instead try unlocking the capq-cabinet with the noun.
Check putting the dispersal-brush on the capq-cabinet:
instead try unlocking the capq-cabinet with the noun.
Check tapping the dispersal-brush on the capq-cabinet:
instead try unlocking the capq-cabinet with the noun.
Check unlocking the locked capq-cabinet with something:
if the second noun is the dispersal-brush:
now the capq-cabinet is unlocked;
mark g-capq-cabinet as done;
instead say "You brush the quill over the rutilum cabinet. The attraction symbol blurs and fades away.";
if the second noun is the rutilum-seal:
instead say "[one of]You press the rutilum seal against the symbol. Indeed, it sticks! Unfortunately this does not loosen the cabinet cover at all. You manage to pry the seal back off, but the cabinet is still locked[or]You stick the rutilum seal to the cabinet, and then pry it off again. The cabinet remains locked[stopping].";
if the second noun is a metal-seal:
instead say "This cabinet does not have a seal lock.";
instead say "The cabinet has no lock."
Check locking the unlocked capq-cabinet with something:
if the second noun is a metal-seal:
instead say "This cabinet does not have a seal lock.";
instead say "The cabinet has no lock."
Check inspecting the locked capq-cabinet with the oculus:
instead say "The oculus magnifies the [attraction-symbol] symbol, but the cabinet is otherwise unchanged."
The initial appearance of the sh-phlo-electrum is "A shiny sheet of paper has fallen near the cabinet."
Section - Rector's Quarters
The Rector-Quarters is a recallable room. The printed name is "Master Rector's Quarters".
The zone is rec-quarters-zone.
The description is "This is where the Master Rector of [TheFullRetort] sleeps, and presumably where he incinerates anybody who sniggers at his title. You can't see any scorch marks, but that just means he's tidy."
Understand "master", "rector", "rector's", "rectors", "quarters" as the Rector-Quarters.
The can't-go is "The door is north."
Check going outside in the Rector-Quarters:
instead try going north.
The rec-desk is a prominent-scenery supporter in the Rector-Quarters. The printed name is "desk".
The description is "It's just a utilitarian writing space."
Understand "writing", "desk", "compact" as the rec-desk.
Definition: a thing is non-paper-sheet if it is not a paper-sheet.
Rule for writing a paragraph about the rec-desk:
now rec-desk is mentioned;
let N be the number of things on rec-desk;
if N is not zero:
let M be the number of paper-sheets on rec-desk;
if M is zero:
say "You see [a list of things *in rec-desk roomily] on the desk.";
else:
if M is 1:
let T be a random paper-sheets on rec-desk;
say "In one corner is a compact writing desk; [a T] of paper rests on it.";
now T is mentioned;
else:
say "In one corner is a compact writing desk, with [if M is 2]a couple of[else]some[end if] sheets of paper stacked on it. You see ";
begin cheap list for M;
repeat with T running through paper-sheets on rec-desk:
say cheap list T with "[a substitution-variable]";
now T is mentioned;
end cheap list;
say ".";
let diff be N - M;
if diff is not zero:
say "[line break][A list of non-paper-sheet things *in rec-desk roomily] [if diff is 1]is[else]are[end if] also lying on the desk."
Check looking under the rec-desk:
instead say "The Master Rector apparently does not lose things under his desk."
Check pushing the rec-desk:
instead say "The desk is fastened to the wall, as if the [Retort] were an old sea-vessel."
Check pulling the rec-desk:
instead try pushing the rec-desk.
Check taking the rec-desk:
instead try pushing the rec-desk.
The rec-bunk is a scenery bunk in the Rector-Quarters.
The description is "Just another bunk."
The recq-door is a scenery door. The printed name is "Alchemy door".
The opening-goal is g-recq-door.
The pull-side is Deck-Suite.
The refer-name is "Deck Suite Alchemy door".
The description is "[if the location is Deck-Suite]This must be the Master Rector's quarters. [end if]The Alchemy door is [open-closed recq-door]."
Understand "alchemy", "door" as the recq-door.
Understand "master", "rector", "rector's", "rectors", "quarters" as the recq-door when the location is the Deck-Suite.
Rector-Quarters is south of the recq-door. The recq-door is south of the Deck-Suite.
Section - Arms Quarters
The Arms-Quarters is a recallable room. The printed name is "Master-at-Arms Quarters".
The description is "You know little about the [Retort's] Master-at-Arms, and this stateroom reveals little more. She must spend a bare minimum of off-duty hours here, in between bruising drill sessions and management of the combat alchemies."
The zone is arms-quarters-zone.
Understand "arms", "master", "master-at-arms", "quarters" as the Arms-Quarters.
For room-visiting the Arms-Quarters:
mark g-armsq-door as done.
The can't-go is "The door is south."
Check going outside in the Arms-Quarters:
instead try going south.
The arms-bunk is a scenery bunk in the Arms-Quarters.
The description is "Just another bunk."
The real-arms-door is a syn-bridge-door in the Deck-Suite. The printed name is "Venture door".
The pull-side is Deck-Suite.
The refer-name is "Deck Suite Venture door".
The description is "This should be the quarters of the Master-at-Arms. [The real-arms-door] is open."
Understand "door", "venture" as the real-arms-door.
Understand "master", "master's", "masters", "arms", "master-at-arms", "quarters" as the real-arms-door when the location is the Deck-Suite.
The real-arms-door is north of the Deck-Suite. The real-arms-door is south of the Arms-Quarters.
The initial appearance of the baros-key is "Lying by the bunk is a key. It appears to be made of delicately-chipped flint. Thus it must be the key to the Barosy gate -- but what the Master-at-Arms was doing with the Barosy key, you have no idea."
Section - Scrubs Country
Under-Hall is a room. The printed name is "Scrubs Country".
The zone is core-hall-zone.
The description is "This familiar, faintly grubby hallway runs west towards the quarters and mess of the midshipmen and ensigns. To the north is a study room for you apprentices; to the south is your wardroom.[para]Unfortunately, another crack prevents you from proceeding any farther down the hall."
Under-Hall is west of Quarters-Hall.
The Under-Hall is wallpaper-enabled.
The can't-go is "The hall west is blocked, so you can only go north, south, or back east."
Check going west in the Under-Hall:
instead try entering the scrubs-fracture.
The scrubs-fracture is a fracture in the Under-Hall.
The description is "A fracture lies to the west, blocking the rest of the hallway."
Check entering the scrubs-fracture:
instead say "This fracture is as impermeable as all the others. The comforts of your sleeping quarters appear to be out of reach."
Section - Study Room
The Study-Room is a recallable room. The printed name is "Study Room".
The zone is core-hall-zone.
The description is "This small library is used by the apprentices and trainees to swot up on lecture notes. Introductory textbooks and battered lexicons are heaped up untidily in the corners. The exit is south."
The Study-Room is north of Under-Hall.
Understand "study" as the Study-Room.
The can't-go is "The only exit is south."
The aroma-description is "You smell books. Old, ratty, food-stained books".
Check going outside in the Study-Room:
instead try going south.
The study-books are plural-named readable scenery in the Study-Room. The printed name is "books".
The study-books has a number called the current-count.
Understand "book", "books", "tome", "tomes", "heap", "heaps", "stack", "stacks", "textbook", "textbooks", "lexicon", "lexicons", "battered", "ratty", "notes" as the study-books.
Check examining the study-books:
increment the current-count of study-books;
if the current-count of study-books is:
-- 1: instead say "You open one of the books. That's strange. It's not printed in English.";
-- 2: instead say "You look through another book. Why would any of the apprentices have foreign texts here? You don't even recognize the language.";
-- 3: instead say "You flip through another book. This one, too, is completely unfamiliar.";
-- 4: instead say "You choose a book at random. Some of the diagrams seem familiar, but the text is completely unrecognizable.";
-- 5: instead say "You discover another unreadable book.";
-- 6:
now the current-count of study-books is 2;
instead say "This isn't working.";
-- otherwise: instead say "You are unable to make sense of the book."
Check searching the study-books:
instead say "These are the familiar stacks of books you've studied in your rare leisure hours."
Check taking the study-books:
instead try examining the study-books.
Check opening the study-books:
instead try examining the study-books.
Check entering the study-books:
instead say "Getting lost in a book is an idiom."
Check smelling the study-books:
instead try smelling the location.
Check inspecting the study-books with the oculus:
instead say "Through the oculus, the books are a great mass of information. Not a collection of works, oddly, but a single indistinct mass."
The initial appearance of the tao-amulet is "A ricepaper ribbon is poking out from under a stack of books."
Definition: a paper-sheet is study-sheet-pair if it is sh-study-room-2 or it is sh-study-room-3.
Rule for writing a paragraph about a study-sheet-pair paper-sheet:
if sh-study-room-2 is in the location and sh-study-room-3 is in the location:
say "Two papers, [a sh-study-room-2] and [a sh-study-room-3], are lying here.";
else if sh-study-room-2 is in the location:
say "[A sh-study-room-2] of paper is lying here.";
else if sh-study-room-3 is in the location:
say "[A sh-study-room-3] of paper is lying here."
Section - Under Ward
The Under-Ward is a recallable room. The printed name is "Under Ward".
The zone is core-hall-zone.
The description is "This closet-sized room is reserved for the rest and relaxation of the ensigns. Normally a few of you are about, studying or eating or (commonly) both; but these are not normal times and the room is abandoned."
The Under-Ward is south of Under-Hall.
Understand "under", "ward" as the Under-Ward.
The can't-go is "The only exit is north."
The aroma-description is "As always, the room smells faintly of stale beans".
Check going outside in the Under-Ward:
instead try going north.
The initial appearance of the sh-anaphylaxis is "Someone has left a tiny recipe sheet on the floor."
The initial appearance of the torch-lighter is "You notice somebody's torch-lighter here. Not that any ensign would ever sneak an illicit roll-up."
Chapter - Scaphe Wing
Section - Scaphe View South
The Scaphe-View is a recallable room. The printed name is "Scaphe Arcade".
The zone is core-hall-zone.
The description is "You are in a pleasant red-brick gallery edged by a row of wooden columns. A heavy steel portal in the west wall is the access to the marcher's exoscaphe. It's [if scaphe-port is closed]currently closed[else]standing open[end if]. A valve wheel is mounted next to the portal.[para]The arcade runs north towards an overlook window. There is a corridor to the east. You also see a crawlway hatch in the floor; it's open, but it seems to be flooded."
Understand "exoscaphe", "scaphe", "'scaphe", "arcade" as Scaphe-View.
The Scaphe-View is west of West-Side-Hall.
The can't-go is "Exits are east, west, and down; the arcade runs north from here."
Check going inside in the Scaphe-View:
instead try going west.
The sv-valve is scenery in Scaphe-View. The printed name is "valve wheel".
The sv-valve can be open or closed.
Understand "valve", "wheel", "emergency" as the sv-valve.
The description is "The valve wheel is marked 'Emergency Bay Pressurization,' and is also marked with the shorthand symbol of Pneuma."
The lens-view is "Pneuma[if Pneuma is not fixed], though it is weak[end if]".
Check opening the sv-valve when the sv-valve is open:
instead say "The valve is already fully open."
Check closing the sv-valve when the sv-valve is closed:
instead say "The valve is already closed."
Check opening the sv-valve:
if Pneuma is not fixed:
instead say "The valve seems to be locked in place. You're not sure what's wrong with it.";
now the sv-valve is open;
if the atmosphere of Scaphe-Bay is vacuum-atm:
now the atmosphere of Scaphe-Bay is normal-atm;
now the atmosphere of Scaphe-Dome is normal-atm;
instead say "The valve turns stiffly. You hear air whistling through the pipes -- faintly, and then louder, as the pressure in the bay increases. After a time, the whistle drops to a hiss, and then stops.";
else:
instead say "The valve turns easily. The [']scaphe bay is already at full air pressure, so you hear no further equalization."
Check closing the sv-valve:
if Pneuma is not fixed:
instead say "The valve seems to be locked in place. You're not sure what's wrong with it.";
now the sv-valve is closed;
instead say "You spin the valve closed again."
Check turning the sv-valve:
if the sv-valve is open:
instead try closing the sv-valve;
else:
instead try opening the sv-valve.
Check pushing the sv-valve:
instead try turning the sv-valve.
Check pulling the sv-valve:
instead try turning the sv-valve.
Check switching on the sv-valve:
instead try opening the sv-valve.
Check switching off the sv-valve:
instead try closing the sv-valve.
Check freeing the sv-valve:
instead try opening the sv-valve.
Report topically-applying the clock-tincture to the sv-valve:
say "You carefully pour the tincture over the valve. It soaks in, but you see no other effect";
if Pneuma is not fixed:
say ". The fault must not lie in the mechanism";
instead say "."
The scaphe-view-pool is mass-named scenery in Scaphe-View. The printed name is "water".
Understand "water", "pool", "flood", "flooded", "hatch", "hatchway", "crawl", "crawlway", "crawlspace" as the scaphe-view-pool.
The description of the scaphe-view-pool is "The crawlway hatch is uncovered, but water ripples in the opening. The entire crawlspace below must be flooded."
Check searching the scaphe-view-pool:
instead say "You can't make out much in the flooded crawlspace -- not from up here[if the B-chime is in Scaphe-Crawl]. But you catch a metallic gleam from the depths[end if]."
The drop-stuff-in-scaphe-view-pool rule is listed after the better can't insert what's not held rule in the check inserting it into rulebook.
Check inserting a takeable thing into the scaphe-view-pool (this is the drop-stuff-in-scaphe-view-pool rule):
perform throw moisturization with the noun in Scaphe-Crawl;
stop the action.
Check eating the scaphe-view-pool:
instead say "You think about how clean the marcher's crawlways haven't been, and what filth a subterranean flood is likely to have washed up. You decide not to ingest any."
Check tasting the scaphe-view-pool:
instead try eating the noun.
Check touching the scaphe-view-pool:
instead say "It's cold and slightly oily."
Check entering the scaphe-view-pool:
instead try going down.
Check opening the scaphe-view-pool:
instead say "The hatchway has no cover."
Check closing the scaphe-view-pool:
instead say "The hatchway has no cover."
The initial appearance of the measuring-block is "You notice a small brass cube lying by a column."
The sv-far-window is a far-sight in the Scaphe-View. The printed name is "window".
The description is "The overlook window is at the north end of the gallery."
The reach-reason is "The overlook window is at the north end of the gallery."
Understand "glass", "window", "overlook" as the sv-far-window.
An arcade-column is a kind of thing.
An arcade-column is usually plural-named scenery.
The printed name of an arcade-column is usually "columns".
The description of an arcade-column is usually "The columns are white-painted wood with Romance egg-and-dart capitals. They form the edge of the covered walkway, which runs [if the location is Scaphe-View]north[else]south[end if] from here. Of course the whole arcade is indoors, but it's a nice architectural touch."
Understand "column", "columns", "colonnade", "pillar", "pillars", "white", "paint", "painted", "wood", "wooden", "row", "row of" as an arcade-column.
Check climbing an arcade-column:
instead say "The columns are too smooth to climb. Anyhow, there's nothing above you but the ceiling."
The arcade-columns-s is an arcade-column in the Scaphe-View.
Section - Scaphe View North
The Scaphe-View-North is a room. The printed name is "North Arcade".
The zone is core-hall-zone.
The description is "This is the north end of the gallery. A long window in the west wall overlooks the exoscaphe bay. You can see the [']scaphe itself on the other side, hooked up to the portal you saw back south.[para]To the north is a massive door of pale marble, outrageously carved[if marble-door is locked]. The door is closed[else if the marble-door is closed]. The area around the lock is disfigured[else]. The area around the lock is disfigured, and the door is standing open[end if]."
The Scaphe-View-North is north of Scaphe-View.
The can't-go is "The door is north, and the arcade runs south[if g-scaphe-view-window is ever-done]; the window is west[end if]."
Check look-outward-ing in the Scaphe-View-North:
instead try searching the sv-window.
The marble-door is a mineralish lockable scenery door. The printed name is "marble door".
The opening-goal is g-marble-door.
The pull-side is Scaphe-View-North.
The refer-name is "North Arcade marble door".
The lens-view is "the Earth".
Understand "marble", "pale", "door", "slab", "imposing", "carved", "cherub", "cherubs", "grapevine", "lock", "handle" as the marble-door.
The marble-door is north of Scaphe-View-North. The marble-door is south of the Dressing-Room.
Check examining the marble-door:
say "The door to the [if location is Scaphe-View-North]north[else]south[end if] is an imposing marble slab, carved with cherubs and incongruously cheery grapevines";
if the marble-door is locked:
instead say ". You've always wondered if this part of the marcher was taken from a decadent bathhouse somewhere[one of]. Not that decadent bathhouses are part of your life experience[or]. Not that decadent bathhouses are part of your life experience... while you're awake[or][stopping]. Be that as it may, the door is firmly shut.";
say ". The carvings are now scarred by solvent";
if the marble-door is open:
say ", and the door is wide open";
else:
say ", however";
instead say "."
Check opening the locked marble-door:
if g-marble-door is ever-done:
goal-perform g-marble-door;
if the marble-door is open:
say "You open the door.";
stop the action;
instead say "You tug on the marble handle, but the door is locked."
Check touching the marble-door:
instead say "You tap on the door. The marble feels dense and cool."
Check unlocking the marble-door with the marble-solvent:
instead try putting the marble-solvent on the marble-door.
Report topically-applying the marble-solvent to the marble-door:
if the marble-door is unlocked:
instead say "You pour marble solvent onto the door, scarring it further.";
now the marble-door is unlocked;
instead say "You pour a drop of marble solvent onto the door. The dark liquid soaks instantly into the pale stone, leaving a rough scar. Perfect! You concentrate on the area around the handle, corroding deep grooves into the door's substance. After some careful work, the entire locking mechanism falls away, leaving the door swinging loosely."
Check putting the bamuriatic on the marble-door:
[Bamuriatic is not topical, so we have to trigger topically-applying manually.]
retire the noun by applying to the second noun;
instead try topically-applying the noun to the second noun.
Check tapping the bamuriatic on the marble-door:
retire the noun by applying to the second noun;
instead try topically-applying the noun to the second noun.
Report topically-applying the bamuriatic to the marble-door:
instead say "You dribble the powerful acid over the door. It etches frosty tracks into the marble surface, but does not penetrate."
Check tapping the F-sharp-chime on the marble-door when the symbol-type of the F-sharp-chime is permeability-symbol:
say "You carefully lay the [symbol-type of the noun] symbol against [the second noun]";
instead say ". The symbol does not discharge; it seems that marble is not enough like glass."
Check inspecting the marble-door with the oculus:
instead say "The marble door has a bit of a Bacchanalian tint when viewed through the oculus. Nothing explicit, mind you."
The sv-window is a glass-window.
[Glass-passable door "window"; really always open]
[See also the p-window]
The sv-window can be ever-tried. [resettable]
The sv-window can be breath-vacuum-glossed.
The sv-window is east of the Scaphe-Bay and west of the Scaphe-View-North.
Understand "heavy", "long", "glass", "window", "overlook" as the sv-window.
Check examining the sv-window:
if the location is the Scaphe-View-North:
say "The thick glass is a bit wavy, but you can see the exoscaphe bay on the other side. It's a high brick hall, the mirror of this one, but with vast steel doors on the far side.[para]Most of the bay is taken up by the exoscaphe itself, a lumpy metal tortoise on track-tread wheels. The [']scaphe is backed up to its entry portal, which connects to this hall, southward.[para]The bay roof appears to have been damaged[if Pneuma is fixed] and then crudely repaired[end if]";
if the sh-tortoise is in the Scaphe-Bay:
say ".[para]There seems to be a bit of paper lying at the far end of the bay";
else:
say "The thick glass is a bit wavy, but you can see the arcade on the other side";
if the F-sharp-chime is part of the sv-window:
say ".[para][The F-sharp-chime] is stuck in the glass, vibrating steadily";
instead say "."
Check searching the sv-window:
instead try examining the sv-window.
Check touching the sv-window:
if the F-sharp-chime is part of the sv-window:
instead say "You feel a steady vibration... and a yielding, as the glass slides through your flesh. It's rather unnerving.";
instead say "It feels like solid glass."
Check opening the sv-window:
instead say "The window can't be opened[if the atmosphere of Scaphe-Bay is vacuum-atm]. (There's vacuum on the other side, anyhow.)[else].[end if]"
Check closing the sv-window:
instead say "The window is fixed closed."
Check listening to the sv-window when the F-sharp-chime is part of the sv-window:
instead try listening to the F-sharp-chime.
Check attacking the sv-window:
instead try smashing the sv-window.
Check smashing the sv-window:
if the F-sharp-chime is part of the sv-window:
instead say "You probably couldn't break it in this state.";
instead say "The glass won't break; nor would you want it to."
Check going when the door gone through is the sv-window:
if the F-sharp-chime is part of the sv-window:
if the location is Scaphe-View-North and the atmosphere of the Scaphe-Bay is vacuum-atm and vacuum-potion-remaining is zero:
[Handle auto-solutions... for this sub-case]
if g-scaphe-view-window is ever-done:
instead goal-travel to Scaphe-Bay;
say "You press your fingers against the glass. You feel a steady vibration... and a yielding, as the glass slides through your flesh. It's rather unnerving.[para]More unnerving, however, is the suction you feel on the other side. The bay must be in hard vacuum -- depressurized through its damaged roof. Walking through in this state would be deadly";
say breath-vacuum-potion-gloss sv-window;
stop the action;
mark the g-scaphe-view-window as done;
if the atmosphere of the Scaphe-Bay is normal-atm:
now g-scaphe-view-window is bypassed;
if the sv-window is not ever-tried:
now the sv-window is ever-tried;
say "You press your fingers against the glass. You feel a steady vibration... and a yielding, as the glass slides through your flesh. It's rather unnerving, and you push the rest of your body through as quickly as possible.";
else:
say "You slide back through the vibrating glass.";
if the location is Scaphe-View-North and the atmosphere of the Scaphe-Bay is vacuum-atm:
say "[line break][vacuum-entry-reaction].";
perform inventory vacuumization in the Scaphe-Bay;
continue the action;
[Handle auto-solutions...]
if g-scaphe-view-window is ever-done:
if the location is Scaphe-View-North:
instead goal-travel to Scaphe-Bay;
else:
instead goal-travel to Scaphe-View-North;
instead say "The window is solid glass."
Check putting the F-sharp-chime on the sv-window when the ring-time of the F-sharp-chime is not zero:
instead try tapping the F-sharp-chime on the sv-window.
Check inserting the F-sharp-chime into the sv-window when the ring-time of the F-sharp-chime is not zero:
instead try tapping the F-sharp-chime on the sv-window.
Check tapping the F-sharp-chime on the sv-window when the ring-time of the F-sharp-chime is not zero:
if the symbol-type of the F-sharp-chime is decoherence-symbol:
invoke reset, involuntarily;
instead say "You press the chime against the window. The glass vibrates, and the bronze sinks slowly into it. The frequency of the vibration rises as you push. The glass seem to ripple -- and then explodes into splinters, all at once.[para]Unfortunately the glass explodes in all directions, much of it through you[if the atmosphere of the Scaphe-Bay is vacuum-atm]. Somewhere there is a rising howl of air escaping into the [']scaphe bay, but you are already slipping into[else]. You quickly slip into[end if] unconsciousness.";
if the symbol-type of the F-sharp-chime is permeability-symbol:
if the F-sharp-chime is part of the sv-window:
instead say "It's already stuck in the window.";
now the ring-time of the F-sharp-chime is three;
now the F-sharp-chime is part of the sv-window;
instead say "You press the chime against the window. The glass vibrates, and the bronze sinks slowly into it -- not like metal into tar, but like a knife sliding between infinitesimal layers of glass.[para]When you draw your hand away, the chime remains suspended in the glass. Its vibration continues at a steady pitch.";
instead say "(BUG) F-sharp-chime on sv-window: [symbol-type of the F-sharp-chime]."
Check inserting something into the sv-window when the F-sharp-chime is part of the sv-window:
instead say "You're not sure about the mechanics of pushing things through permeable glass. Easier to walk through yourself."
Check inserting something into the sv-window:
instead say "You can't push things through solid glass."
The sv-view is a far-sight in the Scaphe-View-North. The printed name is "exoscaphe bay".
Understand "scaphe", "'scaphe", "exoscaphe", "bay", "roof", "damage", "damaged", "crack" as the sv-view.
The description is "Through the window, you see[if Pneuma is not fixed] that the bay roof is badly damaged. Chunks of brick vaulting have fallen away, leaving a wide crack, through which shine the brilliant forbidding stars of a Hadean land[else] that the bay roof has been damaged and hastily repaired. Chunks of brick are clumped hither-thither at the top of the vault, as if an invisible hand were holding them in place[end if].[para]Pieces of roof have fallen on the exoscaphe itself. It's hard to tell, but it looks like the [']scaphe's upper dome is also cracked, and the rest of the hull is battered and dented."
The reach-reason is "The bay and exoscaphe are on the other side of the window."
Check entering the sv-view:
instead try going west.
Check inspecting the sv-view with the sv-window:
instead try examining the sv-view.
Check inspecting something with the sv-window:
instead say "The window only overlooks the exoscaphe and the [']scaphe bay."
The sv-portal-view is a far-sight in the Scaphe-View-North. The printed name is "portal".
The description is "The exoscaphe portal connects to the gallery south of here."
The reach-reason is "The portal is to the south."
Understand "entry", "entrance", "portal" as the sv-portal-view.
The arcade-columns-n is an arcade-column in the Scaphe-View-North.
The initial appearance of the marble-pebble is "Perhaps the door has suffered some damage. A chip of white marble is lying loose on the floor nearby."
Section - Dressing Room
The Dressing-Room is a recallable room. The printed name is "Dressing Room".
The zone is dressing-room-zone.
The description is "The side chamber is reserved for marchmen to change into protective suits, before boarding the [']scaphe. It is rather less sumptuous than the carved door led you to guess. The only exit is south through the marble door, which is [open-closed marble-door].[para]A row of persy suits are lined up along the wall. You don't see any helmets, though."
Understand "dressing" as Dressing-Room.
The can't-go is "The exit is south."
The aroma-description is "There's a faint smell of sweaty socks".
Check going outside in the Dressing-Room:
instead try going south.
The persy-suits are plural-named scenery in the Dressing-Room. The printed name is "persy suits".
The description is "These suits let a man walk out into a Hadean land and return alive. They look fearsomely complicated, and the helmets are all missing -- an odd omission."
Understand "persy", "percy", "persephone", "protective", "suit", "suits", "row", "row of" as the persy-suits.
Check searching the persy-suits:
instead say "You peer into one of the suits. There's a lot of padding and a lot of alchemical inscriptions for strength, flexibility, and breathing. Nothing you can pry out and use, though."
Check entering the persy-suits:
instead say "The suits are reserved for Venture file; you've never been trained to wear one. Anyway, you're pretty sure they're useless without the helmets."
Check taking the persy-suits:
instead say "The suits are too bulky to drag around. They're meant to be worn, and you don't know how to wear one."
Check pushing the persy-suits:
instead try taking the persy-suits.
Check pulling the persy-suits:
instead try taking the persy-suits.
Check inserting something into the persy-suits:
instead say "There's no reason to hide things in the suits."
Check inspecting the persy-suits with the planetary-lens:
instead say "The suits show confused traces of every foreign land they've ever set foot on."
Check inspecting the persy-suits with the oculus:
instead say "Through the oculus, the suits shine with markings of mobility and healthful environment. They're incomplete, though, without their helmets."
The initial appearance of the sh-brun-oil is "Someone has left a greasy sheet of paper here."
Section - Scaphe Crawl
The Scaphe-Crawl is a low-ceilinged room. The printed name is "Arcade Crawlspace, Flooded". The refer-name is "the Flooded Arcade Crawlspace".
The near-zone-room is Scaphe-View.
The description is "This crawlway runs north and south -- or it did, before it collapsed and flooded. Now you are floating in not-very-clean water, weakly illuminated by a few remaining sophic lamps.[para]To the south, the crawlway runs into murky darkness, out of sight. The way north is blocked by fallen beams. The hatch -- and air -- is a rippling patch of light overhead."
The Scaphe-Crawl is below the Scaphe-View.
The atmosphere of the Scaphe-Crawl is water-atm.
The can't-go is "The crawlway north has collapsed, so you can only swim south or up."
Check going down from the Scaphe-View:
begin underwater activity;
perform inventory moisturization in Scaphe-Crawl.
Check going up from the Scaphe-Crawl:
cease underwater activity.
Check going outside in the Scaphe-Crawl:
instead try going up.
Check going north in the Scaphe-Crawl:
instead try entering the scaphe-crawl-beams.
Check going south from the Scaphe-Crawl:
if breath-potion-remaining is zero:
exert yourself underwater;
instead say "You kick downwards and begin pulling yourself along the crawlway. But even a few feet of the dark, cramped passage makes your lungs heave in your chest. You push backwards, back to where air is within reach.";
say "You kick downwards and pull yourself along the crawlway. The passage is cramped and claustrophobic, and even with the potion, your chest feels tight. But you soon see light ahead, and an open hatch becomes visible above you."
The scaphe-crawl-hatch is scenery in the Scaphe-Crawl. The printed name is "hatch".
The description is "The opening above leads back to the scaphe gallery."
Understand "hatch", "hatchway", "opening", "patch", "air", "rippling", "light" as the scaphe-crawl-hatch.
Check entering the scaphe-crawl-hatch:
instead try going up.
Check getting off the scaphe-crawl-hatch:
instead try going up.
The scaphe-crawl-water is a mass-named room-proxy in the Scaphe-Crawl. The printed name is "water".
Understand "water" as the scaphe-crawl-water.
The description of the scaphe-crawl-water is "Chilly water fills the crawlway, top to bottom."
To say drink-crawl-water:
say "[if breath-potion-remaining is zero]Drinking the water you're swimming in is a little too close to drowning. Besides, it's[else]No, it's[end if] probably full of floating crawlspace crud".
Check eating the scaphe-crawl-water:
instead say "[drink-crawl-water]."
Check tasting the scaphe-crawl-water:
instead try eating the noun.
Check touching the scaphe-crawl-water:
instead say "It's cold and slightly oily."
Check entering the scaphe-crawl-water:
instead say "You are already submerged."
The scaphe-crawl-beams are plural-named scenery in the Scaphe-Crawl. The printed name is "fallen beams".
The description is "To the north, the roof has fallen in. No doubt the same catastrophe flooded the place. In any case, the crawlway is blocked in that direction."
Understand "fallen", "beam", "beams", "roof", "ceiling" as the scaphe-crawl-beams.
Check entering the scaphe-crawl-beams:
instead say "The crawlway to the north is blocked by fallen beams."
Check pushing the scaphe-crawl-beams:
instead say "Even underwater, the beams are too heavy to move."
Check pulling the scaphe-crawl-beams:
instead try pushing the scaphe-crawl-beams.
Check taking the scaphe-crawl-beams:
instead try pushing the scaphe-crawl-beams.
Check repairing the scaphe-crawl-beams:
instead say "The roof is far beyond your capacity to repair."
The initial appearance of the B-chime is "A glint of bronze is visible in the debris. It looks like another chime -- B natural, if you're not mistaken."
Section - Scaphe Bay Outside
The Scaphe-Bay is a recallable room. The printed name is "Exoscaphe Bay".
The zone is scaphe-bay-zone.
The atmosphere is vacuum-atm.
The description is "You are in a wide brick hall, or perhaps an indoor courtyard. It is unfurnished and undecorated -- not meant for human occupation. It was built to house the steel bulk of the exoscaphe, which vehicle occupies most of its floor space.[para]The west wall is dominated by enormous steel doors, wide enough for the [']scaphe to trundle out on its missions. The doors are currently closed. A much smaller (and darker) doorway is visible to the north. A long window on the east wall provides a view of the arcade."
Understand "bay", "exoscaphe", "scaphe", "'scaphe" as the Scaphe-Bay.
The can't-go is "The bay doors are west, the dark doorway is north, and the window is east."
Check going outside in the Scaphe-Bay:
instead try entering the bay-doors.
Check going west in the Scaphe-Bay:
instead try entering the bay-doors.
Check going inside in the Scaphe-Bay:
instead try going east.
The bay-doors are metallic plural-named scenery in the Scaphe-Bay. The printed name is "bay doors".
The description is "The doors to the west are tall sheets of steel. They are closed."
Understand "door", "doors", "bay", "sheets", "steel", "enormous", "vast", "tall" as the bay-doors.
Check entering the bay-doors:
instead say "The bay doors are closed, and you can't open them by hand."
Check opening the bay-doors:
instead say "The doors are far too large to be opened by hand. Some machinery operates them, but you're not sure from where it's controlled."
Check closing the bay-doors:
instead say "The bay doors are already closed."
Check pushing the bay-doors:
instead try opening the bay-doors.
Check pulling the bay-doors:
instead try opening the bay-doors.
The bay-rubble is prominent-scenery in the Scaphe-Bay. The printed name is "rubble".
The description is "Chunks of mortared brick have fallen across the [']scaphe and the rest of the bay."
Understand "rubble", "debris", "chunk", "chunks", "brick", "bricks", "vaulting", "fallen" as the bay-rubble.
The initial appearance of the bay-rubble is "[bay-rubble-appearance]."
To say bay-rubble-appearance:
if Pneuma is not fixed:
say "Fallen bits of brick vaulting lie everywhere. Stars shine in through a jagged gap in the roof";
if the atmosphere of Scaphe-Bay is vacuum-atm:
say ", and the dead silence of airlessness fills the hall";
else:
say ", and (BUG) there is air";
else:
say "The crack in the roof has been crudely patched, but quite a bit of rubble is still strewn around the bay";
if the atmosphere of Scaphe-Bay is vacuum-atm:
say ". Airless silence attests that the atmospere has not been restored";
else:
say ". The air is back, at least";
Check searching the bay-rubble:
instead say "You dig through the rubble for a few moments, but find nothing worth mentioning."
Check taking the bay-rubble:
instead say "Some of the brick debris is too large to carry, and the rest is too small to bother with."
Check pushing the bay-rubble:
instead say "You kick some bricks around."
Check pulling the bay-rubble:
instead try pushing the bay-rubble.
Check repairing the bay-rubble:
instead say "It would take a team of masons a week to start."
The bay-roof is a far-sight in the Scaphe-Bay. The printed name is "cracked roof".
The description is "[if Pneuma is not fixed]Some catastrophe has occurred. The roof gapes, and Hadean stars shine in[else]Chunks of brickwork seal the roof now. Pneuma must be holding them in place[end if]."
Understand "crack", "cracked", "gap", "jagged", "roof", "ceiling", "vault" as the bay-roof.
Understand "hadean", "sky", "star", "stars" as the bay-roof when Pneuma is not fixed.
Check inspecting the bay-roof with the planetary-lens when Pneuma is not fixed:
instead say "The lens displays the sky's Hadean nature."
The bay-scaphe is metallic scenery in the Scaphe-Bay. The printed name is "exoscaphe".
The description is "The exoscaphe looks like a monstrous steel tortoise on rolling treads. It's parked on the east side of the bay, aligned with its portal, but in fact its bulk fills most of the hall.[para]The [']scaphe has been seriously dented by falling brick. The glass dome on top is definitely cracked."
Understand "scaphe", "'scaphe", "exoscaphe", "steel", "bulk", "vehicle", "tank", "tortoise", "tread", "treads" as the bay-scaphe.
The lens-view is "Mars, with tinges of many foreign lands".
Check entering the bay-scaphe:
instead say "The exoscaphe has only one external portal, and that's currently mated with the [Retort]. You can reach it from the arcade."
Check climbing the bay-scaphe:
instead say "The exoscaphe has no footholds for climbing."
Check repairing the bay-scaphe:
instead say "Aside from the dome, the [']scaphe's damage looks superficial."
Check inspecting the bay-scaphe with the oculus:
instead say "The exoscaphe has a marvelous structure woven of protection, strength, and self-motility."
The bay-scaphe-dome is a far-sight in the Scaphe-Bay. The printed name is "glass dome".
The description is "A glass dome surmounts the exoscaphe. It's been damaged by falling brick, but you can't see how badly."
The reach-reason is "The dome is on top of the exoscaphe, out of reach."
Understand "glass", "dome" as the bay-scaphe-dome.
The bay-void-door is an open unopenable scenery door. The printed name is "dark doorway".
The description is "The doorway is very, very dark."
Understand "door", "doorway", "dark" as the bay-void-door.
The Scaphe-Bay is south of the bay-void-door.
The Bay-Void-Room is north of the bay-void-door.
Check searching the bay-void-door:
instead try examining the bay-void-door.
Check inspecting the bay-void-door with the oculus:
instead say "The oculus shows the dark doorway as associated with time."
The initial appearance of the sh-tortoise is "A brittle sheet of paper lies on the ground near the window."
Section - Bay Void Room
The Bay-Void-Room is a reset-room.
The near-room is the Scaphe-Bay.
The description is "You find yourself drifting through a familiar void."
Section - Scaphe Hull
The Exoscaphe is a recallable room.
The zone is scaphe-zone.
The Exoscaphe is not lamp-enabled.
The description is "[exoscaphe-hull-desc]".
Understand "hull", "scaphe", "'scaphe" as the Exoscaphe.
Rule for printing the name of the Exoscaphe while asking which do you mean: say "Exoscaphe Hull".
To say exoscaphe-hull-desc:
say "The exoscaphe is a vehicle for exploring hostile lands. From the inside, it's more like being in a spherical steel tank. A windowless tank, at that. [if the Scaphe-Dome is not visited]Presumably[else]You recall that[end if] there's a better view from the pilot's dome";
if the dome-hatch is closed:
say "; but the hatch above your head is closed";
else:
say "; you could climb up through the hatch and see";
if the atmosphere of the Exoscaphe is vacuum-atm:
say ".[para]The emergency evacuation has left the chamber in dead, airless silence";
say ".[para]A circular bench runs around the perimeter, broken only by the dark engine compartment to the west and the exit portal to the east. The portal is [open-closed scaphe-port]. You see a small emergency lever next to it";
say ".[para]A cabinet";
if the scaphe-fuse-cabinet is closed:
if the scaphe-fuse-cabinet is dirty:
say " is fastened to the wall. Its latch is tied shut with a knot of white cord";
if Junior-Quarters is visited and g-scaphe-fuse-cabinet is not ever-done:
say ", much like the one you saw on the locker";
else:
say " is fastened to the wall. It's closed";
else:
if the scaphe-fuse-cabinet is empty:
say " fastened to the wall is open, but empty";
else:
say " is fastened to the wall. Inside [is-are a list of things *in the scaphe-fuse-cabinet roomily]";
say period.
The can't-go is "The exit is east, the engine compartment is west, and the dome hatch is up."
Check going outside in the Exoscaphe:
instead try going east.
Check going inside in the Exoscaphe:
instead try going up.
The scaphe-void-door is an open unopenable scenery door. The printed name is "dark doorway".
The description is "The engine compartment is very, very dark."
Understand "door", "doorway", "dark", "engine", "compartment" as the scaphe-void-door.
The Scaphe-Void-Room is west of the scaphe-void-door.
The Exoscaphe is east of the scaphe-void-door.
Check searching the scaphe-void-door:
instead try examining the scaphe-void-door.
Check inspecting the scaphe-void-door with the oculus:
instead say "The oculus shows the dark doorway as associated with time."
The scaphe-port is a metallic scenery door. The printed name is "heavy steel portal".
The opening-goal is g-scaphe-port.
The pull-side is Scaphe-View.
The refer-name is "Exoscaphe portal".
The scaphe-port can be shifted. [small pressure difference; resettable]
Understand "heavy", "steel", "entry", "access", "port", "portal" as the scaphe-port.
Understand "exoscaphe", "scaphe", "'scaphe" as the scaphe-port.
The scaphe-port is west of Scaphe-View and east of the Exoscaphe.
The lens-view is "Mars".
Check examining the scaphe-port:
if the location is the Exoscaphe:
say "This steel portal leads back to the arcade";
else:
say "The steel portal permits entrance to the exoscaphe, when it is in the bay";
if the scaphe-port is open:
say ". The portal is open";
else:
say ". The portal is closed and pressure-tight";
instead say "."
Carry out opening the scaphe-port:
if the scaphe-port is shifted and currently trying silently:
now the scaphe-port is not shifted;
say "There is a brief hiss as the pressure re-equalizes.";
continue the action.
Report opening the scaphe-port:
say "You unseal the portal";
if the scaphe-port is shifted:
now the scaphe-port is not shifted;
say "; there is a brief hiss as the pressure re-equalizes. You";
else:
say " and";
instead say " swing it open."
Check opening the closed scaphe-port when the atmosphere of the Exoscaphe is not normal-atm:
instead say "The steel portal cannot be opened against a pressure differential."
Check getting off the scaphe-port when in the Exoscaphe:
instead try going east.
Check tapping the steel-bolt on the scaphe-port when the symbol-type of the steel-bolt is some-saturation-symbol:
say "You carefully lay the [symbol-type of the noun] symbol against [the second noun]";
uninscribe the steel-bolt;
instead say ". The symbol discharges, but [the second noun] doesn't get any cleaner."
The scaphe-lever is scenery in the Exoscaphe. The printed name is "pressure lever".
The scaphe-lever can be breath-vacuum-glossed.
Understand "pressure", "lever", "valve", "emergency", "small" as the scaphe-lever.
The description is "This hand-length lever is marked 'Emergency Exoscaphe Pressure Equalization'."
Check pulling the scaphe-lever when the scaphe-port is open:
instead say "The lever is locked in place -- no doubt because the steel portal is open. You wouldn't want to depressurize the entire marcher."
Check pulling the scaphe-lever:
if the atmosphere of Scaphe-Bay is the atmosphere of Exoscaphe:
instead say "You pull the lever, but nothing happens. It snaps back when you release it.";
if the atmosphere of Scaphe-Bay is normal-atm:
instead say "(BUG) Should not be possible to repressurize the scaphe.";
if vacuum-potion-remaining is zero:
now the scaphe-port is shifted;
say "You give the lever a quick tug. Air shrieks through the valve, and you feel your ears pop.[para]Gah! You release the lever before the pressure in the exoscaphe can drop further. Suffocating yourself is not on the agenda";
say breath-vacuum-potion-gloss scaphe-lever;
stop the action;
now the atmosphere of Exoscaphe is vacuum-atm;
say "You pull the lever. Air shrieks through the valve... and then the whistle fades away, as the pressure in the [']scaphe drops towards zero.[para][vacuum-entry-reaction].";
perform room vacuumization in the Exoscaphe;
stop the action.
Check pushing the scaphe-lever:
instead say "The lever can only be pulled."
Check turning the scaphe-lever:
instead say "The lever can only be pulled."
Check closing the scaphe-lever:
instead say "The lever is already in the closed position."
Check opening the scaphe-lever:
instead try pulling the scaphe-lever.
Check freeing the scaphe-lever:
instead try pulling the scaphe-lever.
The scaphe-fuse-cabinet is a standard-cabinet in the Exoscaphe.
The opening-goal is g-scaphe-fuse-cabinet.
The scaphe-fuse-cabinet can be clean or dirty.
Understand "latch" as the scaphe-fuse-cabinet.
Understand "fuse", "white", "white-fuse", "white-cord", "glittering", "cord", "knot" as the scaphe-fuse-cabinet when the scaphe-fuse-cabinet is dirty.
[See also junior-fuse-cabinet.]
Check examining the scaphe-fuse-cabinet:
if the scaphe-fuse-cabinet is closed:
if the scaphe-fuse-cabinet is dirty:
say "The cabinet is closed. The latch is bound up with a tight knot of glittering white cord";
else:
say "The cabinet is unlocked, but closed";
else:
say "The cabinet is open";
if the scaphe-fuse-cabinet is empty:
say ", but empty";
else:
say ". Inside you see [a list of things *in the scaphe-fuse-cabinet roomily]";
instead say ".";
Check freeing the dirty scaphe-fuse-cabinet:
instead say "You pick at the white cord, but the knot is too tight."
Check cutting the dirty scaphe-fuse-cabinet:
if the player carries the scalpel:
instead try unlocking the scaphe-fuse-cabinet with the scalpel;
instead say "You have nothing to cut the cord with."
Check unlocking the dirty scaphe-fuse-cabinet with the scalpel:
now the scaphe-fuse-cabinet is clean;
mark g-scaphe-fuse-cabinet as done;
now the tool-used of g-scaphe-fuse-cabinet is the scalpel;
instead say "You hack at the white-fuse with the scalpel. It's a messy job, but after a few moments, the cord falls to bits.";
Check igniting the dirty scaphe-fuse-cabinet with el-fire:
now the scaphe-fuse-cabinet is clean;
mark g-scaphe-fuse-cabinet as done;
now the tool-used of g-scaphe-fuse-cabinet is the second noun;
now the fire-source-used of g-scaphe-fuse-cabinet is the second noun;
instead say "You hold [the second noun] under the white-fuse. The cord ignites with a flash and a [em]pop![/em] It burns away almost instantly, leaving only the smell of burnt metal in the air."
Check igniting the dirty scaphe-fuse-cabinet with something:
instead say "You wave [the second noun] under the white-fuse, but the cord refuses to ignite."
Check igniting the clean scaphe-fuse-cabinet with something:
instead say "You've already burned off the white-fuse."
Check opening the dirty scaphe-fuse-cabinet:
if g-scaphe-fuse-cabinet is ever-done:
goal-perform g-scaphe-fuse-cabinet;
if the scaphe-fuse-cabinet is open:
say "You open the cabinet";
if the scaphe-fuse-cabinet is empty:
say ", which is empty";
else:
say ", revealing [a list of things *in the scaphe-fuse-cabinet]";
say ".";
stop the action;
instead say "The cabinet won't open -- its latch is tied shut."
Does the player mean burning the dirty scaphe-fuse-cabinet:
it is very likely.
Does the player mean burning the dirty scaphe-fuse-cabinet with something:
it is very likely.
The scaphe-bench is a scenery supporter in the Exoscaphe. The printed name is "bench".
The description is "It's just a bare bench. Presumably marchmen sit here while the [']scaphe is trundling out across exotic foreign lands. You wouldn't know."
Understand "bench", "seat", "bare", "circular" as the scaphe-bench.
Check entering the scaphe-bench:
instead say "Now is not the time to rest."
Check looking under the scaphe-bench:
instead say "There's nothing there."
Section - Scaphe Dome
The Scaphe-Dome is a recallable room. The printed name is "Exoscaphe Dome".
The zone is scaphe-dome-zone.
The atmosphere is vacuum-atm. [matching Scaphe-Bay]
The Scaphe-Dome is not lamp-enabled.
The description is "If you were piloting the [']scaphe, you'd sit in this seat and work the controls, peering out through the glass dome around you. The vehicle looks to have fallen on rough times, however -- or vice versa. The dome is cracked[if the atmosphere of Scaphe-Dome is vacuum-atm], the air is gone,[end if] and the controls look dead.[para]The only exit is the hatch in the floor, which is [open-closed dome-hatch]."
Understand "dome", "piloting", "exoscaphe", "scaphe", "'scaphe" as the Scaphe-Dome.
The can't-go is "The only way out is down the hatch."
Check going outside in the Scaphe-Dome:
instead try going down.
Check look-outward-ing in the Scaphe-Dome:
instead try searching the dome-window.
The dome-seat is a room-proxy in the Scaphe-Dome. The printed name is "seat".
The description is "It's just a place to sit."
Understand "seat" as the dome-seat.
Check entering the dome-seat:
instead say "You're already seated. (There's no room to stand.)"
Check putting something on the dome-seat:
instead try dropping the noun.
The dome-controls are plural-named scenery in the Scaphe-Dome. The printed name is "controls".
The description is "The control console is an unwieldy mess of levers and wheels. The gauges all seem locked at zero, however."
Understand "console", "control", "controls", "lever", "levers", "wheel", "wheels", "gauge", "gauges" as the dome-controls.
Check searching the dome-controls:
instead try examining the dome-controls.
Check pushing the dome-controls:
instead say "The controls are all locked."
Check pulling the dome-controls:
instead try pushing the dome-controls.
Check turning the dome-controls:
instead try pushing the dome-controls.
Check switching on the dome-controls:
instead say "The controls are drawing no power. The [']scaphe's alchemical battery must be dead."
Check switching off the dome-controls:
instead say "The control console is already turned off."
Check repairing the dome-controls:
instead try switching on the dome-controls.
Check looking under the dome-controls:
instead say "You find nothing else."
Check inspecting the dome-controls with the oculus:
instead say "Through the oculus, the control console is a delicate array of functional assocations."
Check topically-applying the clock-tincture to the dome-controls:
instead say "You pour the tincture over the controls. It soaks in, but the controls do not move. Apparently the console is in good repair; it just doesn't have power."
The dome-window is glassy scenery in the Scaphe-Dome. The printed name is "glass dome".
The description is "The dome surrounds your upper body, allowing you to look out on the bay in every direction. However, the collapse of the bay roof has damaged the glass. The dome is still in one piece, but several cracks run across it. They look nasty enough to have let the air out[if the atmosphere of Scaphe-Dome is vacuum-atm].[else]. (And then back in when you repressurized the bay.)[end if]".
Understand "glass", "dome", "window", "nasty", "crack", "cracks", "gap", "gaps" as the dome-window.
Check searching the dome-window:
instead try examining the sdom-view.
Check getting off the dome-window:
instead try entering the dome-window.
Check entering the dome-window:
instead say "The cracks in the dome are too narrow for your fingers, even."
Check opening the dome-window:
instead say "The dome wasn't built to open. If the damage it's suffered hasn't done it, it's not going to happen."
Check smashing the dome-window:
instead say "The glass is cracked, but some alchemical virtue holds the dome together. Someone built this thing well."
Check attacking the dome-window:
instead try smashing the dome-window.
Check repairing the dome-window:
instead say "You have no way to repair the dome."
Check inserting something into the dome-window:
if the noun is the F-sharp-chime and the ring-time of the F-sharp-chime is not zero:
instead try tapping the noun on the second noun;
instead say "The cracks in the dome are too narrow to push anything through."
The dome-hatch is a metallic scenery door. The printed name is "small hatch".
The opening-goal is g-dome-hatch.
The pull-side is Scaphe-Dome.
The refer-name is "Exoscaphe hatch".
Understand "small", "hatch", "steel" as the dome-hatch.
Understand "pilot's", "piloting", "dome" as the dome-hatch when the location is the Exoscaphe.
The dome-hatch is below Scaphe-Dome and above the Exoscaphe.
The lens-view is "Mars".
Check examining the dome-hatch:
if in the Exoscaphe:
say "This hatch leads up into the piloting dome";
else:
say "This hatch leads down into the main hull of the [']scaphe";
if the dome-hatch is open:
say ". It is currently open";
else:
say ". It is currently closed";
instead say "."
Check opening the closed dome-hatch when the atmosphere of the Exoscaphe is not the atmosphere of Scaphe-Dome:
if the location is Exoscaphe and the g-dome-hatch is ever-done:
goal-perform g-dome-hatch;
if the dome-hatch is open:
say "You open the hatch.";
stop the action;
instead say "The dome hatch cannot be opened against a pressure differential."
Check opening the closed dome-hatch when the atmosphere of the Exoscaphe is normal-atm and the atmosphere of Scaphe-Dome is normal-atm:
now g-dome-hatch is bypassed.
Check tapping the steel-bolt on the dome-hatch when the symbol-type of the steel-bolt is some-saturation-symbol:
say "You carefully lay the [symbol-type of the noun] symbol against [the second noun]";
uninscribe the steel-bolt;
instead say ". The symbol discharges, but [the second noun] doesn't get any cleaner."
The sdom-view is a far-sight in the Scaphe-Dome. The printed name is "exoscaphe bay".
Understand "scaphe", "'scaphe", "exoscaphe", "steel", "hull", "bay", "roof" as the sdom-view.
The description is "Through the dome, you see[if Pneuma is not fixed] that the bay roof is badly damaged. Chunks of brick vaulting have fallen away, leaving a wide crack, through which shine the brilliant forbidding stars of a Hadean land[else] that the bay roof has been damaged and hastily repaired. Chunks of brick are clumped hither-thither at the top of the vault, as if an invisible hand were holding them in place[end if].[para]The [']scaphe itself is parked by the bay wall and docked with its portal. It lies partially under the collapse, however. The steel hull is battered and dented. Pieces of roof lie strewn across it, around the dome."
The reach-reason is "That's outside the dome."
Check entering the sdom-view:
instead try entering the dome-window.
Check inspecting the sdom-view with the dome-window:
instead try examining the sdom-view.
Check inspecting something with the dome-window:
instead say "The dome only overlooks the [']scaphe bay."
The 3rd-key is a takeable-thing [in the Scaphe-Dome]. The printed name is "spare lab key".
Understand "spare", "thin", "tertiary", "lab key", "key" as the 3rd-key.
The description of the 3rd-key is "This [if g-3rd-door is not ever-done]looks like[else]is[end if] a key to the Tertiary Alchemy Lab[if in the Scaphe-Dome]. Why someone left it in the scaphe, you have no idea[end if]."
The initial appearance of the 3rd-key is "A thin key is visible under the console."
Rule for writing a paragraph about the sh-scaphe-dome:
now the sh-scaphe-dome is mentioned;
say "A dessicated sheet of paper";
if the 3rd-key is in Scaphe-Dome and the 3rd-key is not handled:
now the 3rd-key is mentioned;
say " and a thin key are";
else:
say " is";
say " visible under the console."
Section - Scaphe Void Room
The Scaphe-Void-Room is a reset-room.
The near-room is the Exoscaphe.
The description is "You find yourself drifting through a familiar void."
Chapter - Garden
Section - Paper Garden
The Garden is a recallable room. The printed name is "Paper Garden".
The zone is garden-zone.
The description is "The garden is the marcher's refuge of meditation and calm. Paper paths wind among beds of paper flowers; the walls are hung with paper trees beneath a calm blue-painted ceiling. A tiny brick-lined pool lies at the garden's center. The place isn't large, but it doesn't feel small. You've always liked it.[para]An opening to the north leads back to the [Retort's] main corridor, and another south to the lower reaches. To the east, a paper arch gives entry to the paper hedge maze. The observatory door to the west is [open-closed obs-door]."
Understand "paper" as the Garden.
The Garden is south of West-Side-Hall.
The can't-go is "Exits are north, south, and down; the observatory door is west, and the maze is east."
The aroma-description is "Usually the garden has the scent of living plants and a distinct breeze. But now that you pay attention, the atmosphere is quite dead now".
Check going east from the Garden when Aistheta is not fixed:
now the flail-counter of the Garden-Maze-Lost is zero;
if g-maze-center is ever-done:
goal-perform g-maze-center;
[To be consistent with other movement goals, g-maze-center covers the actions needed to travel, but not the travel itself.]
if the player carries centrality-lodestone:
say "You allow the pendulum to lead you through the maze.";
now the player is in Garden-Maze-Center;
stop the action;
say "You step through the arch. Within moments, you are entirely turned around."
Check waving the centrality-lodestone in Garden:
instead say "You hold the silk cord by one end, and set the stone swinging. It pulls gently to the east, towards the archway."
Check waiting in the Garden:
instead say "Time drifts peaceably by."
The garden-pool-surface is mass-named scenery in Garden. The printed name is "water".
Understand "water", "pool", "pond", "brick", "bricks", "tiny", "brick-lined" as the garden-pool-surface.
The description of the garden-pool-surface is "The pool is only eight feet across. It's trimmed with tiny, neat bricks -- no doubt to make the pool look bigger. Its importance is mostly symbolic, after all. But somehow, you can't make out the bottom from here."
Check searching the garden-pool-surface:
instead say "The pool is very deep, somehow."
The drop-stuff-in-garden-pool rule is listed after the better can't insert what's not held rule in the check inserting it into rulebook.
Check inserting a takeable thing into the garden-pool-surface (this is the drop-stuff-in-garden-pool rule):
perform throw moisturization with the noun in Garden-Pool;
if the noun is the brass-pin and the brass-pin symbol-matches fixation-symbol:
say "[br]You notice a faint light trailing behind it as it disappears into the murk.";
stop the action.
Check eating the garden-pool-surface:
instead say "The water should be symbolically pure, but that doesn't mean it's actually clean. You decide not to ingest any."
Check tasting the garden-pool-surface:
instead try eating the noun.
Check touching the garden-pool-surface:
instead say "It's cold."
Check entering the garden-pool-surface:
instead try going down.
Check inspecting the garden-pool-surface with the oculus:
instead say "The oculus shows the pool as symbolizing a deep, clear lake."
The garden-maze-entry is paper-scenery in the Garden. The printed name is "paper arch".
The description is "A decorative paper arch stands to the east, strung up on bamboo poles. Through it you can see the mad folds of the [Retort's] hedge maze[if Garden-Maze-Lost is unvisited and Garden-Maze-Center is unvisited], where you've never dared (or been ordered) to venture[end if]."
Understand "paper", "arch", "archway", "hedge", "maze", "bamboo", "pole", "poles" as the garden-maze-entry.
Check entering the garden-maze-entry:
instead try going east.
Check searching the garden-maze-entry:
instead say "That's the trick, isn't it."
Check inspecting the garden-maze-entry with the oculus:
instead say "The oculus shows the paper maze as symbolizing the necessary mystery of the [Retort's] operation. You're not sure why it's necessary. (If you knew, it wouldn't be a mystery, you suppose.)"
The garden-trees are plural-named paper-scenery in the Garden. The printed name is "paper trees".
The description is "Paper silhouettes in the shapes of trees adorn the walls. They're hung in layers, giving an artful impression of hazy distance."
Understand "garden", "paper", "wall", "walls", "wallpaper", "tree", "trees", "cutout", "cutouts", "silhouette" as the garden-trees.
Check entering the garden-trees:
instead say "The trees are a pleasant illusion."
Check climbing the garden-trees:
instead say "You can't climb paper cutouts."
Check inspecting the garden-trees with the oculus:
instead say "The oculus shows the paper trees as symbolizing wild Nature."
The garden-flowers are plural-named paper-scenery in the Garden. The printed name is "paper flowers".
The description is "Real plants don't grow here -- that's what the herbarium is for. The paper garden is the marcher's [em]symbol[/em] of a garden. The [Retort] could not travel the Higher Spheres without this place unchangingly [em]here.[/em] 'It does not change nor fade nor wither,' although it sometimes needs to be dusted."
Understand "garden", "paper", "flower", "flowers", "bed", "beds", "grass" as the garden-flowers.
Check searching the garden-flowers:
instead say "The illusion does not survive a close inspection, so you refrain."
Check taking the garden-flowers:
instead say "The paper flowers have no alchemical virtue."
Check rubbing the garden-flowers:
instead say "The paper flowers are adequately clean at the moment."
Check inspecting the garden-flowers with the oculus:
instead say "The oculus shows the paper flowers as symbolizing tamed Nature."
The garden-paths are plural-named paper-scenery in the Garden. The printed name is "paths".
The description is "Okay, the paths aren't really paper. They're reed mats that look like paper. They wander in little arcs among the paper flowers."
Understand "garden", "paper", "reed", "path", "paths", "mat", "mats" as the garden-paths.
Check searching the garden-paths:
instead say "A pleasant pastime, but not fruitful."
Check entering the garden-paths:
instead say "You're already standing on the garden paths."
Check putting something on the garden-paths:
instead try dropping the noun.
Check inserting something into the garden-paths:
instead try dropping the noun.
The garden-ceiling is a far-sight in the Garden. The printed name is "ceiling".
The description is "The ceiling is curved and painted sky-blue, hinting at clouds. If you don't look up, it's easy to forget that it's there. Although the breeze that usually aids the illusion is stilled now."
The reach-reason is "The ceiling is out of reach."
Understand "ceiling", "roof", "sky", "blue", "sky-blue", "blue-painted", "calm", "cloud", "clouds" as the garden-ceiling.
Check inspecting the garden-ceiling with the oculus:
instead say "The oculus shows the painted sky as symbolizing, in fact, the sky."
Section - Garden Pool
The Garden-Pool is a room. The printed name is "Garden Pool".
The near-zone-room is Garden.
The description is "You are floating in a well, eight feet across and perhaps ten feet deep. The water is cold and still. The water's surface is a sheet of light above you, and the base of the well is a circle of darkness below.[para]In the center of the darkness you see a darker hole. It's an opening in the floor below you, a narrow shaft running downward out of sight."
The Garden-Pool is below the Garden.
The atmosphere of the Garden-Pool is water-atm.
The Garden-Pool is not lamp-enabled.
The can't-go is "You can only swim up or down."
Check going down from the Garden:
begin underwater activity;
perform inventory moisturization in Garden-Pool.
Check going up from the Garden-Pool:
cease underwater activity.
Check going outside in the Garden-Pool:
instead try going up.
Check going inside in the Garden-Pool:
instead try going down.
Check going down from the Garden-Pool:
if breath-potion-remaining is zero:
exert yourself underwater;
instead say "You kick downwards until your lungs heave in your chest. But the channel's end is still nowhere in sight. You flip around and stretch for the surface.";
say "You haul yourself further downwards, into the channel."
The garden-pool-water is a mass-named room-proxy in the Garden-Pool. The printed name is "water".
Understand "water" as the garden-pool-water.
The description of the garden-pool-water is "Chilly water surrounds you."
To say drink-garden-water:
say "[if breath-potion-remaining is zero]Drinking the water you're swimming in is a little too close to drowning. Besides, it's[else]No, it's[end if] probably full of fake grass trimmings".
Check eating the garden-pool-water:
instead say "[drink-garden-water]."
Check tasting the garden-pool-water:
instead try eating the noun.
Check touching the garden-pool-water:
instead say "It's cold."
Check entering the garden-pool-water:
instead say "You are already submerged."
The garden-pool-channel is scenery in the Garden-Pool. The printed name is "channel".
The description is "A narrower channel leads even farther into the depths."
Understand "channel", "hole", "opening", "narrow", "narrower", "dark", "darker", "passage", "shaft" as the garden-pool-channel.
Check entering the garden-pool-channel:
instead try going down.
The drop-stuff-in-garden-channel rule is listed after the better can't insert what's not held rule in the check inserting it into rulebook.
Check inserting a takeable thing into the garden-pool-channel (this is the drop-stuff-in-garden-channel rule):
now the noun is in Garden-Pool-Bottom;
say "[The noun] sinks out of sight";
if the noun is the brass-pin and the brass-pin symbol-matches fixation-symbol:
say ", trailing its faint glow";
instead say "."
Section - Garden Pool Bottom
The Garden-Pool-Bottom is a room. The printed name is "Bottom of Shaft".
The description is "You are at the bottom of a narrow vertical submerged shaft. Little light reaches you, and the water is icy cold.[para]At the very bottom of the shaft is [if pool-slab is dirty]a mud-covered slab. Its surface is irregular, but the mud is too thick to make out what's carved there[else]a muddy slab, carved with letters[end if]."
The Garden-Pool-Bottom is below the Garden-Pool.
The atmosphere of the Garden-Pool-Bottom is water-atm.
The Garden-Pool-Bottom is not lamp-enabled.
The can't-go is "Up is the only option."
Check going up from the Garden-Pool-Bottom:
say "You launch yourself towards the surface.[para]";
cease underwater activity;
now the player is in the Garden;
stop.
Check going outside in the Garden-Pool-Bottom:
instead try going up.
Check going down in the Garden-Pool-Bottom:
instead say "You have reached the bottom."
The garden-poolbottom-water is a mass-named room-proxy in the Garden-Pool-Bottom. The printed name is "water".
Understand "water", "shaft" as the garden-poolbottom-water.
The description of the garden-poolbottom-water is "Chilly water surrounds you."
Check eating the garden-poolbottom-water:
instead say "[drink-garden-water]."
Check tasting the garden-poolbottom-water:
instead try eating the noun.
Check touching the garden-poolbottom-water:
instead say "It's very cold."
Check entering the garden-poolbottom-water:
instead say "You are already submerged."
The pool-slab is readable scenery in the Garden-Pool-Bottom. The printed name is "muddy slab".
The pool-slab can be clean or dirty. The pool-slab is dirty. [resettable]
Understand "mud", "muddy", "slab", "carved", "carving", "irregular", "surface" as the pool-slab.
Understand "letter", "letters", "word", "words" as the pool-slab when the pool-slab is clean.
Check examining the pool-slab:
if the pool-slab is dirty:
instead say "The mud on the slab is dimpled irregularly. You cannot tell what's beneath, however.";
say "A word is carved on the slab. [if the emulgence-word is not known]You have never seen it, but you[else]You[end if] have an unspoken sense: it is";
if perfect-mud-creation is not known:
say " a word of emulgence, a word of blending. Like the blending of earth and water into mud";
else:
say " the word of emulgence, the one mentioned in the mud synthesis. A word of blending";
if the emulgence-word is not known:
mark emulgence-word as known;
say ".[para]You memorize the word of emulgence";
instead say "."
Check searching the pool-slab:
if the pool-slab is dirty:
instead try rubbing the pool-slab;
instead try examining the pool-slab.
Check rubbing the pool-slab:
if the pool-slab is clean:
instead say "The slab is clean enough to read.";
now the pool-slab is clean;
instead say "You brush at the mud, trying not to stir it up into the water around you. Letters come into view, neat enough to read even in this murky light."
Check looking under the pool-slab:
instead try rubbing the pool-slab.
Check touching the pool-slab:
if the pool-slab is dirty:
instead try rubbing the pool-slab;
instead say "You brush your fingers over the letters."
Check taking the pool-slab:
instead say "The slab is too large to carry, certainly while swimming."
Check pushing the pool-slab:
if the pool-slab is dirty:
instead try rubbing the pool-slab;
instead say "The slab is too deeply buried to move."
Check pulling the pool-slab:
instead try pushing the pool-slab.
Section - Garden Maze Lost
The Garden-Maze-Lost is a room. The printed name is "[if Aistheta is not fixed]Lost in Paper Maze[else]Paper Maze, Interior[end if]". The refer-name is "the Paper Maze".
The description is "[garden-maze-lost-desc]".
The Garden-Maze-Lost has a number called the flail-counter.
The Garden-Maze-Lost has a number called the desc-counter.
The Garden-Maze-Lost is east of the Garden.
The Garden-Maze-Lost is west of the Garden-Maze-Center.
To say garden-maze-lost-desc:
if Aistheta is not fixed:
if the desc-counter of Garden-Maze-Lost is:
-- 1: say "You are standing in a hedge-maze of paper screens which form folding and forking paths in every direction. The screens are taller than you";
-- 2: say "This is a hedge-maze, formed of paper screens taller than you. The passages fork and fold in every direction";
-- 3: say "You are standing amid tall paper screens which form a maze around you. The passages fork and fold in every direction";
-- 4: say "You are surrounded by a maze of tall paper screens, painted to resemble hedges. The passages fold and fork in every direction";
-- 5: say "This is a maze of paper screens, taller than you, which form forking and folding passages in every direction";
-- 6: say "You are surrounded by paper screens, taller than you, which form a maze of folding and forking paths";
-- otherwise: say "You are in a hedge-maze of paper screens, taller than you, which fold and fork in every direction";
if the flail-counter of Garden-Maze-Lost is:
-- 0: do nothing;
-- 1: say ".[para]The paper maze is the nest of the dragon Pneuma. Only senior officers are supposed to enter -- but you've never heard that the maze was [em]difficult[/em]";
-- 2: say ".[para]This is really much more confusing than it should be";
-- 3: say ".[para]You are lost. Perhaps the rectors have some mystical way in and out of here";
-- otherwise: say ".[para]You are lost";
say period;
else:
say "The hedge-maze is just a few symbolic forks and blind alleys. You can see the center to the east, and the exit archway to the west";
say period.
The can't-go is "[if Aistheta is not fixed]You're not sure[else]You can go east to the center, or west to the garden[end if]."
For room-visiting the Garden-Maze-Lost:
randomize the maze desc counter.
To randomize the maze desc counter:
let N be the desc-counter of Garden-Maze-Lost;
let M be zero;
if Aistheta is not fixed:
let M be a random number between 0 and 6; [inclusive]
if M is N:
increment M;
now the desc-counter of Garden-Maze-Lost is M.
Check going in Garden-Maze-Lost when Aistheta is not fixed:
if the noun is up or the noun is down:
instead say "The maze pathways are all level.";
let N be the flail-counter of Garden-Maze-Lost;
increment the flail-counter of Garden-Maze-Lost;
if a random chance of N in 5 succeeds:
say "[one of]By sheer luck[or]Happily[or]Finally[or]After some blind turns[at random], you catch a glimpse of the archway, and stumble back out into the garden.";
clean up maze discards;
now the player is in the Garden;
stop the action;
say "[one of]You turn left[or]You turn right[or]You take several random turns[or]You try going straight for a while[or]You try to double back[or]You take a sharp turn[or]You wander at random[at random]";
say "[one of], but you only find more pathways[or], but it is of no avail[or]. You only become more lost[or]. It doesn't help[or]. This intersection looks vaguely familiar[or]. You think you have found somewhere new[at random].";
clean up maze discards;
randomize the maze desc counter;
now the player is in the Garden-Maze-Lost;
stop the action.
Check going in Garden-Maze-Lost when Aistheta is fixed:
if the noun is up or the noun is down:
instead say "The maze pathways are all level.";
if the noun is outside:
instead try going west;
if the noun is inside:
instead try going east;
[no discard clean-up in this case]
if the noun is west:
say "You make your way back to the garden.";
continue the action;
if the noun is east:
mark g-maze-center as done;
now g-maze-center is bypassed;
say "You easily trace the path to the center.";
continue the action;
instead say "The other paths are obvious dead ends."
Check waving the centrality-lodestone in Garden-Maze-Lost:
if Aistheta is fixed:
instead say "You hold the silk cord by one end, and set the stone swinging. It tugs firmly to the east.";
say "You hold the silk cord by one end, and set the stone swinging.[para]The stone circles oddly for a moment, then leaps to one side. You turn down the path it indicates. Soon the pendulum tugs the other way, and you follow it further. After just a few moments, the maze opens up into a wide clearing.";
mark g-maze-center as done;
clean up maze discards;
now the player is in Garden-Maze-Center;
stop the action.
The maze-screens are plural-named paper-scenery in the Garden-Maze-Lost. The printed name is "paper screens".
The description is "The screens are painted with abstract leaf designs, representing hedgerows. They form the garden maze which surrounds the dragon's lair[if Aistheta is fixed]. You can see most of the paths from here, though[else if the flail-counter of Garden-Maze-Lost is even]. The paths all look alike[else]. The paths all look different[end if]."
Understand "garden", "paper", "screen", "screens", "hedge", "hedges", "hedge-maze", "maze", "leaf", "leaves" as the maze-screens.
Check entering the maze-screens:
instead try going inside.
Check getting off the maze-screens:
instead try going outside.
Check climbing maze-screens:
instead say "The screens are too flimsy to climb. Anyway, that would be cheating."
Check searching the maze-screens:
instead say "That's the trick, isn't it."
Check inspecting the maze-screens with the oculus:
instead say "The oculus shows the paper maze as symbolizing the necessary mystery of the [Retort's] operation. You're not sure why it's necessary. (If you knew, it wouldn't be a mystery, you suppose.)"
To clean up maze discards:
[A simple "now all ... in ..." declaration would be slower.]
repeat with T running through takeable things in Garden-Maze-Lost:
retire T by maze-discarding.
Section - Garden Maze Center
The Garden-Maze-Center is a recallable room. The printed name is "Paper Maze, Center". The refer-name is "the Paper Maze Center".
The zone is garden-maze-zone.
The description is "You have found the heart of the[if a dragon is in Garden-Maze-Center] hedge[end if] maze: a circle of paper screens. A single opening to the west leads back to the labyrinth. You also notice an open hatchway which leads to a crawlspace below[if no dragon is in Garden-Maze-Center].[para]With the dragon gone, the illusion of a hedge maze has faded. It's just a paper room[end if]."
Understand "paper", "maze", "center", "heart" as the Garden-Maze-Center.
Rule for printing the name of the Garden-Maze-Center while asking which do you mean: say "Paper Maze Center".
The can't-go is "You can go west or down."
Check going outside in the Garden-Maze-Center:
instead try going west.
Check going west from the Garden-Maze-Center when Aistheta is not fixed:
now the flail-counter of the Garden-Maze-Lost is two;
say "You head back out into the maze."
Check touching the lamps-backdrop in Garden-Maze-Center when Pneuma is not fixed:
[Customize the "...you can't fix it from here" message.]
instead say "There's no reason to mess with the sophic lamps. Something is wrong with Pneuma; best deal with that directly."
Check waving the centrality-lodestone in Garden-Maze-Center:
instead say "You hold the silk cord by one end, and set the stone swinging. It spins in a tight circle, indicating that you are already at the center."
The short-description of Pneuma is "inscribed on the screens".
The mazecen-hatch is scenery in the Garden-Maze-Center. The printed name is "hatchway".
The description is "It's just an open hatchway that leads down."
Understand "hatch", "hatchway", "crawlway", "crawlspace" as the mazecen-hatch.
Check entering the mazecen-hatch:
instead try going down.
Check closing the mazecen-hatch:
instead say "There's no hatch to close."
The mazecen-screens are plural-named readable paper-scenery in the Garden-Maze-Center. The printed name is "paper screens".
The description is "The screens are painted with abstract leaf designs, representing hedgerows. [mazecen-screens-descextra]."
Understand "garden", "paper", "screen", "screens", "hedge", "hedges", "hedge-maze", "maze", "leaf", "leaves", "circle" as the mazecen-screens.
To say mazecen-screens-descextra:
if a dragon (called D) is in Garden-Maze-Center:
say "[The D] is inscribed across them";
else:
say "The mandala is no longer visible";
Check entering the mazecen-screens:
instead say "You are already standing at the center."
Check climbing mazecen-screens:
instead say "The screens are too flimsy to climb. Anyway, that would be cheating."
Check inspecting the mazecen-screens with the oculus:
instead say "The oculus shows the paper maze as symbolizing the necessary mystery of the [Retort's] operation. You're not sure why it's necessary. (If you knew, it wouldn't be a mystery, you suppose.)"
Section - Maze Crawl
The Maze-Crawl is a low-ceilinged room. The printed name is "Garden Crawlway".
The zone is garden-maze-zone.
The description is "You are at the west end of a low corridor, but the way east is fracture-blocked. Light spills down from an opening above. There's a wide crack in the south wall, although it looks like it narrows ahead.[para][if Baros is not fixed]You feel oddly heavy[else]The gravity feels normal now[end if]."
The Maze-Crawl is below the Garden-Maze-Center.
The can't-go is "The east passage is blocked, so you can go up or south."
[North-south travel rules are under Baros-Crawl.]
Check going west in the Maze-Crawl:
instead say "The crawlway goes no farther west."
Check going east in the Maze-Crawl:
instead try entering the mcrawl-fracture.
Check going outside in the Maze-Crawl:
instead try going up.
Check jumping in the Maze-Crawl when Baros is not fixed:
instead say "You can only get a few inches off the ground. The gravity is definitely off-standard."
The mcrawl-fracture is a fracture in the Maze-Crawl.
The description is "A fracture lies to the east, blocking the crawlway."
Section - Observatory
The Observatory is a recallable room.
The zone is observatory-zone.
The description is "[Observatory-desc]".
The can't-go is "The exit is east. There are alcoves north and south, though the north one is blocked[if the counterweight is fastened]. The ladder up is out of reach, but you can go down into the pool[else]. You can go up the ladder or down into the pool[end if]."
The aroma-description is "The observatory smells inexplicably of sea air".
To say Observatory-desc:
say "[if the obs-door is locked]You have found your way into[else]This is[end if] the observatory, the [Retort's] guiding eye";
say ". The dome overhead is set with windows, and each window shows a different sky and a different array of stars.[para]";
say "One level above you, an ironwork bridge crosses the dome, north to south";
if the counterweight is fastened:
say ". A ladder descends at either end, but only one of the two is lowered, and that one is obstructed by a fracture that cuts off the north side of the dome. The south-side ladder is folded up under the bridge; its counterweight hangs near the floor";
else:
say ". A ladder descends at either end. One ladder is obstructed by a fracture that cuts off the north side of the dome. The other, thankfully, is now within reach";
say ".[para]";
say "The door to the east is [open-closed obs-door]. Open alcoves to the north and south house additional equipment, but again, the north side is fracture-blocked. You also see the flooded crawlway hatch at your feet";
say period.
For room-visiting Observatory:
now the el-water is ever-seen.
Check going north in the Observatory:
instead try entering the obs-fracture.
Check going outside in the Observatory:
instead try going east.
The obs-dome is a far-sight in the Observatory. The printed name is "dome".
The reach-reason is "The dome arches high above the Aithery bridge."
The description is "The dome windows show... to be honest, you've never understood the theory. Each one is a world where the [Retort] has ever been -- or each one is the heart of some constellation -- or each one shows an aspect of the [Retort's] relationship to the Cosmos. Or something.[if Portico is visited][para](And if the windows are all different, the [Retort] must still be rigged for the march? But the portico seems to be grounded in a Hadean land... well, you knew something was wrong.)[end if][para]They are beautiful, though. You see skies that vary from velvet black to jewel-bright arrays of stars."
Understand "dome", "observatory", "window", "windows", "sky", "skies", "star", "stars", "array", "array of" as the obs-dome.
Check entering the obs-dome:
instead say "You are already standing under the dome."
Check inspecting the obs-dome with the planetary-lens:
instead say "You look up at the dome through the lens. Then you look away, blinking away a terrible headache."
Check inspecting the obs-dome with the oculus:
instead say "Through the lens, the dome looks like everywhere you've ever visited in your life."
The obs-bridge is a far-sight in the Observatory. The printed name is "bridge".
The reach-reason is "You can't reach the bridge from the observatory floor."
The description is "The bridge is the Aithery, one of the four dragon-nests. Normally the Captain would be standing up there, gazing up at the heavens and steering the [Retort] on its way[if Ch4-Scholar is not in the Aithery]. But now the bridge seems abandoned[else]. Now someone is up there, but it doesn't seem to be the Captain[end if].[para]The bridge runs from one side of the dome to the other, about ten feet above the floor. Access is by two ladders[if the counterweight is fastened]. Unfortunately one of them is blocked by a fracture, and the other is folded up under the bridge. Its counterweight hangs down, as it should, but the mechanism seems to be jammed[else]. One is blocked by a fracture, but the other is now lowered within reach[end if]."
Understand "bridge", "ironwork", "aithery" as the obs-bridge.
Check entering the obs-bridge:
instead try going up.
The compass is a prominent-scenery supporter in the Observatory.
Understand "pedestal", "screen", "slender", "circular", "fused", "white", "quartz" as the compass.
Rule for writing a paragraph about the compass:
now the compass is mentioned;
say "In the center of the chamber, beneath the bridge, stands the compass pedestal";
if the el-water is on the compass:
now the el-water is mentioned;
say " with its capsule of elemental water";
say ".[first time][br][sarge]Swabbies aren't allowed in here... You must be getting sneaky, kid.[/sarge][br][only]".
Check examining the compass:
say "The compass is a slender pedestal topped by a circular screen of white fused quartz";
if the el-water is on the compass:
say ". A capsule of elemental water is suspended above it.[para]The capsule is supposed to focus the light of the stars onto the screen, to indicate the [Retort's] location. But the screen is blank";
else:
say ". The screen is blank";
instead say "."
Check reading the compass:
instead try searching the compass.
Check searching the compass:
if the el-water is on the compass:
say "The capsule of water hangs above the compass, but the screen is blank";
else:
say "The compass is blank";
instead say "."
Check putting something on the compass when the noun is not the el-water:
instead say "You shouldn't put things on the compass. It will mess up the alignment. Or something."
Check inserting the el-water into the compass:
instead try putting the el-water on the compass.
Report putting the el-water on the compass:
instead say "You hold the capsule above the compass, where it belongs. A subtle force pulls it back into place."
Report taking the not handled el-water:
[Doesn't fire if you put it back and take it again. Whatever.]
now the el-water is handled;
instead say "You pull the elemental water away from the compass. It resists for a moment, then comes free."
Check climbing the compass:
instead say "The compass is only waist-high, and it doesn't look strong enough to take your weight."
Check turning the compass:
instead say "It's not a lodestone compass; it doesn't rotate."
Check inspecting the compass with the planetary-lens:
instead say "You look down at the screen through the lens. Then you look away, blinking away a terrible headache."
Check inspecting the compass with the oculus:
instead say "Through the oculus, the compass screen looks like a sheaf of maps -- thousands of layers of maps, imperfectly aligned."
The obs-fracture is a fracture in the Observatory.
The description is "A fracture blocks the north edge of the dome."
Check entering the obs-fracture:
instead say "The north nook (and the north-side ladder) are behind the fracture."
The bridge-ladder is metallic scenery in the Observatory. The printed name is "folding ladder".
Understand "folding", "ladder", "pulley", "mechanism" as the bridge-ladder.
Understand "folded" as the bridge-ladder when the counterweight is fastened.
Understand "unfolded" as the bridge-ladder when the counterweight is unfastened.
The description of the bridge-ladder is "[if the counterweight is fastened]The ladder is folded up under the bridge, a good eight feet above you. You recall hearing in marcher-gossip that it's been jammed for weeks; it's a running joke that the single ladder on the north side has had to serve the entire bridge crew. But that option is closed to you, now.[else]The ladder has unfolded, and now offers an easy climb to the bridge above.[end if]"
Instead of doing anything except examining to the bridge-ladder when the counterweight is fastened:
instead say "The ladder is folded up, high above and out of reach."
Check entering the bridge-ladder:
instead try going up.
Check climbing the bridge-ladder:
instead try going up.
Check putting something on the bridge-ladder when the counterweight is fastened:
instead try touching the bridge-ladder.
Check inserting something into the bridge-ladder when the counterweight is fastened:
instead try touching the bridge-ladder.
Check going up in the Observatory when the counterweight is fastened:
if g-bridge-ladder is ever-done:
instead goal-travel to Aithery;
instead say "You cannot reach the folded ladder."
Report going up from the Observatory:
say "You climb the ladder."
The bridge-cable is metallic scenery in the Observatory. The printed name is "cable".
The lens-view is "Mars".
Understand "steel", "cable" as the bridge-cable.
The description of the bridge-cable is "The cable descends from the bridge mechanism. It supports a massive lead counterweight, which hangs a few feet above the floor."
Check pulling the bridge-cable:
instead try pushing the bridge-cable.
Check shaking the bridge-cable:
instead try pushing the bridge-cable.
Check waving the bridge-cable:
instead try pushing the bridge-cable.
Check pushing the bridge-cable:
if the symbol-type of the counterweight is gossamerity-symbol:
instead say "The weight bobs loosely around on the end of the cable. The cable mechanism still seems to be jammed, however.";
else:
instead say "You manage to move the counterweight a few inches, but it swings back as soon as you stop leaning on it."
Check taking the bridge-cable:
instead say "The cable is fastened at both ends."
Check turning the bridge-cable:
instead say "You can't turn it much."
Check freeing the bridge-cable:
instead say "The cable is riveted solidly to the counterweight."
Check climbing the bridge-cable:
instead say "You've always been last in your class at rope-climbing, and this cable is smoother than the practice ropes."
The counterweight is a metallic takeable-thing in the Observatory.
The counterweight can be fastened or unfastened. [resettable]
The counterweight has a symbol-type. [even though it's not inscribable] [resettable]
Understand "counter", "weight", "lead", "massive", "block", "block of" as the counterweight.
Understand "gossamer", "gossamerity", "symbol" as the counterweight when the symbol-type of the counterweight is gossamerity-symbol.
Understand "ponderous", "ponderosity", "symbol" as the counterweight when the symbol-type of the counterweight is ponderosity-symbol.
For printing inventory details of the counterweight when the symbol-type of counterweight is not no-symbol:
[should always be inscribed, really]
say " (inscribed with the [symbol-type of counterweight] symbol)";
The lens-view is "Saturn".
Check examining the fastened counterweight:
say "The counterweight is a massive block of lead. It hangs from the bridge, at the end of a steel cable";
if the symbol-type of the counterweight is ponderosity-symbol:
say ". (BUG) Ponderosity when weight is fastened";
if the symbol-type of the counterweight is gossamerity-symbol:
say ". However, the cable is rather slack; the weight is bobbing loosely in a way which massive weights generally don't.[para]You see a [gossamerity-symbol] symbol glowing on the lead weight";
instead say "."
Check examining the unfastened counterweight:
if the player is carrying the counterweight:
say "You are carrying the block of lead, which is not as massive as usual";
else:
[The only supporter it can be on is the tilt-slab.]
say "A[if the symbol-type of the counterweight is not gossamerity-symbol] massive[end if] block of lead is lying";
if the counterweight is on the tilt-slab:
say " on the slab";
else:
say " here";
if the symbol-type of the counterweight is ponderosity-symbol:
say ". You see a [ponderosity-symbol] symbol glowing on the weight's surface";
if the symbol-type of the counterweight is gossamerity-symbol:
say ". You see a [gossamerity-symbol] symbol glowing on the weight's surface";
instead say "."
Rule for writing a paragraph about the counterweight:
if the counterweight is fastened:
now the counterweight is mentioned;
stop;
else:
say "The counterweight lies here, looking";
if the symbol-type of the counterweight is ponderosity-symbol:
say " more massive than usual";
else if the symbol-type of the counterweight is gossamerity-symbol:
say " less massive than usual";
else:
say " massive";
instead say "."
Check taking the counterweight when the symbol-type of the counterweight is ponderosity-symbol:
instead say "A team of Hibernian marines couldn't pick up the lead weight right now."
Check taking the counterweight when the symbol-type of the counterweight is no-symbol:
if the counterweight is fastened:
instead say "The counterweight is too heavy to carry, even if it weren't fastened to a cable.";
else:
instead say "The counterweight is too heavy to carry."
Check taking the counterweight when the symbol-type of the counterweight is gossamerity-symbol and the counterweight is fastened:
instead say "You seize the counterweight. It moves in your grasp, albeit sluggishly. But it's still fastened to a cable; you couldn't walk away with it. So you let go again."
Report taking the counterweight:
instead say "You lift the counterweight. It's still heavy, and it retains a massy inertia that makes it feel like it's floating in molasses. But you can carry it."
Report dropping the counterweight:
instead say "The counterweight settles to the ground."
Check putting the counterweight on a supporter:
if the second noun is the tilt-slab:
continue the action;
instead say "That might damage [the second noun]."
Check inserting the counterweight into the kiln:
instead say "The weight is too large to put into the kiln."
Check inserting the counterweight into a ritual-bound:
instead say "The weight is too large to work on effectively in a ritual bound."
Check inserting the counterweight into a container:
instead say "That might damage [the second noun]."
Check rit-adding the counterweight:
instead say "The weight is too large to work on effectively in a ritual bound."
Check freeing the fastened counterweight:
instead say "The counterweight is riveted solidly to the cable."
Check pulling the fastened counterweight:
instead try pulling the bridge-cable.
Check pushing the fastened counterweight:
instead try pushing the bridge-cable.
Check turning the fastened counterweight:
instead say "You can't turn it much."
First check shaking the fastened counterweight:
instead try shaking the bridge-cable.
Check touching the counterweight:
say "It feels like a block of lead";
if the symbol-type of the counterweight is gossamerity-symbol:
say ". It shifts a bit at your touch, however";
instead say "."
Check pushing the counterweight:
if the symbol-type of the counterweight is gossamerity-symbol:
instead say "The lead weight shifts, although it retains a massy inertia.";
else if the symbol-type of the counterweight is ponderosity-symbol:
instead say "The lead weight is utterly immovable.";
else:
instead say "The lead weight is too heavy to move."
Check pulling the counterweight:
instead try pushing the counterweight.
Check turning the counterweight:
instead try pushing the counterweight.
Check shaking the counterweight:
instead try pushing the counterweight.
Check waving the counterweight:
instead try pushing the counterweight.
Check tapping a pebble on the counterweight when the symbol-type of the noun is ponderosity-symbol:
say "You carefully lay the [symbol-type of the noun] symbol against the lead";
uninscribe the noun;
if the symbol-type of the counterweight is ponderosity-symbol:
instead say ". It discharges, but the counterweight becomes no heavier.";
say ". The symbol flares brightly and transfers to the counterweight";
let old-symbol be the symbol-type of the counterweight;
if the symbol-type of the counterweight is gossamerity-symbol:
say ", replacing the [symbol-type of the counterweight] symbol";
now the symbol-type of the counterweight is ponderosity-symbol;
if the counterweight is fastened:
now the counterweight is unfastened;
now the bridge-cable is off-stage;
mark g-bridge-ladder as done;
now the symbol-type of g-bridge-ladder is ponderosity-symbol;
if old-symbol is no-symbol:
say ".[para]The cable vibrates with sudden strain, and then emits a portentous creak. You jump back just as it snaps";
else:
say ".[para]The loose cable twangs taut, vibrating with sudden strain. You jump back just as it snaps";
instead say ". The counterweight, now freed, slams to the floor and lies there like the corpse of Atlas.[para]The shock has evidently been too much for the jammed mechanism. The cable whips up and out of sight; the folded ladder, in reaction, unfolds segment by segment until it reaches the floor.";
if the player carries the counterweight:
now the counterweight is in the location;
instead say ".[para]The lead, quite suddenly, is heavier than a ton of... lead. Fortunately, your toes were out of the way, because the counterweight crashes to the ground with an almighty impact.";
instead say ".[para]The counterweight shifts slightly, settling into the [if the counterweight is on the tilt-slab]slab[else]ground[end if] with unnatural force."
Check tapping a pebble on the counterweight when the symbol-type of the noun is gossamerity-symbol:
say "You carefully lay the [symbol-type of the noun] symbol against the lead";
uninscribe the noun;
if the symbol-type of the counterweight is gossamerity-symbol:
instead say ". It discharges, but the counterweight becomes no lighter.";
say ". The symbol flares brightly and transfers to the counterweight";
let old-symbol be the symbol-type of the counterweight;
if the symbol-type of the counterweight is ponderosity-symbol:
say ", replacing the [symbol-type of the counterweight] symbol";
now the symbol-type of the counterweight is gossamerity-symbol;
if the counterweight is fastened:
instead say ".[para]The cable relaxes slightly. The weight is now swinging more easily, almost bobbing back and forth.";
instead say ".[para]The counterweight shifts a little against the [if the counterweight is on the tilt-slab]slab[else]ground[end if]. It no longer seems as immovable as it was."
Instead of tapping the counterweight on the dispersal-brush:
instead try tapping the second noun on the noun.
Instead of putting the dispersal-brush on the counterweight when the symbol-type of the counterweight is not no-symbol:
instead try tapping the noun on the second noun.
Check tapping the dispersal-brush on the counterweight when the symbol-type of the counterweight is ponderosity-symbol:
now the symbol-type of the counterweight is no-symbol;
instead say "You brush the feather across [the counterweight]. The [ponderosity-symbol] symbol blurs and fades away. You see no other obvious difference, but the weight shifts just a little on the [if the counterweight is on the tilt-slab]slab[else]ground[end if]."
Check tapping the dispersal-brush on the counterweight when the symbol-type of the counterweight is gossamerity-symbol:
now the symbol-type of the counterweight is no-symbol;
say "You brush the feather across [the counterweight]. The [gossamerity-symbol] symbol blurs and fades away";
if the counterweight is fastened:
now the counterweight is unfastened;
now the bridge-cable is off-stage;
mark g-bridge-ladder as done;
now the symbol-type of g-bridge-ladder is gossamerity-symbol;
say ".[para]The loose cable twangs taut, vibrating with sudden strain. You jump back just as it snaps";
instead say ". The counterweight, now freed, slams to the floor.[para]The shock has evidently been enough for the jammed mechanism. The cable whips up and out of sight; the folded ladder, in reaction, unfolds segment by segment until it reaches the floor.";
if the player carries the counterweight:
now the counterweight is in the location;
instead say ".[para]The lead, quite suddenly, regains its original mass. Fortunately, your toes were out of the way, because the counterweight crashes to the ground with an almighty impact.";
instead say ".[para]The counterweight shifts slightly, settling into the [if the counterweight is on the tilt-slab]slab[else]ground[end if] with renewed force."
The obs-door is a lockable scenery door. The printed name is "painted door".
The opening-goal is g-obs-door.
The pull-side is Observatory.
The refer-name is "Observatory door".
The description is "[obs-door-desc]".
Understand "painted", "paint", "door", "latch" as the obs-door.
Understand "rococo", "cherub", "cherubs", "maiden", "maidens", "muse", "observatory" as the obs-door when the location is the Garden.
Understand "plain", "grey", "gray" as the obs-door when the location is the Observatory.
The obs-door is east of the Observatory. The obs-door is west of the Garden.
[locked, but openable from Observatory side.]
To say obs-door-desc:
if the location is the Garden:
say "The observatory door is painted with Rococo cherubs and maidens, no doubt alluding to the Muse of Astrographerie. (The maidens are all tastefully veiled, to your long-time disappointment.) The door is";
if obs-door is closed:
if obs-door is locked:
say " closed and locked";
else:
say " closed but unlocked";
else:
say " open";
else:
say "The door is painted plain grey on this side, matching the walls. It is";
if obs-door is closed:
if obs-door is locked:
say " closed and locked, but the latch is on this side -- you could just pull it open from here";
else:
say " closed but unlocked";
else:
say " open";
say period.
Check going when the door gone through is the obs-door and the obs-door is locked and the location is the Observatory:
say "(first unlocking and opening [the obs-door], from this side)[command clarification break]";
now the obs-door is unlocked;
silently try opening the obs-door;
if the obs-door is closed:
stop the action.
Check going when the door gone through is the obs-door and the obs-door is locked and the location is the Garden:
if g-flood-crawlway is ever-done:
instead goal-travel to the Observatory.
Check opening the obs-door when the obs-door is locked and the location is the Observatory:
say "(first unlocking [the obs-door], from this side)[command clarification break]";
now the obs-door is unlocked.
Check unlocking the obs-door with something when the obs-door is locked and the location is the Observatory:
say "The door doesn't need a key from this side. You twist the knob and the lock snaps open.";
now the obs-door is unlocked;
stop the action.
Check locking the obs-door with something when the obs-door is unlocked and the location is the Observatory:
say "You don't need a key from the side; you just re-lock the door.";
now the obs-door is closed;
now the obs-door is locked;
stop the action.
Check inspecting the obs-door with the oculus:
instead say "Through the oculus, the observatory door gives the impression of fulsome Renaissance natural science."
The obs-view-pool is mass-named scenery in Observatory. The printed name is "hatchway".
Understand "water", "pool", "hatch", "hatchway", "crawl", "crawlway", "crawlspace" as the obs-view-pool.
The description of the obs-view-pool is "The crawlway hatch is uncovered, but water ripples in the opening. The entire crawlspace below must be flooded."
Check searching the obs-view-pool:
instead say "The flooded crawlway is too dim to search from up here."
The drop-stuff-in-obs-view-pool rule is listed after the better can't insert what's not held rule in the check inserting it into rulebook.
Check inserting a takeable thing into the obs-view-pool (this is the drop-stuff-in-obs-view-pool rule):
perform throw moisturization with the noun in Obs-Crawl;
if the noun is the brass-pin and the brass-pin symbol-matches fixation-symbol:
say "[br]You notice a faint light trailing behind it as it disappears into the murk.";
stop the action.
Check eating the obs-view-pool:
instead say "You think about how clean the marcher's crawlways haven't been, and what filth a subterranean flood is likely to have washed up. You decide not to ingest any."
Check tasting the obs-view-pool:
instead try eating the noun.
Check touching the obs-view-pool:
instead say "It's cold and slightly oily."
Check entering the obs-view-pool:
instead try going down.
Check opening the obs-view-pool:
instead say "The hatchway has no cover."
Check closing the obs-view-pool:
instead say "The hatchway has no cover."
Section - Obs Nook
The Obs-Nook is a room. The printed name is "Observatory Alcove, South". The refer-name is "the Observatory Alcove".
The zone is observatory-zone.
The description is "This alcove houses the magnificent Horological Calculator -- a complex machine whose controls include an armillary sphere, a dial, and a slot[if the calc-slot is not empty]. There's [a first thing held by the calc-slot] in the slot[end if]."
The Obs-Nook is south of the Observatory.
For room-visiting Obs-Nook:
now the blank-tin-slip is ever-seen.
The can't-go is "The Observatory is north."
The aroma-description is "The observatory smells inexplicably of sea air".
Check going outside in the Obs-Nook:
instead try going north.
The obs-nook-dome is a far-sight in the Obs-Nook. The printed name is "dome".
The description is "You'd get a better view from the center of the observatory."
The reach-reason is "The observatory dome is to the north."
Understand "dome", "observatory", "window", "windows", "sky", "skies", "star", "stars", "array", "array of" as the obs-nook-dome.
Check entering the obs-nook-dome:
instead try going north.
The obs-nook-bridge is a far-sight in the Obs-Nook. The printed name is "bridge".
The reach-reason is "The bridge is in the observatory proper."
The description is "The bridge is in the observatory proper."
Understand "bridge", "ironwork", "aithery" as the obs-nook-bridge.
Definition: a paper-sheet is obs-sheet-pair if it is sh-observatory-1 or it is sh-observatory-2.
Rule for writing a paragraph about a obs-sheet-pair paper-sheet:
if sh-observatory-1 is in the location and sh-observatory-2 is in the location:
say "Two papers, [a sh-observatory-1] and [a sh-observatory-2], have been discarded here.";
else if sh-observatory-1 is in the location:
say "[A sh-observatory-1] of paper is lying here.";
else if sh-observatory-2 is in the location:
say "[A sh-observatory-2] of paper is lying here."
Section - Obs Aithery
The Aithery is a recallable room.
The zone is aithery-zone.
The description is "This bridge crosses the upper span of the observatory dome. There's nothing at either end except a ladder. This is a place to stand and watch the Cosmos, and the [Retort's] place in it[if no dragon is in the Aithery].[para]With the dragon gone, the windows of the dome seem like pointless scenery[end if]."
Understand "bridge" as the Aithery.
Rule for printing the name of the Aithery while asking which do you mean: say "Aithery Bridge".
The Aithery is above the Observatory.
The can't-go is "You can only go back down the ladder."
The aroma-description is "The observatory smells inexplicably of sea air".
Check going north in the Aithery:
instead try entering the aith-fracture.
Check going south in the Aithery:
instead say "The bridge ends at the south side of the dome. There's no passage beyond; just a ladder down."
Check going outside in the Aithery:
instead try going down.
Report going down from the Aithery:
say "You climb down to ground level."
The short-description of Aistheta is "inscribed on the dome just overhead".
The aith-ladder is metallic scenery in the Aithery. The printed name is "folding ladder".
The description is "The ladder has unfolded, and now reaches down to the observatory floor."
Understand "folding", "ladder", "unfolded" as the aith-ladder.
Check entering the aith-ladder:
instead try going down.
Check climbing the aith-ladder:
instead try going down.
Check pulling the aith-ladder:
instead say "You have no reason to fold the ladder back up, and you probably couldn't anyhow."
Check taking the aith-ladder:
instead try pulling the aith-ladder.
The aith-dome is glassy readable scenery in the Aithery. The printed name is "dome".
The description is "The dome windows show... to be honest, you've never understood the theory. Each one is a world where the [Retort] has ever been -- or each one is the heart of some constellation -- or each one shows an aspect of the [Retort's] relationship to the Cosmos. Or something.[para][aith-dome-descextra]."
Understand "glass", "dome", "observatory", "window", "windows", "sky", "skies", "star", "stars", "array", "array of" as the aith-dome.
To say aith-dome-descextra:
if a dragon (called D) is in the Aithery:
say "The dragon [D] is inscribed across the dome, just overhead";
else:
say "With the dragon gone, the dome seems incomplete";
Check searching the aith-dome:
instead try examining the aith-dome.
Check entering the aith-dome:
instead say "You are already standing under the dome."
Check touching the aith-dome:
instead say "You feel the window glass."
Check smashing the aith-dome:
instead say "Breaking a window would be disastrous. Probably. You think."
Check inspecting the aith-dome with the planetary-lens:
instead say "You look up at the dome through the lens. Then you look away, blinking away a terrible headache."
Check inspecting the aith-dome with the oculus:
instead say "Through the lens, the dome looks like everywhere you've ever visited in your life."
Check putting the F-sharp-chime on the aith-dome when the ring-time of the F-sharp-chime is not zero:
instead try tapping the F-sharp-chime on the aith-dome.
Check inserting the F-sharp-chime into the aith-dome when the ring-time of the F-sharp-chime is not zero:
instead try tapping the F-sharp-chime on the aith-dome.
Check inserting something into the aith-dome:
instead say "You can't push things through solid glass."
The aith-fracture is a fracture in the Aithery.
The description is "A fracture blocks the north edge of the dome."
Check entering the aith-fracture:
instead say "The north end of the bridge (and the north-side ladder) are behind the fracture."
Section - Observatory Crawl
The Obs-Crawl is a low-ceilinged room. The printed name is "Observatory Crawlspace, Flooded". The refer-name is "the Flooded Observatory Crawlspace".
The near-zone-room is Observatory.
The description is "You are floating in the submerged crawlway, which runs back to the north. Another collapse blocks further passage south. A hatchway above gives access to the open air."
The Obs-Crawl is below the Observatory.
The Obs-Crawl is south of the Scaphe-Crawl.
The atmosphere of the Obs-Crawl is water-atm.
The can't-go is "The crawlway south has collapsed, so you can only swim north or up."
Check going down from the Observatory:
begin underwater activity;
perform inventory moisturization in Obs-Crawl.
Check going up from the Obs-Crawl:
mark g-flood-crawlway as done;
cease underwater activity.
Check going outside in the Obs-Crawl:
instead try going up.
Check going south in the Obs-Crawl:
instead try entering the obs-crawl-beams.
Check going north from the Obs-Crawl:
if breath-potion-remaining is zero:
exert yourself underwater;
instead say "You kick downwards and begin pulling yourself along the crawlway. But even a few feet of the dark, cramped passage makes your lungs heave in your chest. You push backwards, back to the light.";
say "You kick downwards and pull yourself along the crawlway. The passage is cramped and claustrophobic, and even with the potion, your chest feels tight. But you soon see light ahead, and an open hatch becomes visible above you."
The obs-crawl-hatch is scenery in the Obs-Crawl. The printed name is "hatch".
The description is "The opening above [if the Observatory is not visited]must lead to[else]leads to[end if] the observatory."
Understand "hatch", "hatchway", "opening", "patch", "air", "rippling", "light" as the obs-crawl-hatch.
Check entering the obs-crawl-hatch:
instead try going up.
Check getting off the obs-crawl-hatch:
instead try going up.
The obs-crawl-water is a mass-named room-proxy in the Obs-Crawl. The printed name is "water".
Understand "water" as the obs-crawl-water.
The description of the obs-crawl-water is "Chilly water fills the crawlway, top to bottom."
Check eating the obs-crawl-water:
instead say "[drink-crawl-water]."
Check tasting the obs-crawl-water:
instead try eating the noun.
Check touching the obs-crawl-water:
instead say "It's cold and slightly oily."
Check entering the obs-crawl-water:
instead say "You are already submerged."
The obs-crawl-beams are plural-named scenery in the Obs-Crawl. The printed name is "fallen beams".
The description is "The crawlway to the south is blocked by another collapse."
Understand "fallen", "collapse", "collapsed", "beam", "beams", "roof", "ceiling" as the obs-crawl-beams.
Check entering the obs-crawl-beams:
instead say "The crawlway to the south is blocked by fallen beams."
Check pushing the obs-crawl-beams:
instead say "Even underwater, the beams are too heavy to move."
Check pulling the obs-crawl-beams:
instead try pushing the obs-crawl-beams.
Check taking the obs-crawl-beams:
instead try pushing the obs-crawl-beams.
Check repairing the obs-crawl-beams:
instead say "You cannot fix the crawlway roof."
Section - Top of Stairs
The Grand-Stair is a recallable room. The printed name is "Grand Stair, Top". The refer-name is "the Top of the Grand Stair". The refer-preposition is "at".
The zone is garden-zone.
The description is "Two hallways intersect beneath an elegant vault of brick-red tile, which sweeps around to follow a grand staircase down to the lower levels. The garden is visible to the north. To the west is the ornate door of the Birdhouse, which is [open-closed bird-door].[para]The hall to the south is blocked by yet another fracture. [if the far-inferno is in Grand-Stair]The side corridor to the east is much the worse; its far end seems to be on fire[else]Happily, the east corridor is no longer on fire[end if]."
Understand "grand", "stair", "stairs", "stairway", "staircase", "top", "top of" as the Grand-Stair.
The Grand-Stair is south of the Garden.
Rule for printing the name of the Grand-Stair while asking which do you mean: say "Top of the Grand Stair".
The can't-go is "You can go east, north, or down the stairs; the Birdhouse door is west. The hall south is blocked."
The aroma-description is "You smell a trace of scorched wood".
Check going south in the Grand-Stair:
instead try entering the stairs-fracture.
Check going inside in the Grand-Stair:
instead try going west.
Check going up in the Grand-Stair:
instead say "This is the top of the staircase."
Check going when the door gone through is the grand-stair-proxy:
if the location is the Grand-Stair:
say "You head down the grand staircase[if the Basement is not visited-this-cycle]. The air grows cooler and quieter as you descend into the depths[end if].";
else:
say "You climb the grand staircase.";
continue the action.
The grand-stair-proxy is a scenery open unopenable door. The printed name is "staircase".
The description is "This wide spiral runs around and [if the location is the Grand-Stair]down to the [Retort's] lower level[else]up to the [Retort's] main level[end if]. Red tile forms a graceful helical vault above."
Understand "stair", "stairs", "staircase", "grand", "wide", "spiral" as the grand-stair-proxy.
Understand "brick", "red", "brick-red", "tile", "vault" as the grand-stair-proxy.
The grand-stair-proxy is below the Grand-Stair. The grand-stair-proxy is above the Basement.
Check taking the grand-stair-proxy:
instead try entering the grand-stair-proxy.
Check climbing the grand-stair-proxy:
instead try entering the grand-stair-proxy.
The stairs-fracture is a fracture in the Grand-Stair.
The description is "A fracture blocks the hallway south of here[if Ch1-Climber is in Grand-Stair]. Lt Michael Powes is caught in it[end if]."
The initial appearance of Ch1-Climber is "[meet Ch1-Climber]You see someone caught beyond the fracture: Lieutenant Powes. He appears to be walking towards the Birdhouse door."
The far-inferno is a far-sight in the Grand-Stair. The printed name is "fire".
The description is "The far end of the east corridor is on fire! You can feel the radiant heat all the way from here."
The reach-reason is "The fire is at the far end of the east hallway."
Understand "fire", "flame", "blaze", "inferno" as the far-inferno.
The stair-garden-view is a far-sight in the Grand-Stair. The printed name is "garden".
The reach-reason is "The paper garden is to the north."
The description is "The paper garden is to the north."
Understand "paper", "garden" as the stair-garden-view.
Check entering the stair-garden-view:
instead try going north.
Section - Birdhouse
The Birdhouse is a recallable room.
The zone is birdhouse-zone.
The description is "The Birdhouse is a circular chamber with no roof. It's not open to the sky; it just goes up forever. The door to the east is [open-closed bird-door]. You also see a cracked flagstone with a gap leading to a crawlspace below.[para]The name comes from a ring of metal pylons that take up the center of the room. You can see the fanciful resemblance to a birdcage[if a dragon is in the Birdhouse], although they don't imprison anything[else], but the cage is empty now; the dragon is gone[end if]."
Understand "chamber", "birdcage" as the Birdhouse.
The can't-go is "The only exits are east and down."
Check going outside in the Birdhouse:
instead try going east.
Check going up in the Birdhouse:
instead say "There's a lot of up, but no way to get there."
The short-description of Syndesis is "inscribed across the curving wall".
The bird-pylons are metallic plural-named scenery in the Birdhouse. The printed name is "pylons".
The description is "There are sixteen pylons set in a ring. They're made of some patina-dulled metal. You know they have something to do with the strange geometry of the room, which maintains or is maintained by the dragon which [if Syndesis is in the Birdhouse]lives[else]should live[end if] here.[para]Like the room, the pillars run upwards to infinity. When you look up, they don't look parallel -- they seem to form an hourglass shape. You have no idea whether that's trick of perspective."
Understand "pylon", "pylons", "pillar", "pillars", "ring", "ring of", "metal", "patina", "dull", "dulled", "patina-dulled", "alloy", "cage", "birdcage" as the bird-pylons.
Check taking the bird-pylons:
instead say "The pylons are fixed in the floor, and... well, they're infinitely tall. You're not sure what it would even mean to shift them."
Check pulling the bird-pylons:
instead try taking the bird-pylons.
Check pushing the bird-pylons:
instead try taking the bird-pylons.
Check turning the bird-pylons:
instead try taking the bird-pylons.
Check entering the bird-pylons:
instead say "You step into the ring of pylons. Except that when your foot lands, you're stepping out of the ring on the other side. Odd."
Check climbing the bird-pylons:
instead say "A terrifying thought. What would you be climbing up to? Fortunately for your peace of mind, the pylons are too smooth to climb."
Check touching the bird-pylons:
instead say "The pylons are some dull alchemical alloy. It feels very cold, and your fingers leave no prints."
Check rubbing the bird-pylons:
instead say "The alloy is very cold. No matter how hard you rub, it neither warms nor becomes brighter."
Check inserting something not sessile into the bird-pylons:
instead say "You try pushing [the noun] into the ring of pylons, but your hand seems to keep coming out the far side. You give up."
Check inspecting the bird-pylons with the planetary-lens:
instead say "You inspect the ring of pylons through the lens. They're hard to focus on, but you get a sense of the Higher Spheres."
Check inspecting the bird-pylons with the oculus:
instead say "Through the oculus, the pylons rather resemble Yggdrasil: they are the roof-tree of the [Retort]."
Check tapping pin-or-bolt on the bird-pylons when the symbol-type of the noun is gensaturation-symbol:
uninscribe the noun;
instead say "You lay the [gensaturation-symbol] symbol against one of the pylons. It discharges with a muted crackle, but only a small patch of the alloy brightens. Clearly the pylons are far too weighty for a simple cleansing ritual.";
The bird-no-roof is a far-sight in the Birdhouse. The printed name is "no roof".
The description is "There's no ceiling. The walls just dwindle into the distance overhead, with the pylons dwindling between them. It gives you more of a sense of vertigo than empty space would."
The reach-reason is "You can't see any such roof."
Understand "roof", "ceiling", "sky", "no roof" as bird-no-roof.
[This doesn't cover looking at the no-roof with other lenses. Whatever.]
Check inspecting the bird-no-roof with the oculus:
instead say "Even with the oculus, you can't see the roof."
Check inspecting the bird-no-roof with the planetary-lens:
instead say "Even with the lens, you can't see the roof."
The bird-door is a lockable scenery door. The printed name is "engraved door".
The pull-side is Grand-Stair.
The refer-name is "Birdhouse door".
The bird-door can be ever-tried. [resettable]
Understand "engraved", "ornate", "door", "handle", "moire", "moiré", "geometric", "moorish", "design" as the bird-door.
Understand "birdhouse" as the bird-door when the location is the Grand-Stair.
The bird-door is west of the Grand-Stair. The bird-door is east of the Birdhouse.
Check examining the bird-door:
if the location is the Grand-Stair:
say "This door leads to the Birdhouse, the lair of one of the [Retort's] dragons. It is engraved with a moiré geometric design -- something Moorish, no doubt symbolic of the dragon's function. The Birdhouse door is [open-closed bird-door]";
else:
say "The engraved door is [open-closed bird-door]";
instead say "."
To print the bird-door explanation, explicitly:
if the bird-door is not ever-tried:
now the bird-door is ever-tried;
mark bird-door-fact as known;
say ".[para]Lovely. With everything that's wrong on the [Retort], this one security stricture remains perfectly functional. It's reacting to your psychic signature -- an ensign can't just walk into the Birdhouse, so when you approach, the door gets defensive. Yes, 'defensive' is a technical term in aura engineering";
else:
if explicitly:
say ". The defensive stricture is still active".
To decide whether bird-door-protected:
if the aura-mod-type is invisibility-symbol:
decide yes;
if the aura-mod-type is imitation-symbol and aura-mod-persona is high-rank:
decide yes;
decide no.
Check closing the open bird-door:
instead say "You had enough trouble opening the door. You're not going to shut it again."
Check opening the closed bird-door:
[Handle successes...]
if the aura-mod-type is invisibility-symbol:
say "The handle is solid in your fingers now, although your hand doesn't exactly feel like part of your body.";
now the aura-mod-time is one;
mark the g-bird-door as done;
now the symbol-type of g-bird-door is invisibility-symbol;
now the bird-door is ever-tried;
continue the action;
if the aura-mod-type is imitation-symbol and aura-mod-persona is high-rank:
say "The handle is solid in your fingers now, although your hand feels like part of someone else's body.";
now the aura-mod-time is one;
mark the g-bird-door as done;
now the symbol-type of g-bird-door is imitation-symbol;
mark aura-imitation-persona-charge as done;
now the persona of aura-imitation-persona-charge is aura-mod-persona;
now the bird-door is ever-tried;
continue the action;
if the aura-mod-type is imitation-symbol:
say "You reach for the handle, but your fingers go numb and slide away";
say ". Your aura must still not be passing muster";
instead say ".";
if bird-door-protected:
instead say "(BUG) bird-door-protected case not handled!";
[Handle auto-solutions...]
if g-bird-door is ever-done and the aura-mod-type is no-symbol:
instead goal-perform g-bird-door;
say "You reach for the handle, but your fingers go numb and slide away";
print the bird-door explanation, explicitly;
instead say "."
Report opening the bird-door:
instead say "You twist and [if in Birdhouse]push[else]pull[end if], and the door opens just like any ordinary door."
Check touching the bird-door when not bird-door-protected:
say "Your fingers slide numbly away from the door";
print the bird-door explanation;
instead say "."
Check rubbing the bird-door when not bird-door-protected:
instead try touching the bird-door.
Check waving the bird-door when not bird-door-protected:
instead try touching the bird-door.
Check shaking the bird-door when not bird-door-protected:
instead try touching the bird-door.
Check inspecting the bird-door with the oculus:
instead say "Through the oculus, you can see the security stricture. It looks like a haze of translucent needles surrounding the door."
Section - Bird-Crawl
The Bird-Crawl is a room. The printed name is "Birdhouse Crawl".
The zone is birdhouse-zone.
The description is "This space must have been a crawlway, but it's entirely fallen in now. You barely fit, and there's no space to wriggle in any direction but back up."
The Bird-Crawl is not lamp-enabled.
The Bird-Crawl is below the bird-hatch. The Birdhouse is above the bird-hatch.
The can't-go of the Bird-Crawl is "You can only go back up."
Check going outside in the Bird-Crawl:
instead try going up.
The bird-hatch is an open unopenable scenery door. The printed name is "flagstone gap".
The description is "[if the location is the Birdhouse]It's just a gap in a flagstone, leading to a crawlway below[else]The Birdhouse is above you[end if]."
Understand "flagstone", "crack", "cracked", "gap" as the bird-hatch.
Understand "birdhouse" as the bird-hatch when the location is the Bird-Crawl.
Check inserting something into the bird-hatch:
if the location is the Birdhouse:
instead say "Just enter the gap and drop [the noun].";
else:
instead say "Just go outside and drop [the noun]."
Check repairing the bird-hatch:
instead say "There's no obvious way to do that."
Chapter - Chancelry
Section - Charred Hall
The Charred-Hall is a recallable room. The printed name is "[if Charred-Hall-alight]Burning Hall West[else]Charred Hall West[end if]".
The zone is garden-zone.
The description is "[Charred-Hall-desc]".
The Charred-Hall is east of the Grand-Stair.
Understand "charred", "burning", "burned", "burnt", "hall", "hallway", "west" as the Charred-Hall.
To say Charred-Hall-desc:
if Charred-Hall-alight:
say "This hall runs west to east, from the grand stairs to the high wing";
if not currently fireproof:
say ". [if the Charred-End is not visited]You've never been inside the high wing, and your chances don't look good today, because it's on fire[else]Except the high wing is on fire at the moment[end if]";
say ".[para]The entire east end of the hall is enveloped in flame. You can't tell what's burning -- the walls? the floor? But the heat is intense; you can't go any further";
else:
say ". The high wing is on fire at the moment; the east end of the corridor is an inferno. But you can barely feel the heat";
else:
say "This hall runs west to east, from the grand stairs to the high wing. The fire to the east has been extinguished, leaving only a layer of ash";
say period.
The can't-go is "The hall runs east and west[if Charred-Hall-alight], although east isn't promising[end if]."
The aroma-description is "The smell of smoke [if Charred-Hall-alight]is thick[else]lingers[end if]".
The out-inferno is scenery in the Charred-Hall. It burns at 15. The printed name is "inferno".
The description is "The inferno fills the far end of the hall[if not currently fireproof]. It does not appear to be spreading, which is strange. (Although you'll accept strange today, if it keeps the rest of the marcher from going up.)[para]Even at this distance, the heat is nearly intolerable[else]. But you feel only a trace of warmth on your face[end if]."
The out-inferno is alight.
The out-inferno can be ever-tried. [resettable]
Understand "fire", "flame", "blaze", "blazing", "inferno", "heat" as the out-inferno.
Check entering the out-inferno:
instead try going east.
Check blowing on the out-inferno:
instead say "You can't blow the inferno out like a candle!"
Check throwing the fire-sucker at the out-inferno:
instead try putting the fire-sucker on the out-inferno.
Report topically-applying the fire-sucker to the out-inferno:
now the in-inferno is off-stage;
now the out-inferno is off-stage;
now the far-inferno is off-stage;
now the atmosphere of Charred-End is normal-atm;
now Charred-End is visited; [necessary because of the way g-charred-hall works! The player has almost certainly visited it before, anyhow.]
mark g-charred-hall as done;
now the tool-used of g-charred-hall is fire-sucker;
instead say "You pull the stopper, and whip the crimson liquid into the flames. There is a mighty [em]whump[/em] as the hallway goes dark.[para]When the green afterimages fade from your sight, the hall looks [one of]like -- like[or]like[stopping] a long-dead fireplace. The walls are blackened and the floor is layered with ash. But there isn't a spark left alight, and while the air smells of smoke, it is not intolerably warm."
Check going east from the Charred-Hall when Charred-Hall-alight:
if g-charred-hall is ever-done and not currently fireproof:
instead goal-travel to Charred-End;
if not currently fireproof:
instead say "The fierce heat drives you back.";
if the player carries the fire-sucker:
instead say "Even though you are fireproof, it would make sense to use [the fire-sucker].";
say "You step into the flames, which feel like a warm breeze on your skin";
mark g-charred-hall as done;
now the tool-used of g-charred-hall is fire-resistance;
if the out-inferno is not ever-tried:
now the out-inferno is ever-tried;
say ". Your marcher uniform, woven with alchemical virtues to resist this sort of mistreatment, only scorches slightly";
say ".";
perform inventory incineration in in-inferno.
A charred-hall-ash is a kind of thing. The printed name of a charred-hall-ash is usually "ash".
A charred-hall-ash is usually scenery.
The description of charred-hall-ash is usually "The [if Charred-Hall-alight]fire[else]now-extinguished fire[end if] has spread a thin layer of ash over the walls and floor."
The lens-view of charred-hall-ash is usually "the Earth, faintly".
Understand "ash", "ashes", "layer", "layer of", "grey", "gray" as a charred-hall-ash.
Check taking charred-hall-ash:
if the ash is off-stage:
now the player carries the ash;
set pronouns from the ash;
instead say "You scrape up a pinch of ash.";
else:
say "You've already taken some ash. You don't need any more.";
if the player does not carry the ash:
instead try recalling the ash;
stop the action.
Check dropping ash when the location is Charred-Hall or the location is Charred-End:
now the ash is off-stage;
instead say "You discard the ash."
Check smelling charred-hall-ash:
instead say "It smells burnt."
Check tasting charred-hall-ash:
instead say "You don't really want to lick the walls."
Check rubbing charred-hall-ash:
instead say "You can't clean the entire hallway."
Check pushing charred-hall-ash:
instead try rubbing the noun.
The ash-west is a charred-hall-ash in Charred-Hall.
Section - Charred Hall East
The Charred-End is a room. The printed name is "[if Charred-Hall-alight]Burning Hall East[else]Charred Hall East[end if]".
The description is "[Charred-End-desc]".
The zone is chancel-pre1-zone.
The atmosphere of Charred-End is fire-atm.
The Charred-End is east of the Charred-Hall.
To say Charred-End-desc:
if Charred-Hall-alight:
say "You are standing in an inferno. That is, you are at the east end of the hall, which is on fire. Even though you can barely feel the heat, the fire is hard to ignore.[para]To the east is an obsidian door, a dark rectangle amid the fire's glare";
else:
say "You are at the east end of the hall, now grey with ash. The hall ends at a door of solid obsidian";
if the obsidian-door is closed:
say ". You know this door leads to the high wing and the Chancel";
if the obsidian-door is locked:
say ", but it is closed and locked";
else:
say "; it is closed, but the lock has been dissolved away";
else:
say ". The obsidian door is open";
say period.
The can't-go is "The hall runs west. The obsidian door is east."
The aroma-description is "The smell of smoke [if Charred-Hall-alight]fills the air[else]lingers[end if]".
Check going outside in the Charred-End:
instead try going west.
Report going west from the Charred-End when Charred-Hall-alight:
say "You step back out of the inferno."
The in-inferno is scenery in the Charred-End. It burns at 15. The printed name is "inferno".
The description is "The fire is all around you. It's a startling view."
The in-inferno is alight.
Understand "fire", "flame", "blaze", "blazing", "inferno", "heat" as the in-inferno.
Check entering the in-inferno:
instead say "You are already standing in the inferno."
Check blowing on the in-inferno:
instead say "You can't blow the inferno out like a candle!"
To decide whether Charred-Hall-alight:
if the atmosphere of Charred-End is fire-atm:
decide yes.
The ash-east is a charred-hall-ash in Charred-End.
The obsidian-door is a mineralish lockable scenery door. The printed name is "obsidian door".
The opening-goal is g-obsidian-door.
The pull-side is Charred-End.
The refer-name is "obsidian door".
The lens-view is "the Earth".
Understand "black", "obsidian", "door", "slab", "rectangle", "polished", "obdurate", "lock", "handle" as the obsidian-door.
The obsidian-door is west of the Antechamber. The obsidian-door is east of the Charred-End.
Check examining the obsidian-door:
say "The door to the east is an obsidian slab, polished and obdurate";
if the obsidian-door is locked:
instead say ". The heat hasn't even touched it.[para]You know that the chancel lies that way, but you've never been permitted inside. The obsidian door is firmly shut.";
say ". The stone is now scarred by solvent";
if the obsidian-door is open:
say ", and the door is wide open";
else:
say ", however";
instead say "."
Check opening the locked obsidian-door:
if g-obsidian-door is ever-done:
goal-perform g-obsidian-door;
if the obsidian-door is open:
say "You open the door.";
stop the action;
instead say "You tug on the obsidian handle, but the door is locked."
Check unlocking the obsidian-door with the obsidian-solvent:
instead try putting the obsidian-solvent on the obsidian-door.
Report topically-applying the obsidian-solvent to the obsidian-door:
if the obsidian-door is unlocked:
instead say "You pour obsidian solvent onto the door, scarring it further.";
now the obsidian-door is unlocked;
instead say "You pour a drop of obsidian solvent onto the door. The dark liquid soaks instantly into the black stone, leaving a rough scar. Perfect! You concentrate on the area around the handle, corroding deep grooves into the door's substance. After some careful work, the entire locking mechanism falls away, leaving the door swinging loosely."
Check putting the bamuriatic on the obsidian-door:
[Bamuriatic is not topical, so we have to trigger topically-applying manually.]
retire the noun by applying to the second noun;
instead try topically-applying the noun to the second noun.
Check tapping the bamuriatic on the obsidian-door:
retire the noun by applying to the second noun;
instead try topically-applying the noun to the second noun.
Report topically-applying the bamuriatic to the obsidian-door:
instead say "You dribble the powerful acid over the door. It etches frosty tracks into the obsidian surface, but does not penetrate."
Check tapping the F-sharp-chime on the obsidian-door when the symbol-type of the F-sharp-chime is permeability-symbol:
say "You carefully lay the [symbol-type of the noun] symbol against [the second noun]";
instead say ". The symbol does not discharge; it seems that obsidian is not quite enough like glass."
The initial appearance of the sh-aura-imit-alt is "[if the atmosphere of the location is fire-atm]You see a sheet of paper lying in a niche where the fire is not so intense. Even so, the paper is singed and smoking[else]A singed sheet of paper has survived[end if]."
Section - Antechamber
The Antechamber is a recallable room.
The zone is chancel-pre2-zone.
The description is "The high officers presumably wait here and prepare themselves for the solemn rituals of the Chancel. That august space is to the north, through a sturdy circular gate, which is [open-closed ante-door].[para]The antechamber itself has nothing in particular to offer. The obsidian door to the west is [open-closed obsidian-door]. A narrow hallway runs south, but a fracture blocks it."
The can't-go is "The obsidian door is west, the Chancel gate is north; a blocked hallway runs south."
Check going inside in the Antechamber:
instead try going north.
Check going outside in the Antechamber:
instead try going west.
Check going south in the Antechamber:
instead try entering the ante-fracture.
The ante-door is a lockable metallic scenery door. The printed name is "circular gate".
The pull-side is Antechamber.
The refer-name is "Chancel gate".
The ante-door can be ever-tried. [resettable]
The description is "This gate is formidible[if ante-door is closed], and forbiddingly shut[else], but it now stands open[end if]. Straight metal bars are set into a circular frame[if ante-door is closed]. A psychic numbness radiates from the gate; you can sense it even without coming near[end if][if the location is the Antechamber].[para]On the other side of the gate is the Chancel -- a modest-sized chamber with an ornate ritual bound. Its north wall, opposite you, is the ornamented writ screen[end if]."
Understand "circular", "gate", "bars", "frame", "formidible", "sturdy" as the ante-door.
Understand "chancel" as the ante-door when the location is the Antechamber.
The Antechamber is south of the ante-door. The Chancel is north of the ante-door.
Check searching the ante-door:
if the location is the Antechamber:
instead say "You look [if the ante-door is closed]between the bars, being careful not to touch them[else]through the open gate[end if]. The Chancel is a modest-sized chamber with an ornate ritual bound. Its north wall, opposite you, is the ornamented writ screen.";
else:
instead say "You can see the antechamber on the other side of the gate.";
To say the ante-door explanation:
if the ante-door is not ever-tried:
now the ante-door is ever-tried;
mark ante-door-fact as known;
say ".[para]This gate has a psychic security stricture[if bird-door-fact is known] as well. It feels even tighter than the one on the Birdhouse[end if]".
To decide whether ante-door-protected:
if the aura-mod-type is imitation-symbol and aura-mod-persona is high-rank:
decide yes;
decide no.
Check closing the open ante-door:
instead say "You had enough trouble opening the gate. You're not going to shut it again."
Check opening the closed ante-door:
[Handle successes...]
if the aura-mod-type is imitation-symbol and aura-mod-persona is high-rank:
say "The bars are solid in your fingers now, although your hand feels like part of someone else's body.";
now the aura-mod-time is one;
mark the g-ante-door as done;
now the ante-door is ever-tried;
mark aura-imitation-persona-charge as done;
now the persona of aura-imitation-persona-charge is aura-mod-persona;
continue the action;
if the aura-mod-type is imitation-symbol:
say "You reach for the bars, but your fingers go numb and slide away";
say ". Your aura must still not be passing muster";
instead say ".";
if ante-door-protected:
instead say "(BUG) ante-door-protected case not handled!";
[Handle auto-solutions...]
if g-ante-door is ever-done and the aura-mod-type is no-symbol:
instead goal-perform g-ante-door;
say "You reach for the bars, but your fingers go numb and slide away";
if the aura-mod-type is invisibility-symbol:
now the ante-door is ever-tried;
say ". Apparently, psychic nonexistence does not impress the defensive stricture";
say the ante-door explanation;
instead say "."
Report opening the ante-door:
instead say "You [if in Chancel]shove[else]yank[end if] the bars. The gate swings open without fuss."
Check touching the ante-door when not ante-door-protected:
say "Your fingers slide numbly away from the bars";
say the ante-door explanation;
instead say "."
Check rubbing the ante-door when not ante-door-protected:
instead try touching the ante-door.
Check waving the ante-door when not ante-door-protected:
instead try touching the ante-door.
Check shaking the ante-door when not ante-door-protected:
instead try touching the ante-door.
Check inspecting the ante-door with the oculus:
instead say "Through the oculus, you can see the security stricture. It looks like a haze of translucent needles surrounding the gate."
The ante-fracture is a fracture in the Antechamber.
The description is "A fracture blocks the hallway south of here."
Definition: a paper-sheet is antechamber-sheet-pair if it is sh-antechamber-1 or it is sh-antechamber-2.
Rule for writing a paragraph about a antechamber-sheet-pair paper-sheet:
if sh-antechamber-1 is in the location and sh-antechamber-2 is in the location:
say "Two papers, [a sh-antechamber-1] and [a sh-antechamber-2], are lying here.";
else if sh-antechamber-1 is in the location:
say "[A sh-antechamber-1] of paper is lying here.";
else if sh-antechamber-2 is in the location:
say "[A sh-antechamber-2] of paper is lying here."
Section - Chancel
The Chancel is a recallable room.
Understand "chamber" as the Chancel.
The zone is chancel-zone.
The description is "The Nave may be the heart of the [Retort], but the Chancel is its soul. The Master Rector performs the marcher's most crucial rituals here. The ritual bound is a low pedestal of chased rutilum, with a shelf beside it.[para]The rest of the room is rather emptier than it looked from outside. To the north is the writ screen, and the Nave beyond it. To the south, the circular gate stands [open-closed ante-door]."
The can't-go is "The only exit is south."
For room-visiting the Chancel:
mark chancel-ritual-location as done.
Check going outside in the Chancel:
instead try going south.
Check going north in the Chancel:
instead try entering the writ-screen.
The chancel-bench is a metallic prominent-scenery chancel-bound-level ritual-bound in the Chancel. The printed name is "rutilum bound".
The short-adjective is "rutilum bound".
The description is "The pedestal is an octagonal rutilum plate, several feet wide, engraved with a ritual bound. A flat rutilum crescent projects to the side, forming a gestalt shelf."
Understand "rutilum", "pedestal", "octagon", "octagonal", "plate", "chased" as the chancel-bench.
Rule for writing a paragraph about the chancel-bench:
if the chancel-bench is empty-inactive:
now the chancel-bench is mentioned;
stop;
say the visible state of the chancel-bench.
The chancel-shelf is a ritual-shelf in the Chancel.
The description is "A crescent shelf extends to one side of the pedestal[if the chancel-shelf is empty]. The gestalt shelf is empty[end if]."
The linked-shelf of the chancel-bench is the chancel-shelf.
Understand "flat", "rutilum", "crescent" as the chancel-shelf.
The nave-view is a far-sight in the Chancel. The printed name is "Nave".
The description is "The Nave is visible on the other side of the writ screen. It looks just as you left it, murals and [if initial-marriage is false]black marks[else]crack[end if] and all."
Understand "nave" as the nave-view.
The reach-reason is "The Nave is on the other side of the writ screen."
Check entering the nave-view:
instead try entering the writ-screen.
Check inspecting the nave-view with the oculus:
instead try inspecting the writ-screen with the second noun.
Check inspecting the nave-view with the planetary-lens:
instead try inspecting the writ-screen with the second noun.
The initial appearance of the sh-chancel is "A crisp sheet of paper is pinned next to the screen.[first time][para][sarge]So you've made it to the center of the universe. Good job -- if you know what you need to do here.[/sarge][only]".
Chapter - Basement
Section - Bottom of Stairs
The Basement is a recallable room. The printed name is "Grand Stair, Bottom". The refer-name is "the Bottom of the Grand Stair". The refer-preposition is "at".
The zone is basement-zone.
The description is "This basement is bare, square, and dank. It has, as far as you are aware, no function whatsoever. (Perhaps every house needs a basement, but the Navy does not stoop to clutter.)[para]The walls are tile; they arch up to join the grand staircase as it ascends to the main levels. The Barosy lies to the east, through a narrow iron gate[if the baros-door is locked] with a brass lock[else if the baros-door is closed], closed but unlocked[else], which stands open[end if]. An irregular gap in the south wall opens out into a larger, darker space."
Understand "cellar", "grand", "stair", "stairs", "stairway", "staircase", "bottom", "bottom of" as the Basement.
Rule for printing the name of the Basement while asking which do you mean: say "Bottom of the Grand Stair".
The can't-go is "You can go south or up the stairs; the Barosy gate is east."
The aroma-description is "The cellar always smells a bit mildewy, no matter how many times you're assigned to scrub it".
Check going down in the Basement:
instead say "You are at the bottom of the stairs."
Check going outside in the Basement:
instead try going south.
Check going inside in the Basement:
instead try going east.
The basement-script is prominent-scenery alien-script in the Basement.
The description is "More twisting black marks are scrawled across the wall and floor."
The initial appearance is "The chamber has been defaced with more of[if not script-legible] the illegible black marks[else if the resonator-fact is not known] the involuted black marks. They hint at meaning, but... wait[else] the involuted black marks. Something about a circle filled with liquid metal[end if]."
Check examining the basement-script when script-legible:
say "Twisting, involuted strokes of black are scrawled across one wall";
if the resonator-fact is not known:
mark the resonator-fact as known;
say alien-script-understanding about "a vibrating film of quicksilver";
say " The black marks describe the activation of machinery. The mechanism of command is a circular mark on a wall -- like the one you saw outside the [Retort]; but the circle in your mind is filled, or covered, with liquid metal. One concentrates on a sequence of geometric transforms, and the metal resonates in response.";
else:
say ".[para][description of the resonator-fact][br]";
stop the action.
The basement-gap is an open unopenable scenery door. The printed name is "gap".
The description is "[if the location is the Basement]This gap leads to the deepest underground reaches of the [Retort][else]This gap leads back to the basement and the grand stairs[end if]."
Understand "irregular", "gap", "hole", "opening" as the basement-gap.
Understand "dark", "darker", "space" as the basement-gap when the location is the Basement.
The basement-gap is south of the Basement.
Check examining the lamps-backdrop when the zone of the location is basement-zone and the location is the Basement:
instead say "Sophic lanterns are set into the tiles above[lamps-gloss]."
The initial appearance of the ivory-bead is "[one of]Wait, a bit of clutter after all: a pale yellow bead is[or]Your eye is drawn to a pale yellow bead[stopping] lying in a corner."
Section - Barosy
The Barosy is a recallable room.
Understand "chamber" as the Barosy.
The zone is barosy-zone.
The description is "This is a long, dim chamber whose walls are immense stone slabs. It's like a burial chamber[if a dragon is in the Barosy], but with no smell of decay. There is only a sense of weight and time[else] -- an empty one, now that the dragon is gone[end if].[para]The iron gate stands [open-closed baros-door][if baros-door is locked] and locked[end if] to the west. You also see a crevice between two slabs to the north; it looks wide enough to wiggle through."
The can't-go is "You can go north or west."
The aroma-description is "You smell a whiff of [if an active dragon is in the Barosy]magic[else]fading magic[end if]".
Check going outside in the Barosy:
instead try going west.
Check going north from the Barosy:
now the heading of Baros-Crawl is north;
say "You squeeze into the crevice."
The short-description of Baros is "inscribed across the entire end wall of the chamber".
The barosy-slabs are plural-named mineralish scenery in the Barosy. The printed name is "stone slabs".
The description is "The walls and roof are colossal slabs of stone -- time-worn, yet closely fit. (Although there's a crevice to the north.) You're not sure what kind of stone they are. Perhaps they're only the idea of stone."
Understand "stone", "slab", "slabs", "wall", "walls", "roof", "immense", "crevice" as the barosy-slabs.
The lens-view is "the deep Earth".
Check taking the barosy-slabs:
instead say "They're not portable at all."
Check entering the barosy-slabs:
instead try going north.
Check repairing the barosy-slabs:
instead say "You don't know any way to repair the crevice."
Check inserting something into the barosy-slabs:
instead say "Just enter the crevice and drop [the noun]."
Check reading the barosy-slabs when a dragon (called D) is in the Barosy:
instead try examining D.
Check inspecting the barosy-slabs with the oculus:
instead say "Through the oculus, the stone slabs look like the roots of mountains."
The baros-door is a metallic lockable scenery door. The printed name is "iron gate".
The opening-goal is g-baros-door.
The pull-side is the Basement.
The refer-name is "Barosy gate".
The matching key of the baros-door is the baros-key.
Understand "iron", "gate", "wrought", "door", "narrow", "heavy", "bar", "bars", "frame", "brass", "lock" as the baros-door.
Understand "barosy" as the baros-door when the location is the Basement.
The baros-door is east of the Basement. The baros-door is west of the Barosy.
The lens-view of the baros-door is "Mars, tinted with the deep Earth".
Check examining the baros-door:
say "The gate is tall and narrow, with heavy bars of wrought iron in an iron frame";
say "[first time]. It's always reminded you uncomfortably of a cemetary's side entrance[only]";
if the baros-door is locked:
say ". The gate is shut, and the heavy brass lock is locked";
else if the baros-door is closed:
say ". The gate is standing shut";
else:
say ". The gate gapes open";
if the Barosy is unvisited:
say ".[para]You've never been inside; the room beyond looks like a bare stone tomb";
instead say "."
Check searching the baros-door:
if the baros-door is closed:
say "You peer between the bars. ";
if the location is the Barosy:
instead say "You see the stairway outside.";
else:
instead say "Beyond the gate is the Barosy, the nest of one of the [Retort]'s four dragons[if the Barosy is unvisited]. You've never been inside[end if]. The angle of the gate doesn't give you much of a view; you can see only a low chamber, walled and roofed with heavy slabs of stone."
Check pushing the baros-door when the baros-door is locked and the location is the Basement:
instead say "You rattle the gate against its lock."
Check pulling the baros-door when the baros-door is locked and the location is the Barosy:
instead say "You rattle the gate against its lock."
Check tapping the brass-pin on the baros-door when the symbol-type of the brass-pin is some-saturation-symbol:
say "You carefully lay the [symbol-type of the brass-pin] symbol against the brass lock";
uninscribe the brass-pin;
instead say ". The symbol discharges with a faint pop. The brass of the lock was quite clean, however, so it does not get noticeably cleaner."
Check tapping the steel-bolt on the baros-door when the symbol-type of the steel-bolt is gensaturation-symbol:
say "You carefully lay the [symbol-type of the steel-bolt] symbol against the brass lock";
uninscribe the steel-bolt;
instead say ". The symbol discharges with a faint pop. The brass of the lock was quite clean, however, so it does not get noticeably cleaner."
Check going when the door gone through is the baros-door and the baros-door is locked and the player carries the baros-key:
say "(first unlocking and opening [the baros-door], with [the baros-key])[command clarification break]";
silently try unlocking the baros-door with the baros-key;
if the baros-door is locked:
stop the action;
silently try opening the baros-door;
if the baros-door is closed:
stop the action.
Check opening the baros-door when the baros-door is locked and the player carries the baros-key:
say "(first unlocking [the baros-door] with [the baros-key])[command clarification break]";
silently try unlocking the baros-door with the baros-key;
if the baros-door is locked:
stop the action.
Check opening the baros-door when the baros-door is locked:
if g-baros-door is ever-done:
goal-perform g-baros-door;
if the baros-door is open:
say "You open the gate.";
stop the action.
Report locking the baros-door with the baros-key:
instead say "You lock the brass lock, producing another complicated internal noise."
Report unlocking the baros-door with the baros-key:
instead say "The flint key unlocks the gate's brass lock with a complicated-sounding [em]cha-lunk[/em]."
Carry out unlocking the baros-door with the baros-key:
now the key-used of g-baros-door is the baros-key.
Report topically-applying the clock-tincture to the baros-door:
if the baros-door is unlocked:
instead say "You carefully pour the tincture into the gate's brass lock. Nothing results, however, since the lock is already aligned.";
now the baros-door is unlocked;
now the key-used of g-baros-door is the clock-tincture;
instead say "You carefully pour the tincture into the keyhole. The dark liquid disappears into the brass lock, leaving no trace... but you hear a series of faint clicks and chimes from within the mechanism. After several moments, the lock emits a satisfying [em]click[/em]."
Section - Baros Crawl
The Baros-Crawl is a room. The printed name is "Barosy Crevice".
The zone is barosy-zone.
The description is "You are crawling along a tight passage through the bowels of the Earth. Or some world, at any rate[if the heading of Baros-Crawl is north]. Some light leaks in from the Barosy, behind you, to the south. To the north it only gets darker[else]. Some light leaks in from the Barosy, ahead of you, to the south. Behind you is only darkness[end if].[para][if Baros is not fixed]You feel oddly heavy[else]The gravity feels normal now[end if]."
The Baros-Crawl is not lamp-enabled.
The Baros-Crawl has a direction called the heading. The heading of Baros-Crawl is usually north.
The Baros-Crawl is north of the Barosy.
The can't-go is "The crack runs north and south."
Check going south from the Baros-Crawl:
say "You [if the heading of the Baros-Crawl is north]back up and emerge into[else]emerge, with some relief, into[end if] the Barosy."
Check going outside in the Baros-Crawl:
instead try going south.
Check going north from the Baros-Crawl:
if Baros is not fixed:
now the heading of the Baros-Crawl is south;
instead say "The sense of weight grows more intense as you move along the crevice. Within a few yards, you feel as if you are carrying a backpack full of bricks.[para]This passage must run through the terrain of a high-gravity land; and Baros is not compensating for it. You turn back before the weight becomes lethal.";
mark g-baros-crawl as done;
say "You push forward until the crevice widens. You see light ahead.";
continue the action.
Check going south from the Maze-Crawl:
if Baros is not fixed:
instead say "The sense of weight grows more intense as you move along the crevice. Within a few yards, you feel as if you are carrying a backpack full of bricks.[para]This passage must run through the terrain of a high-gravity land; and Baros is not compensating for it. You turn back before the weight becomes lethal.";
mark g-baros-crawl as done;
now the heading of the Baros-Crawl is south;
say "The crevice grows narrower as you advance. But you eventually see light ahead.";
continue the action.
The Maze-Crawl is north of the Baros-Crawl.
Check jumping in the Baros-Crawl:
say "There's not really enough room";
if Baros is not fixed:
say ". But you have the sense that you couldn't jump very high";
instead say "."
Chapter - Chasm and Beyond
Section - Chasm North
The Chasm-N is a recallable room. The printed name is "Edge of Chasm". The refer-preposition is "at".
The zone is basement-zone.
The description is "You stand on a broad stone walk, a ledge on the eastern wall of a vast canyon. You are underground; the roof is an arch of stone above you, barely visible. The bottom of the abyss is lost in utter darkness.[para]The chasm runs north and south, out of sight. The ledge follows it south, but to the north it ends abruptly in a wall of stone. A gap in the wall leads north to the basement. Another passage squirms into the rock to the east.[first time][para][sarge]Boldly into the unknown,[/sarge] you think, [sarge]even if it's the unknown reaches of my own marcher.[/sarge][para][sarge]It's a start, kid.[/sarge][only]".
Understand "chasm", "edge", "edge of" as Chasm-N.
The Chasm-N is south of the basement-gap.
Rule for printing the name of the Chasm-N while asking which do you mean: say "Chasm Edge".
The can't-go is "You can go north, south, or east."
The aroma-description is "It smells of forgotten stone".
Check going west in Chasm-N:
instead say "Only if you want to jump in."
Check going northwest in Chasm-N:
instead try going west.
Check going southwest in Chasm-N:
instead try going west.
Check going down in Chasm-N:
instead try going west.
Check going south from Chasm-N when Baros is not fixed:
say "The rock feels oddly unsteady underfoot."
The chasm-sect-n is a chasm-section in Chasm-N.
The chasm-roof-n is a far-sight in Chasm-N. The printed name is "broken bridge".
The description is "You trace the canyon wall rising above you, up to the vault of stone that hangs over the abyss. A stub of a bridge is visible there. It must once have crossed the chasm at a level high overhead. Now the span has fallen away."
Understand "roof", "arch", "vault", "ceiling", "bridge", "stub", "broken", "span" as the chasm-roof-n.
The chasm-n-passage is scenery in Chasm-N. The printed name is "narrow passage".
The description is "A narrow passage winds back into the canyon wall to the east."
Understand "narrow", "passage" as the chasm-n-passage.
Check entering chasm-n-passage:
instead try going east.
Section - Chasm Middle
The Chasm-Slab is a room. The printed name is "Chasm Rubble". The refer-preposition is "at".
The zone is basement-zone.
The description is "Rubble and fallen rocks litter the ledge here. You can walk north or south alongside the abyss, which waits patiently to the west[if Baros is not fixed]. But you have an unnerving sense of vertigo. The world seems to sway around you[end if]."
The Chasm-Slab is south of the Chasm-N.
The can't-go is "You can follow the ledge north or south."
The aroma-description is "It smells of forgotten stone".
Check going west in Chasm-Slab:
instead say "Only if you want to jump in."
Check going northwest in Chasm-Slab:
instead try going west.
Check going southwest in Chasm-Slab:
instead try going west.
Check going down in Chasm-Slab:
instead try going west.
Check going east in Chasm-Slab:
instead say "The canyon wall to the east is a sheer rock face. It rises unbroken to the roof far above."
Check going north from Chasm-Slab when Baros is not fixed:
say "The feeling of vertigo subsides."
Check going south from Chasm-Slab when Baros is not fixed:
say "The ledge seems to sway under your feet, worse and worse as you proceed."
Check jumping in Chasm-Slab when Baros is not fixed:
instead say "You jump up and down. Something is definitely off-kilter about the gravity here."
The chasm-sect-m is a chasm-section in Chasm-Slab.
The description is "The chasm runs alongside this path, directly to the west[if the tilt-slab is in Chasm-Slab]. The slab hangs out over its depths[else]. Its depths are unfathomable[end if]."
The chasm-roof-m is a far-sight in Chasm-Slab. The printed name is "broken bridge".
The description is "You trace the canyon wall rising above you, up to the vault of stone that hangs over the abyss. A stub of a bridge is visible there. It must once have crossed the chasm at a level high overhead. Now the span has fallen away -- no doubt the source of the rubble."
Understand "roof", "arch", "vault", "ceiling", "bridge", "stub", "broken", "span" as the chasm-roof-m.
The chasm-rubble is scenery in Chasm-Slab. The printed name is "rubble".
The description is "Just nondescript rock."
Understand "rubble", "rocks", "debris", "fallen" as the chasm-rubble.
Check taking the chasm-rubble:
instead say "The fallen rocks are either too big to move, or too small to bother with."
Check pushing the chasm-rubble:
instead try taking the chasm-rubble.
Check repairing the chasm-rubble:
instead say "Not a chance."
The tilt-slab is a scenery prominent-scenery supporter in Chasm-Slab. The printed name is "slab".
The tilt-slab has a number called the try-counter. [Only meaningful when the chime is out there.]
Understand "slab", "stone", "rock", "massive", "near", "end" as the tilt-slab.
The lens-view is "the Earth".
Rule for writing a paragraph about the tilt-slab:
say "A particularly massive slab lies at the chasm edge. Half its length rests on [if Baros is not fixed]solid(-ish)[else]solid[end if] ground; but the far half hangs out over empty space, quite unsupported.";
unless the tilt-slab is totally-empty:
say line break;
recite the tilt-slab contents;
stop the action.
To decide whether the tilt-slab is totally-empty:
if the F-sharp-chime is part of the tilt-slab:
decide no;
if something is on the tilt-slab:
decide no;
decide yes.
To recite the tilt-slab contents:
let N be the number of things on the tilt-slab;
if the F-sharp-chime is part of the tilt-slab:
say "You see a bronze chime lying on the far end of the slab";
now the F-sharp-chime is mentioned;
now the F-sharp-chime is ever-seen;
if N is 1:
let T be the first thing held by the tilt-slab;
say ". On the near end, and much more easily reached, is [a T roomily]";
else if N > 1:
say ". On the near end, and much more easily reached, are [a list of things *in the tilt-slab roomily]";
else:
say ". It looks very far away";
if Baros is not fixed:
say "; the idea of crawling out there makes you feel even more unsteady than before";
else:
if N is 1:
let T be the first thing held by the tilt-slab;
say "[A T roomily] rests on the near end of the slab";
else if N > 1:
say "[A list of things *in the tilt-slab roomily] rest on the near end of the slab";
say "."
Check examining the tilt-slab:
say "The slab is at least fifteen feet long, and more than a foot thick. The upper surface is worked flat; it must have been part of a bridge or balcony, somewhere above you, before the catastrophe. Now it lies precariously balanced on the edge of the chasm.";
unless the tilt-slab is totally-empty:
say line break;
recite the tilt-slab contents;
stop the action.
Check searching the tilt-slab:
unless the tilt-slab is totally-empty:
recite the tilt-slab contents;
else:
say "Nothing is on the slab.";
stop the action.
Report putting something on the tilt-slab:
instead say "You put [the noun] on the near end of the slab, where it won't unbalance anything."
Check taking the tilt-slab:
instead say "It's a chunk of stone fifteen feet long. You're not picking it up."
Check repairing the tilt-slab:
instead say "A crew of engineers with a crane would be hard-pressed to repair whatever the slab once was."
Check blowing on the tilt-slab:
instead say "It's not [em]that[/em] precarious."
Check pulling the tilt-slab:
if the counterweight is on the tilt-slab and the symbol-type of the counterweight is not gossamerity-symbol:
instead say "You grasp the edge of the slab and heave. However, the lead weight pins it in place; the slab is immovable.";
instead say "You try to pull the slab to a steadier position. It weighs far too much, however[one of][or]. Your efforts nearly unbalance the thing entirely, and you hastily desist[cycling]."
Check turning the tilt-slab:
instead try pulling the tilt-slab.
Check freeing the tilt-slab:
instead try pushing the tilt-slab.
Check shaking the tilt-slab:
instead try pushing the tilt-slab.
Check waving the tilt-slab:
instead try pushing the tilt-slab.
Check pushing the tilt-slab:
if the counterweight is on the tilt-slab and the symbol-type of the counterweight is not gossamerity-symbol:
instead say "You grasp the edge of the slab and heave. However, the lead weight pins it in place; the slab is immovable.";
say "You grasp the edge of the slab and heave. The thing must weigh tons, but it's so delicately balanced that you manage to lift your end.[para]Unfortunately, once you do, the slab is no longer delicately balanced. Over the edge it goes";
let N be the number of things on the tilt-slab;
if the F-sharp-chime is part of the tilt-slab:
now the F-sharp-chime is off-stage;
retire the F-sharp-chime by chasm-plummeting;
say ". The chime flies off and disappears into the abyss";
if N is 1:
let T be the first thing held by the tilt-slab;
say ", along with [the T]";
else if N > 1:
say ", along with everything else on the slab";
say ". The slab itself follows";
else if N is 1:
let T be the first thing held by the tilt-slab;
say ". [The T] flies off and disappears into the abyss; the slab itself follows";
else if N > 1:
say ". Everything on the slab flies off and disappears into the abyss; the slab itself follows";
else:
say ", and it disappears into the abyss";
while something (called T) is on the tilt-slab:
retire T by chasm-plummeting;
now the tilt-slab is off-stage;
instead say ".[para]You wait long moments for any further sound from below. There is none."
Check climbing the tilt-slab:
instead try entering the tilt-slab.
Check inserting the tilt-slab into a chasm-section:
instead try pushing the tilt-slab.
Check entering the tilt-slab:
if the F-sharp-chime is part of the tilt-slab:
instead try taking the F-sharp-chime;
if the counterweight is on the tilt-slab and the symbol-type of the counterweight is not gossamerity-symbol:
instead say "Even though the slab is held in place, you don't have a reason to go jumping on it.";
instead say "You no longer have any reason to trust the slab's balance with your life."
The slab F-sharp-taking-part rule is listed before the generic F-sharp-taking-part rule in the check taking rulebook.
Check taking the F-sharp-chime when the noun is part of the tilt-slab (this is the slab F-sharp-taking-part rule):
[Permit the raw "take chime" to proceed if the puzzle solution is unset, or if the player has manually half-done it.]
if g-tilt-slab is ever-done and the tool-used of g-tilt-slab is not no-thing and the counterweight is not on the tilt-slab:
goal-perform g-tilt-slab;
stop the action;
if the counterweight is on the tilt-slab and the symbol-type of the counterweight is not gossamerity-symbol:
now the player carries the F-sharp-chime;
mark g-tilt-slab as done;
now the tool-used of g-tilt-slab is the counterweight;
instead say "You step out onto the slab, and kneel at the balance-point. The counterweight seems to be holding it steady, so you slowly stretch forward...[para]You are keenly aware of the empty abyss directly below you. But as you crawl forward, the slab does not shift. You keep your movements steady, and after what seems like hours, your fingers meet bronze.[para]You grasp the chime, crawl backwards, and roll off the slab onto solid ground. Whew.";
if the counterweight is on the tilt-slab and the symbol-type of the counterweight is gossamerity-symbol:
instead say "You step out on the slab, and kneel at the balance-point. Unfortunately, the lessened mass of the counterweight is insufficient to anchor things. You can get a few inches closer to the chime; but it's not enough.";
increment the try-counter of the tilt-slab;
if the try-counter of the tilt-slab is:
-- 1: instead say "You step out on the slab, and kneel at the balance-point. But when you lean forward, the entire thing shifts under your weight. You pull yourself back before the slab completely unbalances.";
-- 2: instead say "No matter how carefully you stretch forward, the slab starts to tilt before you're anywhere near the chime.";
-- otherwise:
now the F-sharp-chime is off-stage;
retire the F-sharp-chime by chasm-plummeting;
instead say "You try once more, stretched out full-length on the slab, creeping forward an inch at a time. The end dips sickeningly; and this time, the chime rolls off and vanishes silently into the chasm below.[para]Well, that's it. You crawl backwards and roll off the slab onto solid ground.";
instead say "(BUG) Uncovered tilt-slab case."
Check getting off the tilt-slab:
if the try-counter of the tilt-slab is not zero:
instead say "You got off the slab as quickly as possible, after that last time.";
instead say "You're not currently on the slab."
Rule for implicitly taking the F-sharp-chime when the F-sharp-chime is part of the tilt-slab:
[I think this is always pre-empted by the reaching-component rule, but we'll include it just in case.]
instead say "The chime is out at the far end of the slab. Taking it won't be easy."
Reaching component rule for the tilt-slab:
if taking:
allow access; [we'll catch the action in "check taking"]
say "The chime is out at the far end of the slab.";
deny access.
Magnetization rule when the item described is the F-sharp-chime and the item described is part of the tilt-slab:
say "[The item described] vibrates in response. It rolls across the slab and leaps into your hand.";
mark g-tilt-slab as done;
now the tool-used of g-tilt-slab is the B-chime;
rule succeeds.
Section - Chasm South
The Chasm-S is a room. The printed name is "Chasm, at Bridge". The refer-name is "the Chasm at the Bridge". The refer-preposition is "at".
The zone is basement-zone.
The description is "The ledge is narrower here; to the south it ends abruptly. To the east you see the entrance to the deep library -- a [if deep-door is locked]padlocked[else if deep-door is closed]closed[else]open[end if] wooden door set into the canyon wall. To the west, a naked stone span bridges the canyon[chasm-s-gravity]."
The Chasm-S is south of the Chasm-Slab.
To say chasm-s-gravity:
if Baros is not fixed:
say ".[para]Vertigo assails you[one of]. What's going on here? Something must be wrong with the dragon Baros; that's what's supposed to keep gravity stable in the [Retort][or]. Something is badly wrong with the gravity here[stopping]";
else:
if Chasm-Bridge is not visited:
say ".[para]The area seems stable now";
The can't-go is "The ledge runs north, the bridge is west, and the door is east."
The aroma-description is "It smells of forgotten stone".
Check going west from Chasm-S:
if Baros is not fixed:
say "The waves of vertigo grow more intense as you stumble towards the bridge";
if bridge-end-west is not ever-tried:
say ". The span itself seems to wobble, although you know it is just the unstable gravity throwing you back and forth.[para]This is a bad idea";
now bridge-end-west is ever-tried;
instead say ". You don't think you could get even halfway across, at this rate.";
continue the action.
Check going inside in the Chasm-S:
instead try going east.
Check going south in Chasm-S:
instead say "The ledge path ends here. You can return north, or try the bridge or the door."
Check going down in Chasm-S:
instead say "Only if you want to jump in."
Check going north from Chasm-S when Baros is not fixed:
say "The world becomes somewhat steadier."
Check jumping in Chasm-S when Baros is not fixed:
instead say "You jump up and down, and nearly fall flat on your arse."
The chasm-sect-s is a chasm-section in Chasm-S.
The description is "The chasm runs alongside this path. Directly to the west, a stone bridge arcs over the depths[if Baros is not fixed]. But you're not sure you want to chance it in these conditions[end if]."
The chasm-roof-s is a far-sight in Chasm-S. The printed name is "roof".
The description is "You trace the canyon wall rising above you, up to the vault of stone that hangs over the abyss."
Understand "roof", "arch", "vault", "ceiling" as the chasm-roof-s.
The bridge-end-west is scenery in Chasm-S. The printed name is "bridge".
The bridge-end-west can be ever-tried. [resettable]
The description is "The bridge is a plain span of stone, a yard wide and a yard deep. It crosses the canyon in a gentle arc[if Baros is not fixed]. It would be almost inviting, if the world weren't tilting vertiginously around you. Or if the bridge had handrails[else] -- not too bad, except for the lack of handrails[end if]."
Understand "bridge", "span", "plain", "naked", "stone" as bridge-end-west.
The lens-view is "the Earth".
Check entering bridge-end-west:
instead try going west.
Check climbing bridge-end-west:
instead try going west.
Section - Deep Stacks
The Deep-Stacks is a recallable room. The printed name is "Deep Stacks".
The zone is deep-stacks-zone.
The description is "The tomes in these stacks are little-regarded treasures, or so the librarians tell you. For certain, though, a marcher never discards a book. The shelves are overstuffed.[para]The room is unfurnished; you see books and nothing beside. The only door is west. However, the south wall is split by a bulging yellow intrusion."
Understand "deep", "stack", "stacks" as the Deep-Stacks.
The can't-go is "The door is west."
The aroma-description is "You smell dust and garlic".
Check going outside in the Deep-Stacks:
instead try going west.
Check going south in the Deep-Stacks:
instead try entering the coral-crack.
Check jumping in Deep-Stacks when Baros is not fixed:
instead say "You jump up and down. The gravity in here is better, but still off-true."
The coral-crack is scenery in the Deep-Stacks. The printed name is "crevice".
The description is "The yellow coral growth bulges in through a crack in the south wall. The crevice is entirely blocked by the growth; you cannot see what world lies on the other side."
Understand "crack", "crevice", "split" as the coral-crack.
Check searching the coral-crack:
instead try examining the coral-crack.
Check entering the coral-crack:
instead say "The crevice is entirely blocked by the growth[if the coral-outcrop is clean]. You would need barrels of potion to dissolve your way through[end if]."
Check repairing the coral-crack:
instead say "You can't."
The coral-outcrop is a scenery thing in the Deep-Stacks. The printed name is "coral outcrop".
The description is "A bulbous yellow outcrop bulges in through a crevice in the south wall. The growth looks more like undersea coral than anything else. But it must have originated in some other world, perhaps a Thalassan land.[para][if dirty]You notice something poking out from underneath the outcrop -- the corner of a bit of paper, trapped between the coral and the floor[else]A large crater has been eaten into the outcrop[end if]."
The lens-view is "some planet you don't recognize".
The coral-outcrop can be shifted. [bit fell off; resettable]
The coral-outcrop can be clean or dirty. The coral-outcrop is dirty. [paper stuck under; resettable]
Understand "coral", "outcrop", "outcropping", "intrusion", "bulbous", "bulge", "bulging", "yellow", "growth", "growths" as the coral-outcrop.
Understand "corner", "bit", "bit of", "paper" as the coral-outcrop when the coral-outcrop is dirty.
Understand "crater" as the coral-outcrop when the coral-outcrop is clean.
Check searching the dirty coral-outcrop:
instead say "You can only see a corner of the paper -- not enough to make out what's written on it."
Check looking under the coral-outcrop:
instead try searching the coral-outcrop.
Check eating the coral-outcrop:
instead say "Wherever it sprouted from, it can't be nourishing for people."
Check tasting the coral-outcrop:
instead say "It tastes faintly garlicky."
Check smelling the coral-outcrop:
instead say "It smells faintly garlicky."
Check taking the coral-outcrop:
if the coral-outcrop is not shifted:
now the coral-outcrop is shifted;
now the player carries the coral;
set pronouns from the coral;
instead say "You try to dig your fingers into the yellow coral. A small chunk comes away in your hand.";
else:
instead say "You are unable to wreak any more damage on the outcrop."
Check pulling the coral-outcrop:
instead try taking the coral-outcrop.
Check pushing the coral-outcrop:
instead try taking the coral-outcrop.
Check smashing the coral-outcrop:
instead try taking the coral-outcrop.
Check attacking the coral-outcrop:
instead try taking the coral-outcrop.
Check freeing the coral-outcrop:
instead try taking the coral-outcrop.
Check rubbing the coral-outcrop:
instead try taking the coral-outcrop.
Check shaking the coral-outcrop:
instead try taking the coral-outcrop.
Check touching the coral-outcrop:
instead say "The yellow outcrop is stiff to the touch."
Report topically-applying the coralicide to the coral-outcrop:
say "You splash the coralicide onto the outcrop";
if the coral-outcrop is clean:
instead say ". It shrinks back a bit more.";
now the coral-outcrop is clean;
now the coral-outcrop is shifted;
now the sh-deep-stacks-3 is in the Deep-Stacks; [Gaian-precip-creation]
instead say ". The yellow growth bubbles, pits, and shrivels.[para]You don't have enough potion to completely destroy the outcrop. But you manage to dissolve enough of a hole to free what was poking out: a stained sheet of paper."
Report topically-applying the fungicide to the coral-outcrop:
instead say "You carefully drip the fungicide over the coral outcrop. Purple fumes billow up, but the coral doesn't seem to be affected. It must not be related to the fungi you know.";
Check putting a charged bubble on the coral-outcrop:
instead try tapping the noun on the coral-outcrop.
Check tapping a charged bubble on the coral-outcrop:
now the noun is uncharged;
instead say "You hold the dusty bubble over the outcrop and twist the valve.[para]The coral bleaches slightly in the stream of elemental air, but it is otherwise unaffected. Strange. If you ever get out of this mess, you'll have to report that to the Life Studies crowd."
Check putting a nontopical chem-source on the coral-outcrop:
instead say "You sprinkle some [short-description of noun] onto the outcrop, but it doesn't affect the coral at all."
Check tapping a nontopical chem-source on the coral-outcrop:
instead say "You sprinkle some [short-description of noun] onto the outcrop, but it doesn't affect the coral at all."
The deep-books are plural-named readable scenery in the Deep-Stacks. The printed name is "books".
The deep-books have a number called the current-count.
Understand "book", "books", "tome", "tomes", "rows", "rows of", "stuffed", "overstuffed", "shelf", "shelves", "stack", "stacks" as the deep-books.
Check examining the deep-books:
increment the current-count of deep-books;
if the current-count of deep-books is:
-- 1: instead say "You pick up a book at random. The pages are blank.";
-- 2: instead say "This book is also blank.";
-- 3: instead say "Blank again. You have no idea what's going on.";
-- 4:
now the current-count of deep-books is 1;
instead say "Apparently every book in this chamber is blank."
Check searching the deep-books:
instead try examining the deep-books.
Check taking the deep-books:
instead try examining the deep-books.
Check opening the deep-books:
instead try examining the deep-books.
Check entering the deep-books:
instead say "Getting lost in a book is an idiom."
Check smelling the deep-books:
instead try smelling the location.
Check inspecting the deep-books with the oculus:
instead say "Through the oculus, the books are a great mass of information. Not a collection of works, oddly, but a single indistinct mass."
The deep-door is a lockable scenery door. The printed name is "pine door".
The opening-goal is g-deep-door.
The pull-side is Chasm-S.
The refer-name is "Deep Stacks door".
Understand "pine", "wood", "wooden", "door", "deep" as the deep-door.
Understand "stack", "stacks", "library" as the deep-door when the location is the Chasm-S.
Understand "padlock", "padlocked", "lock" as the deep-door when the deep-door is locked.
The Deep-Stacks is east of the deep-door. The Chasm-S is west of the deep-door.
Check examining the deep-door:
say "The door is heavy pine, rather rougher than the doors in the rest of the [Retort]";
if the deep-door is locked:
say ". Someone has locked it with a Venture File padlock, which is a violation of six different regulations on library use";
else:
if the deep-door is closed:
say ". The Venture File lock is unlocked, but the door is still closed";
else:
say ". It is standing open";
instead say "."
Check putting a metal-seal on the deep-door:
instead try unlocking the deep-door with the noun.
Check tapping a metal-seal on the deep-door:
instead try unlocking the deep-door with the noun.
Check inspecting the deep-door with the oculus:
instead say "Through the oculus, you perceive the symbolism of the Venture File: [symbol-assoc of venture-file]."
Check unlocking the deep-door with a clay-mold:
instead say "An inverse impression of a seal isn't the same as a seal."
Report unlocking the deep-door with:
now g-deep-door is ever-done;
instead say "You touch [the second noun] to the door, and the lock pops open."
Report locking the deep-door with:
instead say "You lock the door again, using [the second noun]."
Lock-matching rule for the deep-door when key-param is a metal-seal:
if the file of key-param is venture-file:
rule succeeds;
else:
rule fails.
Definition: a metal-seal is venture-file-matching if the file of it is venture-file.
Check going when the door gone through is the deep-door and the deep-door is locked and the player carries an venture-file-matching metal-seal (called T):
say "(first unlocking and opening [the deep-door], with [the T])[command clarification break]";
silently try unlocking the deep-door with the T;
if the deep-door is locked:
stop the action;
silently try opening the deep-door;
if the deep-door is closed:
stop the action.
Check opening the deep-door when the deep-door is locked and the player carries an venture-file-matching metal-seal (called T):
say "(first unlocking [the deep-door] with [the T])[command clarification break]";
silently try unlocking the deep-door with the T;
if the deep-door is locked:
stop the action.
Check opening the deep-door when the deep-door is locked:
if g-deep-door is ever-done:
goal-perform g-deep-door;
if the deep-door is open:
say "You open the door.";
stop the action.
Section - Chasm Bridge
The Chasm-Bridge is a recallable room. The printed name is "Canyon Bridge Span".
The zone is phleg-lab-zone.
The Chasm-Bridge is not lamp-enabled.
The description is "You are standing on a stone bridge that crosses the canyon. The span feels very narrow now. A little light reaches you from lamps along the canyon wall, but none penetrates the depths below.[para]The east end of the bridge debarks at a ledge. The west end dives into a narrow gap which opens directly into the canyon wall."
Understand "canyon", "bridge", "span" as Chasm-Bridge.
The Chasm-Bridge is west of the Chasm-S.
The can't-go is "East or west."
The aroma-description is "A slow draft from below carries the sense of dark water and stone".
Check jumping in Chasm-Bridge:
instead say "Even with stable gravity, you don't have the nerve to jump up and down here."
Check going down in Chasm-Bridge:
instead try entering the chasm-sect-b.
The chasm-sect-b is a chasm-section in Chasm-Bridge.
The description is "The fathomless chasm opens beneath your feet."
Check entering the chasm-sect-b:
instead say "Some wretched remnant of a survival instinct keeps you from diving off the bridge. Silly, at this stage, but there it is."
The chasm-roof-b is a far-sight in Chasm-Bridge. The printed name is "roof".
The description is "A natural stone vault arches over the abyss. You can make out the remnants of walkways and bridges at higher levels, but all appear ruined."
Understand "roof", "arch", "vault", "ceiling", "ruined", "walkway", "walkways", "bridges" as the chasm-roof-b.
The bridge-proxy is scenery in Chasm-Bridge. The printed name is "bridge".
The description is "The bridge is a plain span of stone, a yard wide and a yard deep. It crosses the canyon in a gentle arc, east to west."
Understand "bridge", "span", "plain", "naked", "stone" as bridge-proxy.
The lens-view is "the Earth".
Check entering the bridge-proxy:
instead say "You are standing on the bridge already."
Check getting off the bridge-proxy:
instead try entering the chasm-sect-b.
Section - Deep Lab
The Phleg-Lab is a recallable room. The printed name is "Deep Lab".
The zone is phleg-lab-zone.
The description is "This chamber looks like a natural cavern, squared and smoothed with the crudest of tools. Stalactites hang from the roof; flowstone drips down the walls. An uneven passage runs east.[para]In the center of the chamber is a boulder. It is inscribed with a ritual bound in an archaic, almost crude style. A smaller slab serves as a gestalt shelf."
Understand "deep", "lab", "laboratory" as Phleg-Lab.
The Phleg-Lab is west of the Chasm-Bridge.
The can't-go is "The exit is to the east."
The aroma-description is "Old, wet earth".
Check going outside in the Phleg-Lab:
instead try going east.
The deep-bench is a prominent-scenery ritual-bound in the Phleg-Lab. The printed name is "stony bound".
The short-adjective is "stony bound".
The description is "You recognize a reconstructed Neolithic tradition, designed on principles of Earth-worship."
Understand "stony", "boulder", "archaic", "crude" as the deep-bench.
Rule for writing a paragraph about the deep-bench:
if the deep-bench is empty-inactive:
now the deep-bench is mentioned;
stop;
say the visible state of the deep-bench.
The deep-shelf is a ritual-shelf in the Phleg-Lab.
The description is "A rock slab next to the boulder serves as a gestalt shelf -- the sort that holds symbolically relevant objects during a ritual[if the deep-shelf is empty]. The gestalt shelf is empty[end if]."
The linked-shelf of the deep-bench is the deep-shelf.
Understand "small", "smaller", "rock", "slab" as the deep-shelf.
The phleg-flowstone is scenery in the Phleg-Lab. The printed name is "flowstone".
The description is "You're not sure where this cave originated. Most of the [Retort's] underground zones are basalt, not flowstone cavern.[para]They say that every marcher started with a single room, somewhere on Earth, to which all its other halls and chambers were added. For the [Retort], you wouldn't bet against this room being it."
The lens-view is "the Earth".
Understand "flowstone", "stalactite", "stalagmite", "wall", "walls", "ceiling", "roof" as phleg-flowstone.
Check taking the phleg-flowstone:
instead say "Knocking bits off the walls would ruin the [one of]ambiance.[or]ambiance. (Ambiance is very important for a ritual laboratory.)[stopping]"
Check smashing the phleg-flowstone:
instead try taking the phleg-flowstone.
Check inspecting the phleg-flowstone with the oculus:
instead say "Through the oculus, the flowstone around you is intensely Yin, passive, phlegmatic."
Section - Mineral Maze
The Mineral-Maze is a recallable room. The printed name is "Confusing Cracks".
The zone is basement-zone.
The description is "[Mineral-Maze-desc]".
Understand "confusing", "cracks" as the Mineral-Maze.
The Mineral-Maze is not lamp-enabled.
The Mineral-Maze is east of the Chasm-N.
To say Mineral-Maze-desc:
if Aistheta is not fixed:
say "You are lost in a maze of claustrophic cracks. You've stopped in a fairly wide space, but planes of basalt close in all around you. You could crawl in any imaginable direction; the largest passage heads back west";
else:
say "You are in a wide space within a maze of basalt blocks. Claustrophobic cracks lead in many directions, but the most promising ones run west and east";
say period.
The can't-go is "[Mineral-Maze-can't-go]".
To say Mineral-Maze-can't-go:
if Aistheta is not fixed:
say "You're not sure, except that west is probably out";
if maze-script is in Mineral-Maze:
say ", and the marks run southeast";
else:
if maze-script is in Mineral-Maze:
say "You can go west, east, or southeast";
else:
say "You can go west or east";
say period.
Check going outside in Mineral-Maze:
instead try going west.
Check going up in Mineral-Maze:
instead try going southeast.
Check going in Mineral-Maze when Aistheta is not fixed:
if the noun is southeast and the maze-script is in Mineral-Maze:
say "You follow the trail of script.";
continue the action;
if the noun is west:
say "Fortunately, the large passage leads you out of the maze.";
continue the action;
instead say "You prowl through the twisting passages, but they all seem to lead back to where you started.";
Check going southeast from Mineral-Maze when Aistheta is fixed and the maze-script is not in Mineral-Maze:
instead try going southwest.
Check going east from Mineral-Maze when Aistheta is fixed:
if Mineral-End is not visited:
say "The layout of the passages seems obvious now. You pick your way forward.";
else:
say "You navigate the passages with confidence."
Check going southeast from Mineral-Maze when Aistheta is fixed and the maze-script is in Mineral-Maze:
say "You follow the trail of script."
Check waving the centrality-lodestone in Mineral-Maze:
instead say "You hold the silk cord by one end, and set the stone swinging. It spins in a tight circle, indicating that you are already at the center of this 'maze'. Which is not very helpful."
The maze-walls are plural-named scenery in the Mineral-Maze. The printed name is "basalt walls".
The description is "This space is all dark cracks between blocks of living basalt. Although light must be leaking in from somewhere."
Understand "basalt", "black", "stone", "wall", "walls", "plane", "planes", "block", "blocks", "crack", "cracks" as the maze-walls.
The lens-view is "the Earth".
Check entering the maze-walls:
instead say "You have many choices of direction."
Check climbing the maze-walls:
instead try entering the maze-walls.
Check searching the maze-walls:
instead say "That's the trick, isn't it."
The maze-column is mineralish prominent-scenery in the Mineral-Maze. The printed name is "indigo column".
The description is "A thick column of some indigo mineral hangs down from the ceiling, tapering towards the floor[if maze-script is not in Mineral-Maze]. It's clearly natural, but you're not sure how it could have formed; this is not the domain of flowstone and stalactites. At any rate, it makes a distinctive landmark[else]. Black alien marks curl up the column, across the roof, and into a half-hidden passage to the southeast[end if]."
Understand "violet", "purple", "indigo", "thick", "column", "pillar", "mineral", "stone" as the maze-column.
The lens-view is "the Earth".
The initial appearance of the maze-column is "In the center of this space is a thick column of stone, colored an eye-catching indigo. It runs from floor to ceiling[if maze-script is in Mineral-Maze]. Black alien marks curl up the column, across the roof, and into a half-hidden passage to the southeast[end if]."
Check touching the maze-column:
instead say "The violet mineral is cold and slick."
Check rubbing the maze-column:
instead try touching the maze-column.
Check climbing the maze-column:
instead say "The column is irregular, but not irregular enough to offer handholds."
Check recalling the maze-column when the maze-column-fact is known:
instead say "You recall the vision of the glyph: the polar oil will react if poured over this column."
Report topically-applying the polar-oil to the maze-column:
now the maze-script is in the Mineral-Maze;
instead say "You splash the black oil onto the column. It drips... upward.[para]The fluid flows up the violet stone, clinging in fine inky trails. The marks slowly resolve into the familiar (if you can call it that) alien script, which spirals up the column. The strokes spread across the roof and disappear into a gap to the southeast -- a passage you had not noticed until now."
The maze-script is alien-script.
[Appears when polar-oil is used; resettable]
The description is "A trail of black alien script curls up the column, across the roof, and into a half-hidden passage above you and to the southeast[if script-legible].[para]The marks have meaning now, but you can only see the beginning of the passage[end if]."
Understand "trail", "passage", "gap" as the maze-script.
Check entering the maze-script:
instead try going southeast.
The initial appearance of the basalt-pebble is "A chip of basalt lies here. It must have cracked loose from the walls."
Section - Mineral Dead End Pit
The Mineral-End is a recallable room. The printed name is "Dead End Pit".
The zone is mineral-end-zone.
The description is "You've come to a dead end, a shallow pit of basalt. The only way out is west."
The Mineral-End is not lamp-enabled.
Understand "dead", "end", "pit" as the Mineral-End.
The Mineral-End is east of the Mineral-Maze.
The can't-go is "The exit is west."
Check going outside in Mineral-End:
instead try going west.
Check waving the centrality-lodestone in Mineral-End:
instead say "You hold the silk cord by one end, and set the stone swinging. It tilts sharply to the west."
The initial appearance of the jade is "A pale green bead is lying at the bottom of the pit. It looks like jade."
Section - Mineral Dead End Passage
The Mineral-Nook is a room. The printed name is "Dead End Passage".
The description is "The passage ends here. You can return to the northwest."
The Mineral-Nook is not lamp-enabled.
The Mineral-Nook is southeast of the Mineral-Maze.
The can't-go is "The exit is northwest."
Check going down in Mineral-Nook:
instead try going northwest.
Check going outside in Mineral-Nook:
instead try going northwest.
Check waving the centrality-lodestone in Mineral-Nook:
instead say "You hold the silk cord by one end, and set the stone swinging. It tilts sharply to the northwest."
The nook-script is prominent-scenery alien-script in the Mineral-Nook.
The initial appearance is "The trail of black marks ends here as well, swirling back on itself across the ceiling[if not script-legible][else if the caudex-pattern is not known]. The marks hint at meaning, but... wait[else]. The marks refer to [em]caudex access[/em][end if]."
The description is "Twisting black strokes curve up the passage and wrap themselves into an obscure mandala around the ceiling of the dead end."
Understand "mandala", "trail", "roof", "ceiling" as the nook-script.
Check examining the nook-script when script-legible:
say the description of the nook-script;
if the caudex-pattern is not known:
mark the caudex-pattern as known;
say "[para]You concentrate on the black script, fishing for the echo of meaning. Something about the core... travel to the center, or from the center...[para]Understanding hits like a migraine. You memorize [em]caudex access,[/em] the passage of the spine -- another sequence of geometric transformations.";
else:
say "[para]The pattern means [em]caudex access,[/em] the passage of the spine.";
stop the action.
Section - Chasm Void Room
The Chasm-Void-Room is a reset-room.
The near-room is the Chasm-N. [Or another chasm location, but close enough.]
The description is "The sensation of falling is gone. You are adrift in the void."
Chapter - Outside
The hadean-sky is a backdrop. The printed name is "sky".
The description is "Like most Hadean skies, it is a night of ink and crystal and pitiless stars. A small sun is visible; it shines a clear, heatless white, and does not dim the stars around it."
Understand "hadean", "sky", "star", "stars", "sun", "pitiless", "night", "black" as the hadean-sky.
The lens-view is "a Hadean land".
Instead of doing anything except examining or searching to the hadean-sky:
if inspecting the hadean-sky with something:
continue the action;
instead say "The sky is out of reach."
Check searching the hadean-sky:
instead try examining the hadean-sky.
Check inserting something into the hadean-sky:
instead try touching the hadean-sky.
Check putting something on the hadean-sky:
instead try touching the hadean-sky.
Check tapping something on the hadean-sky:
instead try touching the hadean-sky.
A ground-grey-dust is a kind of thing. The printed name of a ground-grey-dust is usually "grey dust".
A ground-grey-dust is usually scenery.
The description of ground-grey-dust is usually "Hadean dust doesn't lie the way soil does in the fields you know. It's rough, rumpled; marked only by your few footprints."
The lens-view of ground-grey-dust is usually "a Hadean land".
Understand "dust", "hadean", "layer", "layer of", "grey", "gray", "lifeless", "footprints" as a ground-grey-dust.
Check taking ground-grey-dust:
if the grey-dust is off-stage:
now the player carries the grey-dust;
set pronouns from the grey-dust;
instead say "You scrape up a pinch of dust. It's scratchy between your fingers.";
else:
say "You've already taken some dust. You don't need any more.";
if the player does not carry the grey-dust:
instead try recalling the grey-dust;
stop the action.
Check dropping grey-dust when a ground-grey-dust is in the location:
now the grey-dust is off-stage;
instead say "You discard the dust."
Check rubbing ground-grey-dust:
instead say "You can't clean the dust from an entire world."
Check pushing ground-grey-dust:
instead try rubbing the noun.
Section - Hadean Plain
The Out-Plain is a recallable room. The printed name is "Hadean Plain".
The zone is outside-zone.
The atmosphere is vacuum-atm.
The Out-Plain is not lamp-enabled.
The description is "You stand at the edge of a Hadean land now. Grey lifeless dust crunches soundlessly beneath your feet. The sky is black; the stars are glorious. And you have no more protection than the potion you drank.[para]Behind you are the comforting walls of the [Retort]. The airlock is a heavy circular door in the south wall; it is [open-closed outer-door]. To the west, you can see the broad window of the portico. But to the north and east, the Hadean plain stretches away towards jagged foothills.[first time][para][sarge]Your first Venture walk. You're a real marchman now, aren't you, swabbie?[/sarge][only]".
Understand "outside", "hadean", "plain" as Out-Plain.
The can't-go is "The airlock door is south, the portico window is west; or you can venture northeast towards the pass."
Check going inside in Out-Plain:
instead try going south.
Check going north in the Out-Plain:
instead say "The hills to the north look impassable. But you can make out a pass opening to the northeast."
Check going east in the Out-Plain:
instead say "The hills to the east look impassable. But you can make out a pass opening to the northeast."
Check going southwest in the Out-Plain:
instead try entering the retort-wall.
Check going northeast from Out-Plain:
say "You hike up towards the pass. Your feet kick up dust which falls behind you, never trailing in the nonexistent air."
The out-hills-1 are a plural-named far-sight in the Out-Plain. The printed name is "foothills".
The description is "The hills are etched in shades of grey against a sky of stars. You can see a low spot to the northeast -- probably the opening of a mountain pass."
The reach-reason is "You are far from the foothills."
Understand "foothill", "foothills", "grey", "gray", "hill", "hills", "mountain", "mountains", "jagged", "pass", "opening", "canyon" as the out-hills-1.
The lens-view is "a Hadean land".
Check entering the out-hills-1:
instead try going northeast.
The out-dust-1 is a ground-grey-dust in the Out-Plain.
The hadean-sky is in the Out-Plain.
The retort-wall is scenery in the Out-Plain. The printed name is "marcher".
The description is "The [Retort], from this outward view, is a tidy white mansion in a colonial style. (Though the paint must be some refractory alchemical compound, to survive so many foreign environments.) It stands south and west of you. The airlock door to the south is [open-closed outer-door]; the portico window is to the west."
Understand "retort", "tidy", "colonial", "white", "wall", "walls", "paint", "marcher", "mansion", "house" as the retort-wall.
The lens-view is "the Earth".
Check entering the retort-wall:
instead say "You can re-enter the [Retort] to the south or west."
Check touching the retort-wall:
instead say "The painted wall is solid."
Check climbing the retort-wall:
instead say "You can't climb the wall of the [Retort]."
Check tasting the retort-wall:
instead say "You lick the [Retort][first time]. Can't say you've ever done that before[only]."
Check inspecting the retort-wall with the oculus:
instead say "Through the oculus, the [Retort] looks oddly insubstantial."
Section - Hadean Canyon
The Out-Canyon is a room. The printed name is "Hadean Land, in Canyon".
The zone is outside-zone.
The atmosphere is vacuum-atm.
The description is "You are working your way through a narrow canyon. Angular grey mountains loom above you, and stars shine down on it all.[para]The canyon zig-zags down to the southwest. To the southeast, it slopes more gradually, opening onto another dusty plain. A twisted metal shape is visible across the plain, but you cannot tell what it is.[para]You also see an opening in the canyon wall to the northwest. It might be some sort of cave, but if so, it is very dark."
The Out-Canyon is not lamp-enabled.
The Out-Canyon is northeast of the Out-Plain.
The can't-go is "The only navigable paths are southwest and southeast. The cave is northwest."
Check going southeast from Out-Canyon:
say "You continue down out of the crags. The shape grows as you approach, becoming a twisted metal hill by the time you reach its foot."
Check going southwest from Out-Canyon:
say "You trudge back out of the canyon. When the [Retort] appears from around the last bend, it is a breath of relief. Or would be, if you were breathing."
Check going inside in the Out-Canyon:
instead try going northwest.
Check going up in the Out-Canyon:
instead try climbing the canyon-mountains.
The canyon-ship is a far-sight in the Out-Canyon. The printed name is "metal shape".
The reach-reason is "The metal shape is across the plain to the southeast."
The description is "You can only make out a twisted heap of metal. It might be some sort of marcher, but it doesn't look like a building -- more like a sea-going ship somehow dropped out of the black sky."
Understand "metal", "twisted", "shape", "heap", "ship", "marcher" as the canyon-ship.
The out-void-door is an open unopenable scenery door. The printed name is "dark cave".
The description is "The cave is very, very dark."
Understand "cave", "dark", "gap", "opening" as the out-void-door.
The Out-Void-Room is northwest of the out-void-door.
The Out-Canyon is southeast of the out-void-door.
Check searching the out-void-door:
instead try examining the out-void-door.
Check inspecting the out-void-door with the oculus:
instead say "The oculus shows the dark cave as associated with time."
The out-dust-2 is a ground-grey-dust in the Out-Canyon.
The hadean-sky is in the Out-Canyon.
The canyon-mountains are plural-named scenery in the Out-Canyon. The printed name is "mountains".
The description is "The mountains look much higher now that you are among them."
Understand "canyon", "mountain", "mountains", "crag", "crags", "angular", "wall", "walls", "narrow", "grey", "gray" as the canyon-mountains.
Check entering the canyon-mountains:
instead say "You are already in the canyon."
Check climbing the canyon-mountains:
instead say "The canyon walls are much too steep to climb."
Section - Hadean Void Room
The Out-Void-Room is a reset-room.
The near-room is the Out-Canyon.
The description is "You find yourself drifting through a familiar void."
Section - Hadean Wreck
The Out-Ship is a recallable room. The printed name is "Hadean Land, at Wreck".
The zone is outside-zone.
The atmosphere is vacuum-atm.
The Out-Ship is not lamp-enabled.
The description is "You stand at the foot of a wall of metal. It's not a simple construction; it leans inward here, outward there, tracing an irregular shape that looms over the dusty plain. Perhaps it's broken, for debris is scattered around.[para]Mountains rise all around, forming a jagged grey bowl which cups the metal wreck. You can see the canyon pass to the northwest."
Understand "hadean", "alien", "wreck", "wrecked", "ship" as the Out-Ship.
The Out-Ship is southeast of the Out-Canyon.
Rule for printing the name of the Out-Ship while asking which do you mean: say "Wrecked Ship".
The can't-go is "You can go northwest, or[if Out-Airlock is not visited] (perhaps)[end if] enter the wreck to the east."
Check going northwest from Out-Ship:
say "You hike up back towards the pass."
Check going north in Out-Ship:
instead say "The mountains to the north look impassable. But you can make out a pass opening to the northwest."
Check going west in Out-Ship:
instead say "The mountains to the west look impassable. But you can make out a pass opening to the northwest."
Check going south in Out-Ship:
instead say "The terrain to the south is too rough for travel."
Check going inside in Out-Ship:
instead try going east.
The by-ship is prominent-scenery in Out-Ship. The printed name is "metal shape".
The description is "The metal heap, or wreck -- shape -- towers over you. Pieces lean dizzily outward, or inward; you have no way to understand whether they were built that way, or twisted in some unimaginable catastrophe."
Understand "metal", "twisted", "irregular", "broken", "shape", "heap", "ship", "marcher" as the by-ship.
Understand "hill", "wall", "wall of", "wreck", "construction" as the by-ship.
Rule for writing a paragraph about the by-ship:
if the alien-outer-door is closed:
say "A hexagonal outline on the wall, to the east, might be a door. If so, it is closed";
else:
say "A hexagonal door to the east has slid partway open";
if glyph-1-item is in Out-Ship:
say ". A small black knot, a tangle of strokes, is drawn on the hexagon";
if the ship-circle is in Out-Ship:
say ".[para]Next to the [if the alien-outer-door is closed]hexagon[else]door[end if], a small circular arc is incised into the metal[if the mercury is part of the ship-circle]. The circle is filled with mercury[else]";
if the ship-niche is open:
say ".[para]A small niche has opened next to the [if the alien-outer-door is closed]hexagon[else]door[end if]";
if the ship-niche is empty:
say ". It is empty";
else:
say ". Within [is-are a list of things *in the ship-niche]";
instead say "."
Check entering the by-ship:
instead try going east.
Check climbing the by-ship:
instead say "The wall is not flat, but there are no handholds within reach."
Check touching the by-ship:
instead say "The wall is old, cold metal."
Check repairing the by-ship:
instead say "You're helpless to fix it, if it's even broken."
Check inspecting the by-ship with the planetary-lens:
instead say "You cannot understand what you see."
The ship-circle is scenery in Out-Ship. The printed name is "circular arc".
The description is "A circular arc is engraved in the wall, next to the door[if the mercury is part of the ship-circle]. The circle is filled with a mirror-bright film of mercury[else]. It's barely two inches across[end if]."
Understand "circle", "circular", "arc", "bound", "boundary" as the ship-circle.
Understand "film", "mirror" as the ship-circle when the mercury is part of the ship-circle.
Check searching the ship-circle:
instead try examining the ship-circle.
Check examining the mercury when the mercury is part of the ship-circle:
instead try examining the ship-circle.
Check taking the ship-circle:
instead say "The depression is part of the wall."
Check taking the mercury when the mercury is part of the ship-circle:
instead say "You can't scrape the mercury off the wall. It just runs around your fingers, and stays where it is."
Check tasting the ship-circle when the mercury is part of the ship-circle:
instead try tasting the mercury.
Check eating the ship-circle when the mercury is part of the ship-circle:
instead try tasting the mercury.
Check drinking the ship-circle when the mercury is part of the ship-circle:
instead try tasting the mercury.
Check touching the ship-circle:
if the mercury is part of the ship-circle:
instead try touching the mercury;
instead say "The circle does not react to your touch."
Check rubbing the ship-circle:
instead try touching the ship-circle.
Check pushing the ship-circle:
instead try touching the ship-circle.
Check inserting something into the ship-circle:
instead try putting the noun on the ship-circle.
Check putting the mercury on the ship-circle:
instead try tapping the mercury on the ship-circle.
Check putting something on the ship-circle:
instead say "The circle is engraved on a vertical wall; it can't support anything."
Check tapping the mercury on the ship-circle:
now the mercury is part of the ship-circle;
instead say "You tilt the mercury droplet against the circle. It sticks to the metal, and slowly spreads out until it reaches the edge. There is now a perfect circle of quicksilver, mirror-flat, clinging to the wall."
Check inspecting the ship-circle with the planetary-lens:
instead say "You cannot understand what you see."
The glyph-1-item is an alien-glyph-item in Out-Ship.
The glyph-used is glyph-1.
The description is "The knot of script is no more comprehensible than the markings you've seen on the [Retort]. Except that there's something about it... again, that itch of familiarity.[para]You stare harder. It's...[para][em]comprehension[/em][para]That meant something. You don't know what, except that you're lying flat in the dust and you can't remember falling. The hexagon is blank now; the script is... [em]somewhere in the back of your head...[/em] You can [em]remember[/em] the glyph now. You roll over and push to your feet, hoping that you've gained something besides permanent brain damage."
Carry out invoking the caudex-pattern in Out-Ship when the ship-circle is in Out-Ship and the mercury is part of the ship-circle:
now the alien-outer-door is open;
mark g-alien-outer-door as done;
now the ship-circle is off-stage;
retire the mercury with explanation "[The mercury] disappeared into the wreck";
instead say "You begin running through the [em]caudex access[/em] geometric sequence in your head. The quicksilver circle vibrates in response; complex ripples refract across it.[para]When the sequence is complete, the panel silently slides up, hiding the quicksilver circle from view. Then, more slowly, the hexagonal door begins to move. It only slides about halfway open, but that is enough to enter."
Carry out invoking the radix-pattern in Out-Ship when the ship-circle is in Out-Ship and the mercury is part of the ship-circle:
now the polar-oil is ever-seen;
now the ship-niche is open;
now the ship-circle is off-stage;
retire the mercury with explanation "[The mercury] disappeared into the wreck";
instead say "You begin running through the [em]radix access[/em] geometric sequence in your head. The quicksilver circle vibrates in response; complex ripples refract across it.[para]When the sequence is complete, a metal panel neatly and silently rotates, hiding the quicksilver circle from view. Instead, a small niche is now visible, containing a vial of black oil[if the glyph-2-item is in the ship-niche] and another knot of marks[end if]."
Carry out invoking the calyx-pattern in Out-Ship when the ship-circle is in Out-Ship and the mercury is part of the ship-circle:
instead say "You begin running through the [em]calyx access[/em] geometric sequence in your head. The quicksilver circle vibrates in response.[para]You have a sense of listening to an empty void. Of course you [em]are[/em] listening to an empty void, out here. But metaphorically as well."
The ship-niche is a closed unopenable scenery container in Out-Ship. The printed name is "[if closed]panel[else]niche[end if]".
Understand "niche", "metal", "panel", "small" as the ship-niche.
Check examining the ship-niche when the ship-niche is closed:
if the ship-circle is in Out-Ship:
instead say "You can just make out that the circular arc is engraved on a solid panel in the wall. If the panel is meant to move, though, you can't see how.";
else:
instead say "If the panel is meant to move, you can't see how."
Check searching the ship-niche:
instead try examining the ship-niche.
Check opening the ship-niche:
instead try pushing the ship-niche.
Check closing the ship-niche:
instead try pushing the ship-niche.
Check inspecting the ship-niche with the planetary-lens:
instead say "You cannot understand what you see."
The glyph-2-item is an alien-glyph-item in the ship-niche.
The glyph-used is glyph-2.
The description is "You glare at the knot, willing understanding.[para][em]comprehension[/em][para]This symbol resembles the first, but it comes with a new image: the black oil, magnetic oil, flowing over indigo stone. [mark maze-column-fact as known]An indigo stone column[if Mineral-Maze is visited]. A [em]familiar[/em] column, in a twisty maze of underground cracks[end if]! It must have magnetic properties, which the alien oil will respond to."
The glyph-2-item is not scenery. The glyph-2-item is fixed in place.
The out-hills-3 are a plural-named far-sight in the Out-Ship. The printed name is "mountains".
The description is "The mountains loom to the north and west, jagged grey shapes against a sky of stars. The opening of the canyon is visible to the northwest."
The reach-reason is "You are far from the mountains."
Understand "foothill", "foothills", "grey", "gray", "mountain", "mountains", "crag", "crags", "jagged", "pass", "opening", "canyon" as the out-hills-3.
The lens-view is "a Hadean land".
Check entering the out-hills-3:
instead try going northwest.
The out-dust-3 is a ground-grey-dust in the Out-Ship.
The hadean-sky is in the Out-Ship.
The out-debris is scenery in the Out-Ship. The printed name is "debris".
The description is "A few shards of ceramic lie around the wreck, as if they had fallen from it. None of their shapes look meaningful."
Understand "debris", "rubble", "wreckage", "shard", "shards", "ceramic" as the out-debris.
Check taking the out-debris:
instead say "You cannot think of a use for any of the debris."
Check pushing the out-debris:
instead say "You poke at some of the debris, but it remains unfathomable."
Check repairing the out-debris:
instead try pushing the out-debris.
Check inspecting the out-debris with the planetary-lens:
instead say "You cannot understand what you see."
Check recalling the out-debris when the wreck-debris-fact is known:
instead say "You recall the vision of the glyph: the polar oil will react if poured over this debris."
Report topically-applying the polar-oil to the out-debris:
mark the calyx-pattern as known;
instead say "You look for a large bit of ceramic, and pour the black oil onto it. It flows off in inky streams, which branch and ramify in the Hadean dust.[para]For a moment you are looking at familiar -- that is, familiarly strange -- twisted black markings. They refer to [em]calyx access,[/em] the flowering of knowledge... not a physical transition, but a pathway of communication. It has the odor of dragons about it.[para]Then the oil sinks into the dust, all at once, and is gone without a trace."
The initial appearance of the mercury is "A small puddle of mercury gleams in the dust."
Section - Hadean Airlock
The Out-Airlock is a recallable room. The printed name is "Strange Airlock".
The zone is out-airlock-zone.
The recall-minor is true.
The atmosphere is vacuum-atm.
Understand "strange", "airlock" as the Out-Airlock.
The Out-Airlock is not lamp-enabled.
The description is "This chamber is not hexagonal, but it reminds you of a hexagon in all directions, if that makes sense. Perhaps it doesn't."
[See alien-inner-door for paragraph.]
The can't-go is "The inner door is north, and the outer door is west."
Check going inside in Out-Airlock:
instead try going north.
Check going outside in Out-Airlock:
instead try going west.
The alien-outer-door is a scenery door. The printed name is "outer door".
The alien-outer-door is not openable.
The refer-name is "alien wreck".
Understand "outer", "door" as the alien-outer-door.
The opening-goal is g-alien-outer-door.
The alien-outer-door is east of the Out-Ship and west of the Out-Airlock.
Understand "hexagon", "hexagonal", "outline" as the alien-outer-door.
Check examining the alien-outer-door when in Out-Ship:
if the alien-outer-door is closed:
say "It's just a hexagonal outline on the metal wall[if Out-Airlock is not visited]. You're not even sure it [em]is[/em] a door[end if][if glyph-1-item is in Out-Ship].[para]A small knot of black marks is drawn in the center of the outline[end if]";
else:
say "The door has slid partway to the side, permitting entrance";
instead say "."
Check examining the alien-outer-door when in Out-Airlock:
if the alien-outer-door is closed:
say "The outer door is just a hexagonal outline on the metal wall";
else:
say "The outer door has slid partway to the side, permitting exit";
instead say "."
Check inspecting the alien-outer-door with the planetary-lens:
instead say "You cannot understand what you see."
The alien-inner-door is a prominent-scenery door. The printed name is "inner door".
The alien-inner-door is not openable.
The refer-name is "alien airlock inner door".
Understand "inner", "door" as the alien-inner-door.
The opening-goal is g-alien-inner-door.
The alien-inner-door is north of the Out-Airlock and south of the Out-Chamber.
Understand "hexagon", "hexagonal", "outline" as the alien-inner-door.
Rule for writing a paragraph about the alien-inner-door:
if the location is the Out-Airlock:
say "Strange as the architecture may be, an airlock is clearly an airlock. The outer door to the west is [open-closed alien-outer-door]";
if alien-inner-door is closed:
say "; the inner door to the north is closed";
else:
say ". The inner door to the north is open";
if aither-potion-remaining is zero:
say ", but a sense of aching strain seems to pour through it";
else:
say ". You feel a sense of strain from that direction, but it's mostly numb now";
if glyph-3-item is in Out-Airlock:
say ".[para]A small knot of black marks is drawn in the center of the inner door. ";
else:
say ".[para]";
say "Next to the door is another small circle. This one contains a film of black liquid";
say ".";
else:
say "The airlock door to the south is [open-closed alien-inner-door]."
Check examining the alien-inner-door when in Out-Airlock:
if the alien-inner-door is closed:
say "The inner door is just another hexagonal outline on the metal wall[if glyph-3-item is in Out-Airlock].[para]A small knot of black marks is drawn in the center of the outline[end if]";
else:
say "The inner door has slid partway to the side, permitting entrance[if glyph-3-item is in Out-Airlock].[para]A small knot of black marks is still visible on the door[end if]";
instead say "."
Check examining the alien-inner-door when in Out-Chamber:
say "The door has slid partway to the side, permitting exit";
instead say "."
Check opening the alien-outer-door when the alien-outer-door is open:
instead say "The door is already open."
Check opening the alien-outer-door when the alien-outer-door is closed:
if g-alien-outer-door is ever-done:
goal-perform g-alien-outer-door;
if the alien-outer-door is open:
say "You invoke the [em]caudex[/em] pattern to open the outer door";
if in Out-Airlock:
if aither-potion-remaining is zero:
say ". The ache in your bones trickles away, leaving a faint warmth";
else:
say ". The numbness in your bones fades away";
say ".";
stop the action;
instead say "You have no idea how to make the door open."
Check closing the alien-outer-door when the alien-outer-door is closed:
instead say "The door is already closed."
Check closing the alien-outer-door when the alien-outer-door is open:
instead say "It's not obvious how to close the door, now that it's open."
Check opening the alien-inner-door when the alien-inner-door is open:
instead say "The door is already open."
Check opening the alien-inner-door when the alien-inner-door is closed:
if g-alien-inner-door is ever-done:
goal-perform g-alien-inner-door;
if the alien-inner-door is open:
say "You invoke the [em]radix[/em] pattern to open the inner door";
if in Out-Airlock:
if aither-potion-remaining is zero:
say ".[para]An intangible strain seems to pervade the space from the open door. Your bones and teeth ache";
else:
say ". The blue haze in your vision darkens; your teeth feel numb";
say ".";
stop the action;
instead say "You're not sure how to open this door either."
Check closing the alien-inner-door when the alien-inner-door is closed:
instead say "The door is already closed."
Check closing the alien-inner-door when the alien-inner-door is open:
instead say "It's not obvious how to close the door, now that it's open."
Check inspecting the alien-inner-door with the planetary-lens:
instead say "You cannot understand what you see."
The glyph-3-item is an alien-glyph-item in Out-Airlock.
The glyph-used is glyph-3.
The description is "You stare at the knot, willing understanding.[para][em]comprehension[/em][para]This third symbol brings you a new image: a sheet of paper, buried in rubble. Again, the scene is familiar... a crack in a wall... the crawlway under the Nave. You do your best to memorize the paper's exact location[mark the nave-debris-fact as known]."
The airlock-circle is scenery in Out-Airlock. The printed name is "circular arc".
The description is "A circular arc is engraved in one wall, next to the door. It's about two inches across, and filled with a liquid black film."
Understand "circle", "circular", "arc", "bound", "boundary" as the airlock-circle.
Understand "liquid", "film", "black" as the airlock-circle.
Check searching the airlock-circle:
instead try examining the airlock-circle.
Check taking the airlock-circle:
instead say "You can't scrape the black liquid off the wall. It just runs around your fingers, and stays where it is."
Check tasting the airlock-circle:
instead say "Consuming alien reagents is probably stupid."
Check eating the airlock-circle:
instead try tasting the airlock-circle.
Check drinking the airlock-circle:
instead try tasting the airlock-circle.
Check touching the airlock-circle:
instead say "You tap the circle and watch the black surface ripple."
Check rubbing the airlock-circle:
instead try touching the airlock-circle.
Check pushing the airlock-circle:
instead try touching the airlock-circle.
Check inserting something into the airlock-circle:
instead try putting the noun on the airlock-circle.
Check putting something on the airlock-circle:
instead say "The circle is engraved on a vertical wall; it can't support anything."
Check inspecting the airlock-circle with the planetary-lens:
instead say "You cannot understand what you see."
Carry out invoking the radix-pattern in Out-Airlock:
say "You begin running through the [em]radix access[/em] geometric sequence in your head. The black circle vibrates in response; complex ripples refract across it";
if the alien-inner-door is open:
instead say ". But when the sequence is complete, the ripples just fade away.";
now the alien-inner-door is open;
now the alien-outer-door is closed;
mark g-alien-inner-door as done;
say ".[para]When the sequence is complete, the inner door begins to slide aside. Simultaneously, behind you, the outer door closes. Both move in silence -- of course -- and in moments the way inward is clear";
say ".[para]No vapor rushes into the airlock; you are still in vacuum";
if aither-potion-remaining is zero:
say ". But an intangible strain seems to pervade the space from the open door. Your bones and teeth ache";
else:
say ". But the blue haze in your vision darkens; your teeth feel numb";
instead say "."
Carry out invoking the caudex-pattern in Out-Airlock:
say "You begin running through the [em]caudex access[/em] geometric sequence in your head. The black circle vibrates in response; complex ripples refract across it";
if the alien-outer-door is open:
instead say ". But when the sequence is complete, the ripples just fade away.";
now the alien-outer-door is open;
now the alien-inner-door is closed;
mark g-alien-outer-door as done;
say ".[para]When the sequence is complete, the inner door begins to close again, and the outer door starts sliding open";
if aither-potion-remaining is zero:
say ". The ache in your bones trickles away, leaving a faint warmth";
else:
say ". The numbness in your bones fades away";
instead say "."
Carry out invoking the calyx-pattern in Out-Airlock:
instead say "You begin running through the [em]calyx access[/em] geometric sequence in your head. The black circle vibrates in response.[para]You have a sense of listening to an empty void. Of course you [em]are[/em] listening to an empty void, out here. But metaphorically as well."
Section - Hadean Chamber
The Out-Chamber is an alien-aither-env room. The printed name is "Bent Chamber".
The zone is out-chamber-zone.
The atmosphere is vacuum-atm.
The Out-Chamber is not lamp-enabled.
The description is "This chamber has odd angles, but you're pretty sure they're not all intentional. The walls look crumpled and the ceiling is bent downwards. Hallways may have once run in several directions, but the only one that remains wide enough to pass is to the east."
The can't-go is "The airlock door is south, and a clear hall runs east."
Check going north in the Out-Chamber:
instead say "There was once a hallway to the north, but it has crumpled inwards."
Section - Hadean Hallway
The Out-Hall is an alien-aither-env room. The printed name is "Ruined Hallway".
The zone is out-chamber-zone.
The atmosphere is vacuum-atm.
The Out-Hall is not lamp-enabled.
The description is "This hall runs east and west, but to the east the walls are crushed together like a paper sculpture.[para]A wide trapezoidal window is set into the north wall[if a-window is clean]. It looks like ordinary glass, although you suppose one never knows[else], but the glass is gone[end if][if the F-sharp-chime is part of the a-window]. The F-sharp chime is embedded in the window[end if]."
The Out-Hall is east of the Out-Chamber.
[Hall blocked east]
The can't-go is "The[if a-window is dirty] broken[end if] window is north, and the hall runs west."
Check going east in the Out-Hall:
instead say "The hallway is twisted shut beyond this point."
The a-window is a glass-window.
[Glass-passable door "window"; really always open]
[See also sv-window]
The refer-name of the a-window is "window in alien wreck".
The a-window can be clean or dirty. [shattered by glass-break chime; resettable]
The a-window is north of the Out-Hall and south of the Out-Store.
Understand "heavy", "glass", "window", "trapezoid", "wide" as the a-window.
Understand "broken" as the a-window when the a-window is dirty.
Check examining the a-window:
if the a-window is dirty:
say "The window has shattered; no glass remains. ";
if the location is the Out-Hall:
say "You can see a chamber on the other side";
if glyph-4-item is in Out-Store:
say ". There's a smudge on the far wall which just might be another knot of marks";
else:
say "You can see the hallway on the other side";
if the F-sharp-chime is part of the a-window:
say ".[para][The F-sharp-chime] is stuck in the glass, vibrating steadily";
instead say "."
Check searching the a-window:
instead try examining the a-window.
Check touching the a-window:
if the a-window is dirty:
instead say "It's unwise to grope broken glass.";
if the F-sharp-chime is part of the a-window:
instead say "You feel a steady vibration... and a yielding, as the glass slides through your flesh. It's rather unnerving.";
instead say "It feels like solid glass."
Check opening the a-window:
if the a-window is dirty:
instead say "It's already broken.";
instead say "The window can't be opened."
Check closing the a-window:
if the a-window is dirty:
instead say "It's smashed.";
instead say "The window is fixed closed."
Check listening to the a-window when the F-sharp-chime is part of the a-window:
instead try listening to the F-sharp-chime.
Check attacking the a-window:
instead try smashing the a-window.
Check smashing the a-window:
if the a-window is dirty:
instead say "It's already broken.";
if the F-sharp-chime is part of the a-window:
instead say "You probably couldn't break it in this state.";
instead say "The glass won't break."
Check repairing the dirty a-window:
instead say "Hopeless."
Check going when the door gone through is the a-window:
if the a-window is dirty:
mark the g-alien-window as done;
now the symbol-type of g-alien-window is decoherence-symbol;
say "You climb through the broken window.";
continue the action;
if the F-sharp-chime is part of the a-window:
mark the g-alien-window as done;
now the symbol-type of g-alien-window is permeability-symbol;
say "You slide through the vibrating glass.";
continue the action;
[Handle auto-solutions...]
if g-alien-window is ever-done:
if the location is Out-Hall:
instead goal-travel to Out-Store;
else:
instead goal-travel to Out-Hall;
instead say "The window is solid glass."
Check putting the F-sharp-chime on the a-window when the ring-time of the F-sharp-chime is not zero:
instead try tapping the F-sharp-chime on the a-window.
Check inserting the F-sharp-chime into the a-window when the ring-time of the F-sharp-chime is not zero:
instead try tapping the F-sharp-chime on the a-window.
Check tapping the F-sharp-chime on the a-window when the ring-time of the F-sharp-chime is not zero:
if the symbol-type of the F-sharp-chime is decoherence-symbol:
now the a-window is dirty;
uninscribe the F-sharp-chime;
retire the F-sharp-chime by manual destruction in the a-window;
instead say "You press the chime against the window. The glass vibrates, and the bronze sinks slowly into it. The frequency of the vibration rises as you push. The glass seem to ripple -- and then both the window and the chime collapse into a grainy dust, all at once.";
if the symbol-type of the F-sharp-chime is permeability-symbol:
if the F-sharp-chime is part of the a-window:
instead say "It's already stuck in the window.";
now the ring-time of the F-sharp-chime is three;
now the F-sharp-chime is part of the a-window;
instead say "You press the chime against the window. The glass vibrates, and the bronze sinks slowly into it -- not like metal into tar, but like a knife sliding between infinitesimal layers of glass.[para]When you draw your hand away, the chime remains suspended in the glass. Its vibration continues at a steady pitch.";
instead say "(BUG) F-sharp-chime on a-window: [symbol-type of the F-sharp-chime]."
Check inserting something into the a-window when the F-sharp-chime is part of the a-window:
instead say "You're not sure about the mechanics of pushing things through permeable glass. Easier to walk through yourself."
Check inserting something into the clean a-window:
instead say "You can't push things through solid glass."
Section - Hadean Chamber
The Out-Store is an alien-aither-env room. The printed name is "Ruined Chamber".
The zone is out-store-zone.
The atmosphere is vacuum-atm.
The Out-Store is not lamp-enabled.
The description is "This chamber is empty and derelict -- cracked, crooked, uneven. The only exit is a dark gap to the east; you can't tell if it's the remains of a hallway or just a hole in the wall.[para]A wide trapezoidal window is set into the south wall[if a-window is clean][else], but the glass is gone[end if][if the F-sharp-chime is part of the a-window]. The F-sharp chime is embedded in the window[end if][if glyph-4-item is in Out-Store].[para]A small knot of black marks is drawn on one wall[end if]."
The can't-go is "The window to the south and the gap to the east are the only exits."
The wreck-void-door is an open unopenable scenery door. The printed name is "dark gap".
The description is "The gap is very, very dark."
Understand "hole", "dark", "gap", "opening" as the wreck-void-door.
The Wreck-Void-Room is east of the wreck-void-door.
The Out-Store is west of the wreck-void-door.
Check searching the wreck-void-door:
instead try examining the wreck-void-door.
Check inspecting the wreck-void-door with the oculus:
instead say "The oculus shows the dark gap as associated with time."
The glyph-4-item is an alien-glyph-item in Out-Store.
The glyph-used is glyph-4.
The description is "You gaze at the knot, willing understanding.[para][em]comprehension[/em][para]This fourth symbol brings you a new image: the black magnetic oil flowing over ceramic shards. You recognize the debris which lies outside the wreck[mark the wreck-debris-fact as known]."
Section - Wreck Void Room
The Wreck-Void-Room is a reset-room.
The near-room is the Out-Store.
The description is "You find yourself drifting through a familiar void."
Chapter - Endgame
Endgame-1 is a room. The printed name is "You were buried in wreckage".
The description is "Weight pressed down on you. You could not make out what had fallen -- broken beams, chunks of ceiling tile -- but it hurt. [one of]You hurt. You tried to shift; the[or]The[stopping] only way out was up."
The can't-go is "Up seemed like the only way out."
Check going up in endgame-1:
instead try going outside.
Check going outside in endgame-1:
now the current-tense is perfect-tense;
say "You pushed debris aside. A chill bled into stale, hot air. You bled too, and wrenched your body free."
The end-1-wreckage is scenery in Endgame-1. The printed name is "wreckage".
Understand "weight", "wreck", "wreckage", "broken", "beam", "beams", "tile" as the end-1-wreckage.
[This exists only to turn "can't see any such thing" errors into "no time for that" errors.]
Endgame-2 is a room. The printed name is "You have crawled into a ruined corridor".
The description is "The light has nearly vanished. The dimness and vertigo have rendered the laboratory corridor of the [Retort] nearly unrecognizable.[para][first time][endgame-final-char-resolution].[para][only]You've seen the way out of here."
Endgame-2 is outside from Endgame-1.
To say endgame-final-char-resolution:
say "Your cleaning work in the alchemy lab... no. Not important";
if active-dragon is:
-- Aistheta: say ". Could Ctesc have caused this? All those books you liberated for him... he promised that you'd share any secrets he found[if Scholar is aspect-positive]. But he's always been the type to experiment first, report later[else]. But you might have underestimated his greed[end if]. Maybe if you find him";
-- Baros: say ". This must be Powes['] fault. All the time you've spent setting him up for a fall, he must have been trying to set [em]you[/em] up... [if Climber is aspect-positive]you've always known he would[else]you wouldn't have believed it of him[end if]. But surely he couldn't have intended this catastrophe";
-- Syndesis: say ". Where could Ashe... could the Captain be? Not looking for you[if Captain is aspect-positive]; whatever you've shared, whatever she's thought of you, the marcher takes precedence[else]; you've never deluded yourself that she shared that much of herself with you[end if]. She'll have gone for the Aithery, or for the Chancel";
-- Pneuma: say ". Could this be Anderes['] fault? All the reagents you've liberated for her[if Grafter is aspect-positive]... but she's always so careful when she stashes them[else]... if she's been careless with them, you'll be furious[end if]. No profit in broken glass";
-- otherwise: say "(BUG) endgame-final-char-resolution for [active-dragon]";
The can't-go is "You have to get out."
Check going inside in endgame-2:
instead say "You have escaped the wreckage, and you have no intent to return."
Check going down in endgame-2:
instead try going inside.
Check going north in endgame-2:
instead try going outside.
Check going west in endgame-2:
instead try going outside.
Check going outside in endgame-2:
now the current-tense is future-tense;
say "You have made your way along the corridor, scrambling over fallen debris. And a few human forms, but none of them breathe.[para]You've recognized the hand of Sergeant Brooks protruding obscenely from under stone. You've passed it by."
Endgame-3 is a room. The printed name is "You will reach the Nave".
The description is "The Nave will be as dark as the rest of the [Retort]; moth-flickers of phlogiston will dance in the lamps. The floor will be clear now, the ceiling whole; but the walls will be dense with black, alien markings[first time]. You will not recognize them. You will not understand how they got there[only].[para][first time]The marcher will be abandoned, as far as you will be able to see.[para][only]You will barely have learned the rudiments of alchemy, but the ritual bound will be unscathed. Surely there will be something you can try."
Endgame-3 has a number called the ballast-level. [0: no ballast; 1: misplaced ballast; 2: correctly placed ballast. This is set before the final reset.]
Endgame-3 is outside from Endgame-2.
The can't-go is "You will have work to do here."
Check going inside in endgame-3:
instead say "There will be no going back from here."
The end-3-markings is scenery in Endgame-3. The printed name is "markings".
Understand "marking", "markings", "mark", "marks", "black", "alien" as the end-3-markings.
The end-3-bound is scenery in Endgame-3. The printed name is "bound".
Understand "pedestal", "bound", "arc", "ritual" as the end-3-bound.
HL Game Locs ends here.